%# BEGIN BPS TAGGED BLOCK {{{
%# 
%# COPYRIGHT:
%# 
%# This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
%#                                          <jesse@bestpractical.com>
%# 
%# (Except where explicitly superseded by other copyright notices)
%# 
%# 
%# LICENSE:
%# 
%# This work is made available to you under the terms of Version 2 of
%# the GNU General Public License. A copy of that license should have
%# been provided with this software, but in any event can be snarfed
%# from www.gnu.org.
%# 
%# This work is distributed in the hope that it will be useful, but
%# WITHOUT ANY WARRANTY; without even the implied warranty of
%# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
%# General Public License for more details.
%# 
%# You should have received a copy of the GNU General Public License
%# along with this program; if not, write to the Free Software
%# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
%# 02110-1301 or visit their web page on the internet at
%# http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
%# 
%# 
%# CONTRIBUTION SUBMISSION POLICY:
%# 
%# (The following paragraph is not intended to limit the rights granted
%# to you to modify and distribute this software under the terms of
%# the GNU General Public License and is only of importance to you if
%# you choose to contribute your changes and enhancements to the
%# community by submitting them to Best Practical Solutions, LLC.)
%# 
%# By intentionally submitting any modifications, corrections or
%# derivatives to this work, or any other work intended for use with
%# Request Tracker, to Best Practical Solutions, LLC, you confirm that
%# you are the copyright holder for those contributions and you grant
%# Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
%# royalty-free, perpetual, license to use, copy, create derivative
%# works based on those contributions, and sublicense and distribute
%# those contributions and any derivatives thereof.
%# 
%# END BPS TAGGED BLOCK }}}
<& /Admin/Elements/Header, Title => $title &>
<& /Admin/Elements/CustomFieldTabs,
    id => $CustomFieldObj->Id ,
    current_tab => $current_tab,
    Title => $title &>
<& /Elements/ListActions, actions => \@results &>


<form method="post" action="Modify.html" name="ModifyCustomField">
<input type="hidden" class="hidden" name="id" value="<% $id %>" />

<table>

<tr><td class="label"><&|/l&>Name</&></td>
<td><input name="Name" value="<% $CustomFieldObj->Name || '' %>" size="20" /></td></tr>

<tr><td class="label"><&|/l&>Description</&></td>
<td><input name="Description" value="<% $CustomFieldObj->Description || '' %>" size="80" /></td></tr>

<tr><td class="label"><&|/l&>Type</&></td>
<td><& /Admin/Elements/SelectCustomFieldType, 
        Name => "TypeComposite", 
        Default => $CustomFieldObj->TypeComposite, &>
</td></tr>

% if ( $CustomFieldObj->Id and $CustomFieldObj->IsSelectionType and RT->Config->Get('CustomFieldValuesSources') and ( scalar(@{RT->Config->Get('CustomFieldValuesSources')}) > 0 ) ) {
<tr><td class="label"><&|/l&>Field values source:</&></td><td>
<& /Admin/Elements/EditCustomFieldValuesSource, CustomField => $CustomFieldObj &>
</td></tr>
% }

<tr><td class="label"><&|/l&>Applies to</&></td>
<td><& /Admin/Elements/SelectCustomFieldLookupType, 
        Name => "LookupType", 
        Default => $CustomFieldObj->LookupType, &>
</td></tr>

<tr><td class="label"><&|/l&>Validation</&></td>
<td><& /Widgets/ComboBox,
    Name    => 'Pattern',
    Default => $CustomFieldObj->Pattern,
    Size    => 20,
    Values  => \@CFvalidations,
&></td></tr>

<tr><td class="label"><&|/l&>Link values to</&></td><td>
<input size="60" name="LinkValueTo"  value="<% $CustomFieldObj->LinkValueTo || '' %>" />
<div class="hints">
<&|/l&>RT can make this custom field's values into hyperlinks to another service.</&>
<&|/l&>Fill in this field with a URL.</&>
<&|/l&>RT will replace <tt>__id__</tt> and <tt>__CustomField__</tt> with the record id and custom field value, respectively</&>
</div></td></tr>

<tr><td class="label"><&|/l&>Include page</&></td><td>
<input size="60" name="IncludeContentForValue" value="<% $CustomFieldObj->IncludeContentForValue || '' %>" />
<div class="hints">
<&|/l&>RT can include content from another web service when showing this custom field.</&>
<&|/l&>Fill in this field with a URL.</&>
<&|/l&>RT will replace <tt>__id__</tt> and <tt>__CustomField__</tt> with the record id and custom field value, respectively</&>
<i><&|/l&>Some browsers may only load content from the same domain as your RT server.</&></i>
</div></td></tr>

