Qt Reference Documentation

[Previous: States] [Next: Structuring Data with Models]

# QML Animation and Transitions

## Animation and Transitions Elements

- Transition - Animates transitions during state changes
- SequentialAnimation - Runs animations sequentially
- ParallelAnimation - Runs animations in parallel
- Behavior - Specifies a default animation for property changes
- PropertyAction - Sets immediate property changes during animation
- PauseAnimation - Introduces a pause in an animation
- SmoothedAnimation - Allows a property to smoothly track a value
- SpringAnimation - Allows a property to track a value in a spring-like motion
- ScriptAction - Runs scripts during an animation

Elements that animate properties based on data types

- PropertyAnimation - Animates property changes
- NumberAnimation - Animates properties of type qreal
- Vector3dAnimation - Animates properties of type QVector3d
- ColorAnimation - Animates color changes
- RotationAnimation - Animates rotations
- ParentAnimation - Animates parent changes
- AnchorAnimation - Animates anchor changes

In QML, animations are created by applying animation elements to property values. Animation elements will interpolate property values to create smooth transitions. As well, state transitions may assign animations to state changes.

To create an animation, use an appropriate animation element for the type of the property that is to be animated, and apply the animation depending on the type of behavior that is required.

## Triggering Animations

There are several ways of setting animation to an object.

### Direct Property Animation

To create an immediate movement or animated movement, set the property value directly. This may be done in signal handlers or attached properties.

     Rectangle {
         id: blob
         width: 75; height: 75
         color: "blue"

         MouseArea {
             anchors.fill: parent
             onClicked: blob.color = "green"
         }
     }

However, to create more control, property animations apply smooth movements by interpolating values between property value changes. Property animations provide timing controls and allows different interpolations through easing curves.

     Rectangle {
         id: flashingblob
         width: 75; height: 75
         color: "blue"
         opacity: 1.0

         MouseArea {
             anchors.fill: parent
             onClicked: {
                 animateColor.start()
                 animateOpacity.start()
             }
         }

         PropertyAnimation {id: animateColor; target: flashingblob; properties: "color"; to: "green"; duration: 100}

         NumberAnimation {
             id: animateOpacity
             target: flashingblob
             properties: "opacity"
             from: 0.99
             to: 1.0
             loops: Animation.Infinite
             easing {type: Easing.OutBack; overshoot: 500}
        }
     }

Specialized property animation elements have more efficient implementations than the PropertyAnimation element. They are for setting animations to different QML types such as `int`, `color`, and rotations. Similarly, the ParentAnimation can animate parent changes.

See the Controlling Animations section for more information about the different animation properties.

### Transitions during State Changes

States are property configurations where a property may have different values to reflect different states. State changes introduce abrupt property changes; animations smooth transitions to produce visually appealing state changes.

The Transition element can contain animation elements to interpolate property changes caused by state changes. To assign the transition to an object, bind it to the `transitions` property.

A button might have two states, the `pressed` state when the user clicks on the button and a `released` state when the user releases the button. We can assign different property configurations for each state. A transition would animate the change from the `pressed` state to the `released` state. Likewise, there would be an animation during the change from the `released` state to the `pressed` state.

     Rectangle {
         width: 75; height: 75
         id: button
         state: "RELEASED"

         MouseArea {
             anchors.fill: parent
             onPressed: button.state = "PRESSED"
             onReleased: button.state = "RELEASED"
         }

         states: [
             State {
                 name: "PRESSED"
                 PropertyChanges { target: button; color: "lightblue"}
             },
             State {
                 name: "RELEASED"
                 PropertyChanges { target: button; color: "lightsteelblue"}
             }
         ]

         transitions: [
             Transition {
                 from: "PRESSED"
                 to: "RELEASED"
                 ColorAnimation { target: button; duration: 100}
             },
             Transition {
                 from: "RELEASED"
                 to: "PRESSED"
                 ColorAnimation { target: button; duration: 100}
             }
         ]
     }

Binding the `to` and `from` properties to the state's name will assign that particular transition to the state change. For simple or symmetric transitions, setting the to `to` property to the wild card symbol, "`*`", denotes that the transition applies to any state change.

         transitions:
             Transition {
                 to: "*"
                 ColorAnimation { target: button; duration: 100}
             }

