    {-# OPTIONS_GHC -fno-warn-missing-signatures #-}

    -----------------------------------------------------------------------------
    -- |
    -- Module       : XMonad.Config.Gnome
    -- Copyright    : (c) Spencer Janssen <spencerjanssen@gmail.com>
    -- License      : BSD
    --
    -- Maintainer   : Spencer Janssen <spencerjanssen@gmail.com>
    --
    -- This module provides a config suitable for use with the GNOME desktop
    -- environment.

    module XMonad.Config.Gnome (
        -- * Usage
        -- -- $usage
        gnomeConfig,
        gnomeRun
        ) where

    import XMonad
    import XMonad.Config.Desktop

    import qualified Data.Map as M

    -- $usage
    -- To use this module, start with the following @~\/.xmonad\/xmonad.hs@:
    --
    -- > import XMonad
    -- > import XMonad.Config.Gnome
    -- >
    -- > main = xmonad gnomeConfig
    --

    gnomeConfig = desktopConfig
        { terminal = "gnome-terminal"
        , keys     = \c -> gnomeKeys c `M.union` keys desktopConfig c }

    gnomeKeys (XConfig {modMask = modm}) = M.fromList $
        [ ((modm, xK_p), gnomeRun)
        , ((modm .|. shiftMask, xK_q), spawn "gnome-session-save --kill") ]

    -- | Launch the "Run Application" dialog.  gnome-panel must be running for this
    -- to work.
    gnomeRun :: X ()
    gnomeRun = withDisplay $ \dpy -> do
        rw <- asks theRoot
        gnome_panel <- getAtom "_GNOME_PANEL_ACTION"
        panel_run   <- getAtom "_GNOME_PANEL_ACTION_RUN_DIALOG"

        io $ allocaXEvent $ \e -> do
            setEventType e clientMessage
            setClientMessageEvent e rw gnome_panel 32 panel_run 0
            sendEvent dpy rw False structureNotifyMask e
            sync dpy False