<tr><td class="label">&nbsp;</td><td>
<input type="hidden" class="hidden" name="SetEnabled" value="1" />
<input type="checkbox" class="checkbox" name="Enabled" value="1" <% $EnabledChecked |n%> />
<&|/l&>Enabled (Unchecking this box disables this custom field)</&>
</td></tr>

</table>

% if ( $CustomFieldObj->Id && $CustomFieldObj->IsSelectionType && !$CustomFieldObj->IsExternalValues ) {
<h2><&|/l&>Values</&></h2>
<div>
<& /Admin/Elements/EditCustomFieldValues, CustomField => $CustomFieldObj &>
<& /Admin/Elements/AddCustomFieldValue, CustomField => $CustomFieldObj &>
</div>
% }

<& /Elements/Submit, Name => 'Update', Label => $id eq 'new'? loc('Create'): loc('Save Changes') &>

</form>
<%INIT>
my ($title, @results, $Disabled);

my $CustomFieldObj = RT::CustomField->new( $session{'CurrentUser'} );
my $current_tab = 'Admin/CustomFields/Modify.html';

unless ( $id ) {
    $title = loc("Create a CustomField");
    $id    = 'new';
    $current_tab .= '?Create=1';
}
else {
    if ( $id eq 'new' ) {
        my ( $val, $msg ) = $CustomFieldObj->Create(
            Name          => $Name,
            TypeComposite => $TypeComposite,
            LookupType    => $LookupType,
            Description   => $Description,
            Pattern       => $Pattern,
            LinkValueTo   => $LinkValueTo,
            IncludeContentForValue => $IncludeContentForValue,
        );
        $m->comp( "/Elements/Error", Why => loc( "Could not create CustomField", $msg ) ) unless $val;
        push @results, $msg;
        $title = loc( 'Created CustomField [_1]', $CustomFieldObj->Name );
    } else {
        $CustomFieldObj->Load( $id ) || $m->comp("/Elements/Error", Why => loc('No CustomField') );
        $title = loc( 'Editing CustomField [_1]', $CustomFieldObj->Name );
    }
    $current_tab .= "?id=$id";
}

if ( $ARGS{'Update'} && $id ne 'new' ) {

    #we're asking about enabled on the web page but really care about disabled.
    $ARGS{'Disabled'} = $Disabled = $Enabled? 0 : 1;

    my @attribs = qw(Disabled Pattern Name TypeComposite LookupType Description LinkValueTo IncludeContentForValue);
    push @results, UpdateRecordObject(
        AttributesRef => \@attribs,
        Object        => $CustomFieldObj,
        ARGSRef       => \%ARGS
    );
    $CustomFieldObj->SetValuesClass( $ValuesClass );

    my $paramtag = "CustomField-". $CustomFieldObj->Id ."-Value";
    # Delete any fields that want to be deleted
    foreach my $key ( keys %ARGS ) {
        next unless $key =~ /^Delete-$paramtag-(\d+)$/o;
        my ($val, $msg) = $CustomFieldObj->DeleteValue( $1 );
        push (@results, $msg);
    }

    # Update any existing values
    my $values = $CustomFieldObj->ValuesObj;
    while ( my $value = $values->Next ) {
        foreach my $attr qw(Name Description SortOrder Category) {
            my $param = "$paramtag-". $value->Id ."-". $attr;
            next unless exists $ARGS{$param};
            next if ($value->$attr()||'') eq ($ARGS{$param}||'');

            my $mutator = "Set$attr";
            my ($id, $msg) = $value->$mutator( $ARGS{$param} );
            push (@results, $msg);
        }
    }

    # Add any new values
    if ( defined $ARGS{ $paramtag ."-new-Name" } && length $ARGS{ $paramtag ."-new-Name" } ) {
        my ($id, $msg) = $CustomFieldObj->AddValue(
            map { $_ => $ARGS{ $paramtag ."-new-$_" } }
                qw( Name Description SortOrder Category )
        );
        push (@results, $msg);
    }
}

$id = $CustomFieldObj->id if $CustomFieldObj->id;

my $EnabledChecked = qq[checked="checked"];
$EnabledChecked = '' if $CustomFieldObj->Disabled;

my @CFvalidations = (
    '(?#Mandatory).',
    '(?#Digits)^[\d.]+$',
    '(?#Year)^[12]\d{3}$',
);

$m->callback(CallbackName => 'ValidationPatterns', Values => \@CFvalidations);

</%INIT>
<%ARGS>
$id => undef
$TypeComposite => undef
$LookupType => undef
$MaxValues => undef
$SortOrder => undef
$Description => undef
$Pattern => undef
$Name => undef
$SetEnabled => undef
$Enabled => 0
$ValuesClass => 'RT::CustomFieldValues'
$LinkValueTo => undef
$IncludeContentForValue => undef
</%ARGS>