### Default Animation as Behaviors

Default property animations are set using behavior animations. Animations declared in Behavior elements apply to the property and animates any property value changes. However, Behavior elements have an `enabled` property to purposely enable or disable the behavior animations.

A ball component might have a behavior animation assigned to its `x`, `y`, and `color` properties. The behavior animation could be set up to simulate an elastic effect. In effect, this behavior animation would apply the elastic effect to the properties whenever the ball moves.

     Rectangle {
         width: 75; height: 75; radius: width
         id: ball
         color: "salmon"

         Behavior on x {
             NumberAnimation {
                 id: bouncebehavior
                 easing {
                     type: Easing.OutElastic
                     amplitude: 1.0
                     period: 0.5
                 }
             }
         }
         Behavior on y {
             animation: bouncebehavior
         }
         Behavior {
             ColorAnimation { target: ball; duration: 100 }
         }
     }

There are several methods of assigning behavior animations to properties. The `Behavior on <property>` declaration is a convenient way of assigning a behavior animation onto a property.

See the Behaviors example for a demonstration of behavioral animations.

## Playing Animations in Parallel or in Sequence

Animations can run in parallel or in sequence. Parallel animations will play a group of animations at the same time while sequential animations play a group of animations in order: one after the other. Grouping animations in SequentialAnimation and ParallelAnimation will play the animations in sequence or in parallel.

A banner component may have several icons or slogans to display, one after the other. The `opacity` property could transform to `1.0` denoting an opaque object. Using the SequentialAnimation element, the opacity animations will play after the preceding animation finishes. The ParallelAnimation element will play the animations at the same time.

     Rectangle {
         id: banner
         width: 150; height: 100; border.color: "black"

         Column {
             anchors.centerIn: parent
             Text {
                 id: code
                 text: "Code less."
                 opacity: 0.01
             }
             Text {
                 id: create
                 text: "Create more."
                 opacity: 0.01
             }
             Text {
                 id: deploy
                 text: "Deploy everywhere."
                 opacity: 0.01
             }
         }

         MouseArea {
             anchors.fill: parent
             onPressed: playbanner.start()
         }

         SequentialAnimation {
             id: playbanner
             running: false
             NumberAnimation { target: code; property: "opacity"; to: 1.0; duration: 200}
             NumberAnimation { target: create; property: "opacity"; to: 1.0; duration: 200}
             NumberAnimation { target: deploy; property: "opacity"; to: 1.0; duration: 200}
         }
     }

Once individual animations are placed into a SequentialAnimation or ParallelAnimation, they can no longer be started and stopped independently. The sequential or parallel animation must be started and stopped as a group.

The SequentialAnimation element is also useful for playing transition animations because animations are played in parallel inside transitions.

See the Animation basics example for a demonstration of creating and combining multiple animations in QML.

## Controlling Animations

There are different methods to control animations.

### Animation Playback

All animation elements inherit from the Animation element. It is not possible to create Animation objects; instead, this element provides the essential properties and methods for animation elements. Animation elements have `start()`, `stop()`, `resume()`, `pause()`, `restart()`, and `complete()` -- all of these methods control the execution of animations.

### Easing

Easing curves define how the animation will interpolate between the start value and the end value. Different easing curves might go beyond the defined range of interpolation. The easing curves simplify the creation of animation effects such as bounce effects, acceleration, deceleration, and cyclical animations.

A QML object may have different easing curve for each property animation. There are also different parameters to control the curve, some of which are exclusive to a particular curve. For more information about the easing curves, visit the easing documentation.

The easing example visually demonstrates each of the different easing types.

### Other Animation Elements

In addition, QML provides several other elements useful for animation:

- PauseAnimation: enables pauses during animations
- ScriptAction: allows JavaScript to be executed during an animation, and can be used together with StateChangeScript to reused existing scripts
- PropertyAction: changes a property immediately during an animation, without animating the property change

These are specialized animation elements that animate different property types

- SmoothedAnimation: a specialized NumberAnimation that provides smooth changes in animation when the target value changes
- SpringAnimation: provides a spring-like animation with specialized attributes such as mass, damping and epsilon
- ParentAnimation: used for animating a parent change (see ParentChange)
- AnchorAnimation: used for animating an anchor change (see AnchorChanges)