if (word(2 $loadinfo()) != [pf]) { load -pf $word(1 $loadinfo()); return; };
/*
 * guh Copyright 1993 - Dont ask me why i called it that.  I just did.
 *
 * Written by Jeremy Nelson (jnelson@acronet.net)
 * Requires ircII-EPIC
 *
 * General aliases that are useful for tracking
 *  "whatchan" - returns all the channels a person is on
 *  "is_on" - returns the nickname of a user if s/he is on.
 *  "uh" - takes a list of names and returns a list of userhosts
 *         corresponding to those nicks
 *  "inc" - more for antiquity's sake, proves a point
 */

alias whatchan 
{
	stack push on 319;
	^on ^319 * {
		stack pop on 319;
		return $1-;
	};
	wait for ^whois $0;
};

alias is_on 
{
	@ serverctl(set $servernum() maxison 0);
	^local blahblah;
	stack push on 303
	^on ^303 * {
		bless;
		push blahblah $*;
	};
	wait for ison $*;
	stack pop on 303;
	return $blahblah;
};

alias is_off
{
	^local blahblah $*;
	fe ($is_on($*)) foo {
		@ blahblah = remw($foo $blahblah);
	};
	return $blahblah;
};

alias uh 
{
	^local blahblah;
	wait for {
		^userhost $* -cmd {
			bless;
			push blahblah $3@$4;
		};
	};
	return $blahblah;
};

alias inc (var, amt default 1)
{
	@ *var += amt;
};

#hop'93
