The Alternative Csound Reference Manual
Previous |  | Next

# sndwarp

sndwarp -- Reads a mono sound sample from a table and applies time-stretching and/or pitch modification.

## Description

sndwarp reads sound samples from a table and applies time-stretching and/or pitch modification. Time and frequency modification are independent from one another. For example, a sound can be stretched in time while raising the pitch!

The window size and overlap arguments are important to the result and should be experimented with. In general they should be as small as possible. For example, start with iwsize=sr/10 and ioverlap=15. Try irandw=iwsize*.2. If you can get away with less overlaps, the program will be faster. But too few may cause an audible flutter in the amplitude. The algorithm reacts differently depending upon the input sound and there are no fixed rules for the best use in all circumstances. But with proper tuning, excellent results can be achieved.

## Syntax

ar [, ac] sndwarp xamp, xtimewarp, xresample, ifn1, ibeg, iwsize, irandw, ioverlap, ifn2, itimemode

## Initialization

ifn1 -- the number of the table holding the sound samples which will be subjected to the sndwarp processing. GEN01 is the appropriate function generator to use to store the sound samples from a pre-existing soundfile.

ibeg -- the time in seconds to begin reading in the table (or soundfile). When itimemode is non- zero, the value of xtimewarp is offset by ibeg.

iwsize -- the window size in samples used in the time scaling algorithm.

irandw -- the bandwidth of a random number generator. The random numbers will be added to iwsize.

ioverlap -- determines the density of overlapping windows.

ifn2 -- a function used to shape the window. It is usually used to create a ramp of some kind from zero at the beginning and back down to zero at the end of each window. Try using a half a sine (i.e.: f1 0 16384 9 .5 1 0) which works quite well. Other shapes can also be used.

## Performance

ar -- the single channel of output from the sndwarp unit generator. sndwarp assumes that the function table holding the sampled signal is a mono one. This simply means that sndwarp will index the table by single-sample frame increments. The user must be aware then that a stereo signal is used with sndwarp, time and pitch will be altered accordingly.

ac (optional) -- a single-layer (no overlaps), unwindowed versions of the time and/or pitch altered signal. They are supplied in order to be able to balance the amplitude of the signal output, which typically contains many overlapping and windowed versions of the signal, with a clean version of the time-scaled and pitch-shifted signal. The sndwarp process can cause noticeable changes in amplitude, (up and down), due to a time differential between the overlaps when time-shifting is being done. When used with a balance unit, ac can greatly enhance the quality of sound.

xamp -- the value by which to scale the amplitude (see note on the use of this when using ac).

xtimewarp -- determines how the input signal will be stretched or shrunk in time. There are two ways to use this argument depending upon the value given for itimemode. When the value of itimemode is 0, xitimewarp will scale the time of the sound. For example, a value of 2 will stretch the sound by 2 times. When itimemode is any non-zero value then xtimewarp is used as a time pointer in a similar way in which the time pointer works in lpread and pvoc. An example below illustrates this. In both cases, the pitch will not be altered by this process. Pitch shifting is done independently using xresample.

xresample -- the factor by which to change the pitch of the sound. For example, a value of 2 will produce a sound one octave higher than the original. The timing of the sound, however, will not be altered.

## Examples

Here is an example of the sndwarp opcode. It uses the files sndwarp.orc, sndwarp.sco, and mary.wav.

Example 1. Example of the sndwarp opcode.

    /* sndwarp.orc */
    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - play an audio file.
    instr 1
      ; Use the audio file defined in Table #1.
      a1 loscil 30000, 1, 1, 1

      out a1
    endin

    ; Instrument #2 - time-stretch an audio file.
    instr 2
      kamp init 6500
      ; Start at 1 second and end at 3.5 seconds.
      ktimewarp line 1, p3, 3.5
      ; Playback at the normal speed.
      kresample init 1
      ; Use the audio file defined in Table #1.
      ifn1 = 1
      ibeg = 0
      iwsize = 4410
      irandw = 882
      ioverlap = 15
      ; Use Table #2 for the windowing function.
      ifn2 = 2
      ; Use the ktimewarp parameter as a "time" pointer.
      itimemode = 1

      a1 sndwarp kamp, ktimewarp, kresample, ifn1, ibeg, iwsize, irandw, ioverlap, ifn2, itimemode
      out a1
    endin
    /* sndwarp.orc */

    /* sndwarp.sco */
    ; Table #1: an audio file.
    f 1 0 262144 1 "mary.wav" 0 0 0
    ; Table #2: half of a sine wave.
    f 2 0 16384 9 0.5 1 0

    ; Play Instrument #1 for 3.5 seconds.
    i 1 0 3.5
    ; Play Instrument #2 for 7 seconds (time-stretched).
    i 2 3.5 10.5
    e
    /* sndwarp.sco */

The below example shows a slowing down or stretching of the sound stored in the stored table (ifn1). Over the duration of the note, the stretching will grow from no change from the original to a sound which is ten times "slower" than the original. At the same time the overall pitch will move upward over the duration by an octave.

    iwindfun=1
    isampfun=2
    ibeg=0
    iwindsize=2000
    iwindrand=400
    ioverlap=10
    awarp   line    1, p3, 1
    aresamp line    1, p3, 2
    kenv    line    1, p3, .1
    asig    sndwarp kenv, awarp, aresamp, isampfun, ibeg, iwindsize, iwindrand, ioverlap,iwindfun,0

Now, here's an example using xtimewarp as a time pointer and using stereo:

    itimemode     =         1
    atime         line      0, p3, 10
    ar1, ar2       sndwarpst kenv, atime, aresamp, sampfun, ibeg, iwindsize, iwindrand, ioverlap, iwindfun, itimemode

In the above, atime advances the time pointer used in the sndwarp from 0 to 10 over the duration of the note. If p3 is 20 then the sound will be two times slower than the original. Of course you can use a more complex function than just a single straight line to control the time factor.

Now the same as above but using the balance function with the optional outputs:

    asig,acmp   sndwarp  1, awarp, aresamp, isampfun, ibeg, iwindsize, iwindrand, ioverlap, iwindfun, itimemode
    abal        balance asig, acmp

    asig1,asig2,acmp1,acmp2 sndwarpst 1, atime, aresamp, sampfun, ibeg, iwindsize, iwindrand, ioverlap, iwindfun, itimemode
    abal1       balance asig1, acmp1
    abal2       balance asig2, acmp2

In the above two examples notice the use of the balance unit. The output of balance can then be scaled, enveloped, sent to an out or outs, and so on. Notice that the amplitude arguments to sndwarp and sndwarpst are "1" in these examples. By scaling the signal after the sndwarp process, abal, abal1, and abal2 should contain signals that have nearly the same amplitude as the original input signal to the sndwarp process. This makes it much easier to predict the levels and avoid samples out of range or sample values that are too small.

| More Advice
| Only use the stereo version when you really need to be processing a stereo file. It is somewhat slower than the mono version and if you use the balance function it is slower again. There is nothing wrong with using a mono sndwarp in a stereo orchestra and sending the result to one or both channels of the stereo output!

## See Also

sndwarpst

## Credits

Author: Richard Karpen
Seattle, WA USA
1997

Example written by Kevin Conder.

Previous | Home | Next
slider8f | Up | sndwarpst