## Unit srfi-1

SRFI 1 (list library) procedures. A few procedures that can be found in R5RS, such as `car` and `append`, are omitted below. For more information, see the original SRFI 1 document.

## The procedures

The templates given below obey the following conventions for procedure formals:

LIST | A proper (finite, nil-terminated) list
CLIST | A proper or circular list
FLIST | A finite (proper or dotted) list
PAIR | A pair
X, Y, D, A | Any value
OBJECT, VALUE | Any value
N, I | A natural number (an integer >= 0)
PROC | A procedure
PRED | A procedure whose return value is treated as a boolean
= | A boolean procedure taking two arguments

It is an error to pass a circular or dotted list to a procedure not defined to accept such an argument.

### Constructors

`(xcons d a) -> pair` procedure

      (lambda (d a) (cons a d))

  Of utility only as a value to be conveniently passed to higher-order procedures.

      (xcons '(b c) 'a) => (a b c)

  The name stands for "eXchanged CONS."

`(cons* elt_1 elt_2 ...) -> object` procedure

  Like `list`, but the last argument provides the tail of the constructed list, returning

  `(cons ELT_1 (cons ELT_2 (cons ... ELT_N)))`

  This function is called `list*` in Common Lisp and about half of the Schemes that provide it, and `cons*` in the other half.

      (cons* 1 2 3 4) => (1 2 3 . 4)
      (cons* 1) => 1

`(make-list n [fill]) -> list` procedure

  Returns an N-element list, whose elements are all the value FILL. If the FILL argument is not given, the elements of the list may be arbitrary values.

      (make-list 4 'c) => (c c c c)

`(list-tabulate n init-proc) -> list` procedure

  Returns an N-element list. Element I of the list, where 0 <= I < N, is produced by `(INIT-PROC I)`. No guarantee is made about the dynamic order in which INIT-PROC is applied to these indices.

      (list-tabulate 4 values) => (0 1 2 3)

`(list-copy flist) -> flist` procedure

  Copies the spine of the argument.

`(circular-list elt_1 elt_2 ...) -> list` procedure

  Constructs a circular list of the elements.

      (circular-list 'z 'q) => (z q z q z q ...)

`(iota count [start step]) -> list` procedure

  Returns a list containing the elements

      (START START+STEP ... START+(COUNT-1)*STEP)

  The START and STEP parameters default to 0 and 1, respectively. This procedure takes its name from the APL primitive.

      (iota 5) => (0 1 2 3 4)
      (iota 5 0 -0.1) => (0 -0.1 -0.2 -0.3 -0.4)

### Predicates

Note: the predicates `proper-list?`, `circular-list?`, and `dotted-list?` partition the entire universe of Scheme values.

`(proper-list? x) -> boolean` procedure

  Returns true iff X is a proper list -- a finite, nil-terminated list.

  More carefully: The empty list is a proper list. A pair whose cdr is a proper list is also a proper list:

      <proper-list> ::= ()                            (Empty proper list)
                    |   (cons <x> <proper-list>)      (Proper-list pair)

  Note that this definition rules out circular lists. This function is required to detect this case and return false.

  Nil-terminated lists are called "proper" lists by R5RS and Common Lisp. The opposite of proper is improper.

  R5RS binds this function to the variable `list?`.

      (not (proper-list? X)) = (or (dotted-list? X) (circular-list? X))

`(circular-list? x) -> boolean` procedure

  True if X is a circular list. A circular list is a value such that for every N >= 0, cdr^N(X) is a pair.

  Terminology: The opposite of circular is finite.

      (not (circular-list? X)) = (or (proper-list? X) (dotted-list? X))

`(dotted-list? x) -> boolean` procedure

  True if X is a finite, non-nil-terminated list. That is, there exists an N >= 0 such that cdr^N(X) is neither a pair nor (). This includes non-pair, non-() values (e.g. symbols, numbers), which are considered to be dotted lists of length 0.

      (not (dotted-list? X)) = (or (proper-list? X) (circular-list? X))

`(null-list? list) -> boolean` procedure

  LIST is a proper or circular list. This procedure returns true if the argument is the empty list (), and false otherwise. It is an error to pass this procedure a value which is not a proper or circular list. This procedure is recommended as the termination condition for list-processing procedures that are not defined on dotted lists.

`(not-pair? x) -> boolean` procedure

      (lambda (x) (not (pair? x)))

  Provided as a procedure as it can be useful as the termination condition for list-processing procedures that wish to handle all finite lists, both proper and dotted.

`(list= elt= list_1 ...) -> boolean` procedure

  Determines list equality, given an element-equality procedure. Proper list A equals proper list B if they are of the same length, and their corresponding elements are equal, as determined by ELT=. If the element-comparison procedure's first argument is from LIST_I, then its second argument is from LIST_I+1, i.e. it is always called as `(ELT= A B)` for A an element of list A, and B an element of list B.

  In the N-ary case, every LIST_I is compared to LIST_I+1 (as opposed, for example, to comparing LIST_1 to every LIST_I, for I>1). If there are no list arguments at all, `list=` simply returns true.

  It is an error to apply `list=` to anything except proper lists. While implementations may choose to extend it to circular lists, note that it cannot reasonably be extended to dotted lists, as it provides no way to specify an equality procedure for comparing the list terminators.

  Note that the dynamic order in which the ELT= procedure is applied to pairs of elements is not specified. For example, if `list=` is applied to three lists, A, B, and C, it may first completely compare A to B, then compare B to C, or it may compare the first elements of A and B, then the first elements of B and C, then the second elements of A and B, and so forth.

  The equality procedure must be consistent with `eq?`. That is, it must be the case that

  `(eq? X Y)` => `(ELT= X Y)`.

  Note that this implies that two lists which are `eq?` are always LIST=, as well; implementations may exploit this fact to "short-cut" the element-by-element comparisons.

      (list= eq?) => #t       ; Trivial cases
      (list= eq? '(a)) => #t

### Selectors

`(first pair) -> object` procedure
`(second pair) -> object` procedure
`(third pair) -> object` procedure
`(fourth pair) -> object` procedure
`(fifth pair) -> object` procedure
`(sixth pair) -> object` procedure
`(seventh pair) -> object` procedure
`(eighth pair) -> object` procedure
`(ninth pair) -> object` procedure
`(tenth pair) -> object` procedure

  Synonyms for `car`, `cadr`, `caddr`, ...

      (third '(a b c d e)) => c

`(car+cdr pair) -> [x y]` procedure

  The fundamental pair deconstructor:

      (lambda (p) (values (car p) (cdr p)))

  This can, of course, be implemented more efficiently by a compiler.

`(take x i) -> list` procedure
`(drop x i) -> object` procedure

  `take` returns the first I elements of list X. `drop` returns all but the first I elements of list X.

      (take '(a b c d e)  2) => (a b)
      (drop '(a b c d e)  2) => (c d e)

  X may be any value -- a proper, circular, or dotted list:

      (take '(1 2 3 . d) 2) => (1 2)
      (drop '(1 2 3 . d) 2) => (3 . d)
      (take '(1 2 3 . d) 3) => (1 2 3)
      (drop '(1 2 3 . d) 3) => d

  For a legal I, `take` and `drop` partition the list in a manner which can be inverted with `append`:

      (append (take X I) (drop X I)) = X

  `drop` is exactly equivalent to performing I cdr operations on X; the returned value shares a common tail with X. If the argument is a list of non-zero length, `take` is guaranteed to return a freshly-allocated list, even in the case where the entire list is taken, e.g. `(take lis (length lis))`.

`(take-right flist i) -> object` procedure
`(drop-right flist i) -> list` procedure

  `take-right` returns the last I elements of FLIST. `drop-right` returns all but the last I elements of FLIST.

      (take-right '(a b c d e) 2) => (d e)
      (drop-right '(a b c d e) 2) => (a b c)

  The returned list may share a common tail with the argument list.

  FLIST may be any finite list, either proper or dotted:

      (take-right '(1 2 3 . d) 2) => (2 3 . d)
      (drop-right '(1 2 3 . d) 2) => (1)
      (take-right '(1 2 3 . d) 0) => d
      (drop-right '(1 2 3 . d) 0) => (1 2 3)

  For a legal I, `take-right` and `drop-right` partition the list in a manner which can be inverted with `append`:

      (append (take FLIST I) (drop FLIST I)) = FLIST

  `take-right`'s return value is guaranteed to share a common tail with FLIST. If the argument is a list of non-zero length, `drop-right` is guaranteed to return a freshly-allocated list, even in the case where nothing is dropped, e.g. `(drop-right lis 0)`.

`(take! x i) -> list` procedure
`(drop-right! flist i) -> list` procedure

  `take!` and `drop-right!` are "linear-update" variants of `take` and `drop-right`: the procedure is allowed, but not required, to alter the argument list to produce the result.

  If X is circular, `take!` may return a shorter-than-expected list:

      (take! (circular-list 1 3 5) 8) => (1 3)
      (take! (circular-list 1 3 5) 8) => (1 3 5 1 3 5 1 3)

`(split-at x i) -> [list object]` procedure
`(split-at! x i) -> [list object]` procedure

  `split-at` splits the list X at index I, returning a list of the first I elements, and the remaining tail. It is equivalent to

      (values (take x i) (drop x i))

  `split-at!` is the linear-update variant. It is allowed, but not required, to alter the argument list to produce the result.

      (split-at '(a b c d e f g h) 3) =>
          (a b c)
          (d e f g h)

`(last pair) -> object` procedure
`(last-pair pair) -> pair` procedure

  `last` returns the last element of the non-empty, finite list PAIR. `last-pair` returns the last pair in the non-empty, finite list PAIR.

      (last '(a b c)) => c
      (last-pair '(a b c)) => (c)

### Miscellaneous

`(length+ clist) -> integer or #f` procedure

  Both `length` and `length+` return the length of the argument. It is an error to pass a value to `length` which is not a proper list (finite and nil-terminated). In particular, this means an implementation may diverge or signal an error when `length` is applied to a circular list.

  `length+`, on the other hand, returns `#F` when applied to a circular list.

  The length of a proper list is a non-negative integer N such that `cdr` applied N times to the list produces the empty list.

`(append! list_1 ...) -> list` procedure

  `append!` is the "linear-update" variant of `append` -- it is allowed, but not required, to alter cons cells in the argument lists to construct the result list. The last argument is never altered; the result list shares structure with this parameter.

`(concatenate list-of-lists) -> value` procedure
`(concatenate! list-of-lists) -> value` procedure

  These functions append the elements of their argument together. That is, `concatenate` returns

      (apply append list-of-lists)

  or, equivalently,

      (reduce-right append '() list-of-lists)

  `concatenate!` is the linear-update variant, defined in terms of `append!` instead of `append`.

  Note that some Scheme implementations do not support passing more than a certain number (e.g., 64) of arguments to an n-ary procedure. In these implementations, the `(apply append ...)` idiom would fail when applied to long lists, but `concatenate` would continue to function properly.

  As with `append` and `append!`, the last element of the input list may be any value at all.

`(reverse! list) -> list` procedure

  `reverse!` is the linear-update variant of `reverse`. It is permitted, but not required, to alter the argument's cons cells to produce the reversed list.

`(append-reverse rev-head tail) -> list` procedure
`(append-reverse! rev-head tail) -> list` procedure

  `append-reverse` returns `(append (reverse REV-HEAD) TAIL)`. It is provided because it is a common operation -- a common list-processing style calls for this exact operation to transfer values accumulated in reverse order onto the front of another list, and because the implementation is significantly more efficient than the simple composition it replaces. (But note that this pattern of iterative computation followed by a reverse can frequently be rewritten as a recursion, dispensing with the `reverse` and `append-reverse` steps, and shifting temporary, intermediate storage from the heap to the stack, which is typically a win for reasons of cache locality and eager storage reclamation.)

  `append-reverse!` is just the linear-update variant -- it is allowed, but not required, to alter REV-HEAD's cons cells to construct the result.

`(zip clist_1 clist_2 ...) -> list` procedure

      (lambda lists (apply map list lists))

  If `zip` is passed N lists, it returns a list as long as the shortest of these lists, each element of which is an N-element list comprised of the corresponding elements from the parameter lists.

      (zip '(one two three)
           '(1 2 3)
           '(odd even odd even odd even odd even))
          => ((one 1 odd) (two 2 even) (three 3 odd))

      (zip '(1 2 3)) => ((1) (2) (3))

  At least one of the argument lists must be finite:

      (zip '(3 1 4 1) (circular-list #f #t))
          => ((3 #f) (1 #t) (4 #f) (1 #t))

`(unzip1 list) -> list` procedure
`(unzip2 list) -> [list list]` procedure
`(unzip3 list) -> [list list list]` procedure
`(unzip4 list) -> [list list list list]` procedure
`(unzip5 list) -> [list list list list list]` procedure

  `unzip1` takes a list of lists, where every list must contain at least one element, and returns a list containing the initial element of each such list. That is, it returns `(map car lists)`. `unzip2` takes a list of lists, where every list must contain at least two elements, and returns two values: a list of the first elements, and a list of the second elements. `unzip3` does the same for the first three elements of the lists, and so forth.

      (unzip2 '((1 one) (2 two) (3 three))) =>
          (1 2 3)
          (one two three)

`(count pred clist_1 clist_2) -> integer` procedure

  PRED is a procedure taking as many arguments as there are lists and returning a single value. It is applied element-wise to the elements of the LISTs, and a count is tallied of the number of elements that produce a true value. This count is returned. `count` is "iterative" in that it is guaranteed to apply PRED to the LIST elements in a left-to-right order. The counting stops when the shortest list expires.

      (count even? '(3 1 4 1 5 9 2 5 6)) => 3
      (count < '(1 2 4 8) '(2 4 6 8 10 12 14 16)) => 3

  At least one of the argument lists must be finite:

      (count < '(3 1 4 1) (circular-list 1 10)) => 2

### Fold, unfold & map

`(fold kons knil clist_1 clist_2 ...) -> value` procedure

  The fundamental list iterator.

  First, consider the single list-parameter case. If CLIST_1 = (E_1 E_2 ... E_N), then this procedure returns

  `(KONS E_N ... (KONS E_2 (KONS E_1 KNIL)) ... )`

  That is, it obeys the (tail) recursion

      (fold KONS KNIL LIS) = (fold KONS (KONS (car LIS) KNIL) (cdr LIS))
      (fold KONS KNIL '()) = KNIL

  Examples:

      (fold + 0 lis)			; Add up the elements of LIS.

      (fold cons '() lis)		; Reverse LIS.

      (fold cons tail rev-head)	; See APPEND-REVERSE.

      ;; How many symbols in LIS?
      (fold (lambda (x count) (if (symbol? x) (+ count 1) count))
            0
            lis)

      ;; Length of the longest string in LIS:
      (fold (lambda (s max-len) (max max-len (string-length s)))
            0
            lis)

  If N list arguments are provided, then the KONS function must take N+1 parameters: one element from each list, and the "seed" or fold state, which is initially KNIL. The fold operation terminates when the shortest list runs out of values:

      (fold cons* '() '(a b c) '(1 2 3 4 5)) => (c 3 b 2 a 1)

  At least one of the list arguments must be finite.

`(fold-right kons knil clist_1 clist_2 ...) -> value` procedure

  The fundamental list recursion operator.

  First, consider the single list-parameter case. If CLIST_1 = `(E_1 E_2 ... E_N)`, then this procedure returns

  `(KONS E_1 (KONS E_2 ... (KONS E_N KNIL)))`

  That is, it obeys the recursion

      (fold-right KONS KNIL LIS) = (KONS (car LIS) (fold-right KONS KNIL (cdr LIS)))
      (fold-right KONS KNIL '()) = KNIL

  Examples:

      (fold-right cons '() lis)		; Copy LIS.

      ;; Filter the even numbers out of LIS.
      (fold-right (lambda (x l) (if (even? x) (cons x l) l)) '() lis))

  If N list arguments are provided, then the KONS function must take N+1 parameters: one element from each list, and the "seed" or fold state, which is initially KNIL. The fold operation terminates when the shortest list runs out of values:

      (fold-right cons* '() '(a b c) '(1 2 3 4 5)) => (a 1 b 2 c 3)

  At least one of the list arguments must be finite.

`(pair-fold kons knil clist_1 clist_2 ...) -> value` procedure

  Analogous to `fold`, but KONS is applied to successive sublists of the lists, rather than successive elements -- that is, KONS is applied to the pairs making up the lists, giving this (tail) recursion:

      (pair-fold KONS KNIL LIS) = (let ((tail (cdr LIS)))
                                    (pair-fold KONS (KONS LIS KNIL) tail))
      (pair-fold KONS KNIL {{'()}}) = KNIL

  For finite lists, the KONS function may reliably apply `set-cdr!` to the pairs it is given without altering the sequence of execution.

  Example:

      ;;; Destructively reverse a list.
      (pair-fold (lambda (pair tail) (set-cdr! pair tail) pair) '() lis))

  At least one of the list arguments must be finite.

`(pair-fold-right kons knil clist_1 clist_2 ...) -> value` procedure

  Holds the same relationship with `fold-right` that `pair-fold` holds with `fold`. Obeys the recursion

      (pair-fold-right KONS KNIL LIS) =
          (KONS LIS (pair-fold-right KONS KNIL (cdr LIS)))
      (pair-fold-right KONS KNIL {{'()}}) = KNIL

  Example:

      (pair-fold-right cons '() '(a b c)) => ((a b c) (b c) (c))

  At least one of the list arguments must be finite.

`(reduce f ridentity list) -> value` procedure

  `reduce` is a variant of `fold`.

  RIDENTITY should be a "right identity" of the procedure F -- that is, for any value X acceptable to F,

      (F X RIDENTITY) = X

  `reduce` has the following definition:

  If LIST = (), return RIDENTITY; Otherwise, return `(fold F (car LIST) (cdr LIST))`.

  ...in other words, we compute `(fold F RIDENTITY LIST)`.

  Note that RIDENTITY is used only in the empty-list case. You typically use `reduce` when applying F is expensive and you'd like to avoid the extra application incurred when `fold` applies F to the head of LIST and the identity value, redundantly producing the same value passed in to F. For example, if F involves searching a file directory or performing a database query, this can be significant. In general, however, `fold` is useful in many contexts where `reduce` is not (consider the examples given in the `fold` definition -- only one of the five folds uses a function with a right identity. The other four may not be performed with `reduce`).

  Note: MIT Scheme and Haskell flip F's arg order for their `reduce` and `fold` functions.

      ;; Take the max of a list of non-negative integers.
      (reduce max 0 nums) ; i.e., (apply max 0 nums)

`(reduce-right f ridentity list) -> value` procedure

  `reduce-right` is the fold-right variant of `reduce`. It obeys the following definition:

      (reduce-right F RIDENTITY '()) = RIDENTITY
      (reduce-right F RIDENTITY '(E_1)) = (F E_1 RIDENTITY) = E_1

      (reduce-right F RIDENTITY '(E_1 E_2 ...)) =
          (F E_1 (reduce F RIDENTITY (E_2 ...)))

  ...in other words, we compute `(fold-right F RIDENTITY LIST)`.

      ;; Append a bunch of lists together.
      ;; I.e., (apply append list-of-lists)
      (reduce-right append '() list-of-lists)

`(unfold p f g seed [tail-gen]) -> list` procedure

  `unfold` is best described by its basic recursion:

      (unfold P F G SEED) =
          (if (P SEED) (TAIL-GEN SEED)
              (cons (F SEED)
                    (unfold P F G (G SEED))))

  P
    Determines when to stop unfolding.
  F
    Maps each seed value to the corresponding list element.
  G
    Maps each seed value to next seed value.
  SEED
    The "state" value for the unfold.
  TAIL-GEN
    Creates the tail of the list; defaults to `(lambda (x) '())`

  In other words, we use G to generate a sequence of seed values

  SEED, G(SEED), G^2(SEED), G^3(SEED), ...

  These seed values are mapped to list elements by F, producing the elements of the result list in a left-to-right order. P says when to stop.

  `unfold` is the fundamental recursive list constructor, just as `fold-right` is the fundamental recursive list consumer. While `unfold` may seem a bit abstract to novice functional programmers, it can be used in a number of ways:

      ;; List of squares: 1^2 ... 10^2
      (unfold (lambda (x) (> x 10))
              (lambda (x) (* x x))
      	(lambda (x) (+ x 1))
      	1)

      (unfold null-list? car cdr lis) ; Copy a proper list.

      ;; Read current input port into a list of values.
      (unfold eof-object? values (lambda (x) (read)) (read))

      ;; Copy a possibly non-proper list:
      (unfold not-pair? car cdr lis
                    values)

      ;; Append HEAD onto TAIL:
      (unfold null-list? car cdr head
                    (lambda (x) tail))

  Interested functional programmers may enjoy noting that `fold-right` and `unfold` are in some sense inverses. That is, given operations KNULL?, KAR, KDR, KONS, and KNIL satisfying

  `(KONS (KAR X) (KDR X))` = `x` and `(KNULL? KNIL)` = `#t`

  then

  `(fold-right KONS KNIL (unfold KNULL? KAR KDR X))` = X

  and

  `(unfold KNULL? KAR KDR (fold-right KONS KNIL X))` = X.

  This combinator sometimes is called an "anamorphism;" when an explicit TAIL-GEN procedure is supplied, it is called an "apomorphism."

`(unfold-right p f g seed [tail]) -> list` procedure

  `unfold-right` constructs a list with the following loop:

      (let lp ((seed seed) (lis tail))
        (if (p seed) lis
            (lp (g seed)
                (cons (f seed) lis))))

  P
    Determines when to stop unfolding.
  F
    Maps each seed value to the corresponding list element.
  G
    Maps each seed value to next seed value.
  SEED
    The "state" value for the unfold.
  TAIL
    list terminator; defaults to `'()`.

  In other words, we use G to generate a sequence of seed values

  SEED, G(SEED), G^2(SEED), G^3(SEED), ...

  These seed values are mapped to list elements by F, producing the elements of the result list in a right-to-left order. P says when to stop.

  `unfold-right` is the fundamental iterative list constructor, just as `fold` is the fundamental iterative list consumer. While `unfold-right` may seem a bit abstract to novice functional programmers, it can be used in a number of ways:

      ;; List of squares: 1^2 ... 10^2
      (unfold-right zero?
                    (lambda (x) (* x x))
                    (lambda (x) (- x 1))
                    10)

      ;; Reverse a proper list.
      (unfold-right null-list? car cdr lis)

      ;; Read current input port into a list of values.
      (unfold-right eof-object? values (lambda (x) (read)) (read))

      ;; (append-reverse rev-head tail)
      (unfold-right null-list? car cdr rev-head tail)

  Interested functional programmers may enjoy noting that `fold` and `unfold-right` are in some sense inverses. That is, given operations KNULL?, KAR, KDR, KONS, and KNIL satisfying

  `(KONS (KAR X) (KDR X))` = `x` and `(KNULL? KNIL)` = `#t`

  then

  `(fold KONS KNIL (unfold-right KNULL? KAR KDR X))` = X

  and

  `(unfold-right KNULL? KAR KDR (fold KONS KNIL X))` = X.

  This combinator presumably has some pretentious mathematical name; interested readers are invited to communicate it to the author.

`(map proc clist_1 clist_2 ...) -> list` procedure

  This procedure is extended from its R5RS specification to allow the arguments to be of unequal length; it terminates when the shortest list runs out.

  At least one of the argument lists must be finite:

      (map + '(3 1 4 1) (circular-list 1 0)) => (4 1 5 1)

`(for-each proc clist_1 clist_2 ...) -> unspecified` procedure

  This procedure is extended from its R5RS specification to allow the arguments to be of unequal length; it terminates when the shortest list runs out.

  At least one of the argument lists must be finite.

`(append-map f clist_1 clist_2 ...) -> value` procedure
`(append-map! f clist_1 clist_2 ...) -> value` procedure

  Equivalent to

  `(apply append (map F CLIST_1 CLIST_2 ...))`

  and

  `(apply append! (map F CLIST_1 CLIST_2 ...))`

  Map F over the elements of the lists, just as in the `map` function. However, the results of the applications are appended together to make the final result. `append-map` uses `append` to append the results together; `append-map!` uses `append!`.

  The dynamic order in which the various applications of F are made is not specified.

  Example:

      (append-map! (lambda (x) (list x (- x))) '(1 3 8))
          => (1 -1 3 -3 8 -8)

  At least one of the list arguments must be finite.

`(map! f list_1 clist_2 ...) -> list` procedure

  Linear-update variant of `map` -- `map!` is allowed, but not required, to alter the cons cells of LIST_1 to construct the result list.

  The dynamic order in which the various applications of F are made is not specified. In the n-ary case, CLIST_2, CLIST_3, ... must have at least as many elements as LIST_1.

`(map-in-order f) clist_1 clist_2 ...) -> list` procedure

  A variant of the `map` procedure that guarantees to apply F across the elements of the LIST_I arguments in a left-to-right order. This is useful for mapping procedures that both have side effects and return useful values.

  At least one of the list arguments must be finite.

`(pair-for-each f clist_1 clist_2 ...) -> unspecific` procedure

  Like `for-each`, but F is applied to successive sublists of the argument lists. That is, F is applied to the cons cells of the lists, rather than the lists' elements. These applications occur in left-to-right order.

  The F procedure may reliably apply `set-cdr!` to the pairs it is given without altering the sequence of execution.

      (pair-for-each (lambda (pair) (display pair) (newline)) '(a b c)) ==>
          (a b c)
          (b c)
          (c)

  At least one of the list arguments must be finite.

`(filter-map f clist_1 clist_2 ...) -> list` procedure

  Like `map`, but only true values are saved.

      (filter-map (lambda (x) (and (number? x) (* x x))) '(a 1 b 3 c 7))
          => (1 9 49)

  The dynamic order in which the various applications of F are made is not specified.

  At least one of the list arguments must be finite.

### Filtering & partitioning

`(filter pred list) -> list` procedure

  Return all the elements of LIST that satisfy predicate PRED. The list is not disordered -- elements that appear in the result list occur in the same order as they occur in the argument list. The returned list may share a common tail with the argument list. The dynamic order in which the various applications of PRED are made is not specified.

      (filter even? '(0 7 8 8 43 -4)) => (0 8 8 -4)

`(partition pred list) -> [list list]` procedure

  Partitions the elements of LIST with predicate PRED, and returns two values: the list of in-elements and the list of out-elements. The list is not disordered -- elements occur in the result lists in the same order as they occur in the argument list. The dynamic order in which the various applications of PRED are made is not specified. One of the returned lists may share a common tail with the argument list.

      (partition symbol? '(one 2 3 four five 6)) =>
          (one four five)
          (2 3 6)

`(remove pred list) -> list` procedure

  Returns LIST without the elements that satisfy predicate PRED:

      (lambda (pred list) (filter (lambda (x) (not (pred x))) list))

  The list is not disordered -- elements that appear in the result list occur in the same order as they occur in the argument list. The returned list may share a common tail with the argument list. The dynamic order in which the various applications of PRED are made is not specified.

      (remove even? '(0 7 8 8 43 -4)) => (7 43)

`(filter! pred list) -> list` procedure
`(partition! pred list) -> [list list]` procedure
`(remove! pred list) -> list` procedure

  Linear-update variants of `filter`, `partition` and `remove`. These procedures are allowed, but not required, to alter the cons cells in the argument list to construct the result lists.

### Searching

The following procedures all search lists for a leftmost element satisfying some criteria. This means they do not always examine the entire list; thus, there is no efficient way for them to reliably detect and signal an error when passed a dotted or circular list. Here are the general rules describing how these procedures work when applied to different kinds of lists:

Proper lists
  The standard, canonical behavior happens in this case.
Dotted lists
  It is an error to pass these procedures a dotted list that does not contain an element satisfying the search criteria. That is, it is an error if the procedure has to search all the way to the end of the dotted list. However, this SRFI does not specify anything at all about the behavior of these procedures when passed a dotted list containing an element satisfying the search criteria. It may finish successfully, signal an error, or perform some third action. Different implementations may provide different functionality in this case; code which is compliant with this SRFI may not rely on any particular behavior. Future SRFI's may refine SRFI-1 to define specific behavior in this case. In brief, SRFI-1 compliant code may not pass a dotted list argument to these procedures.
Circular lists
  It is an error to pass these procedures a circular list that does not contain an element satisfying the search criteria. Note that the procedure is not required to detect this case; it may simply diverge. It is, however, acceptable to search a circular list if the search is successful -- that is, if the list contains an element satisfying the search criteria.

Here are some examples, using the `find` and `any` procedures as canonical representatives:

    ;; Proper list -- success
    (find even? '(1 2 3))	=> 2
    (any  even? '(1 2 3))	=> #t

    ;; proper list -- failure
    (find even? '(1 7 3))	=> #f
    (any  even? '(1 7 3))	=> #f

    ;; Failure is error on a dotted list.
    (find even? '(1 3 . x))	=> error
    (any  even? '(1 3 . x))	=> error

    ;; The dotted list contains an element satisfying the search.
    ;; This case is not specified -- it could be success, an error,
    ;; or some third possibility.
    (find even? '(1 2 . x))	=> error/undefined
    (any  even? '(1 2 . x))	=> error/undefined ; success, error or other.

    ;; circular list -- success
    (find even? (circular-list 1 6 3)) => 6
    (any  even? (circular-list 1 6 3)) => #t

    ;; circular list -- failure is error. Procedure may diverge.
    (find even? (circular-list 1 3)) => error
    (any  even? (circular-list 1 3)) => error

`(find pred clist) -> value` procedure

  Return the first element of CLIST that satisfies predicate PRED; false if no element does.

      (find even? '(3 1 4 1 5 9)) => 4

  Note that `find` has an ambiguity in its lookup semantics -- if `find` returns `#f`, you cannot tell (in general) if it found a `#f` element that satisfied PRED, or if it did not find any element at all. In many situations, this ambiguity cannot arise -- either the list being searched is known not to contain any `#f` elements, or the list is guaranteed to have an element satisfying PRED. However, in cases where this ambiguity can arise, you should use `find-tail` instead of `find` -- `find-tail` has no such ambiguity:

      (cond ((find-tail pred lis) => (lambda (pair) ...)) ; Handle (CAR PAIR)
            (else ...)) ; Search failed.

`(find-tail pred clist) -> pair or false` procedure

  Return the first pair of CLIST whose car satisfies PRED. If no pair does, return false.

  `find-tail` can be viewed as a general-predicate variant of the `member` function.

  Examples:

      (find-tail even? '(3 1 37 -8 -5 0 0)) => (-8 -5 0 0)
      (find-tail even? '(3 1 37 -5)) => #f

      ;; MEMBER X LIS:
      (find-tail (lambda (elt) (equal? x elt)) lis)

  In the circular-list case, this procedure "rotates" the list.

  `Find-tail` is essentially `drop-while`, where the sense of the predicate is inverted: `Find-tail` searches until it finds an element satisfying the predicate; `drop-while` searches until it finds an element that doesn't satisfy the predicate.

`(take-while pred clist) -> list` procedure
`(take-while! pred clist) -> list` procedure

  Returns the longest initial prefix of CLIST whose elements all satisfy the predicate PRED.

  `Take-while!` is the linear-update variant. It is allowed, but not required, to alter the argument list to produce the result.

      (take-while even? '(2 18 3 10 22 9)) => (2 18)

`(drop-while pred clist) -> list` procedure

  Drops the longest initial prefix of CLIST whose elements all satisfy the predicate PRED, and returns the rest of the list.

      (drop-while even? '(2 18 3 10 22 9)) => (3 10 22 9)

  The circular-list case may be viewed as "rotating" the list.

`(span pred clist) -> [list clist]` procedure
`(span! pred list) -> [list list]` procedure
`(break pred clist) -> [list clist]` procedure
`(break! pred list) -> [list list]` procedure

  `Span` splits the list into the longest initial prefix whose elements all satisfy PRED, and the remaining tail. `Break` inverts the sense of the predicate: the tail commences with the first element of the input list that satisfies the predicate.

  In other words: `span` finds the intial span of elements satisfying PRED, and `break` breaks the list at the first element satisfying PRED.

  `Span` is equivalent to

      (values (take-while PRED CLIST)
              (drop-while PRED CLIST))

  `Span!` and `break!` are the linear-update variants. They are allowed, but not required, to alter the argument list to produce the result.

      (span even? '(2 18 3 10 22 9)) =>
        (2 18)
        (3 10 22 9)

      (break even? '(3 1 4 1 5 9)) =>
        (3 1)
        (4 1 5 9)

`(any pred clist_1 clist_2 ...) -> value` procedure

  Applies the predicate across the lists, returning true if the predicate returns true on any application.

  If there are N list arguments CLIST_1 ... CLIST_N, then PRED must be a procedure taking N arguments and returning a boolean result.

  `any` applies PRED to the first elements of the CLIST_I parameters. If this application returns a true value, `any` immediately returns that value. Otherwise, it iterates, applying PRED to the second elements of the CLIST_I parameters, then the third, and so forth. The iteration stops when a true value is produced or one of the lists runs out of values; in the latter case, `any` returns `#f`. The application of PRED to the last element of the lists is a tail call.

  Note the difference between `find` and `any` -- `find` returns the element that satisfied the predicate; `any` returns the true value that the predicate produced.

  Like `every`, `any`'s name does not end with a question mark -- this is to indicate that it does not return a simple boolean (`#t` or `#f`), but a general value.

      (any integer? '(a 3 b 2.7))   => #t
      (any integer? '(a 3.1 b 2.7)) => #f
      (any < '(3 1 4 1 5)
             '(2 7 1 8 2)) => #t

`(every pred clist_1 clist_2 ...) -> value` procedure

  Applies the predicate across the lists, returning true if the predicate returns true on every application.

  If there are N list arguments CLIST_1 ... CLIST_N, then PRED must be a procedure taking N arguments and returning a boolean result.

  `every` applies PRED to the first elements of the CLIST_I parameters. If this application returns false, `every` immediately returns false. Otherwise, it iterates, applying PRED to the second elements of the CLIST_I parameters, then the third, and so forth. The iteration stops when a false value is produced or one of the lists runs out of values. In the latter case, `every` returns the true value produced by its final application of PRED. The application of PRED to the last element of the lists is a tail call.

  If one of the CLIST_I has no elements, `every` simply returns `#t`.

  Like `any`, `every`'s name does not end with a question mark -- this is to indicate that it does not return a simple boolean (`#t` or `#f`), but a general value.

`(list-index pred clist_1 clist_2 ...) -> integer or false` procedure

  Return the index of the leftmost element that satisfies PRED.

  If there are N list arguments CLIST_1 ... CLIST_N, then PRED must be a function taking N arguments and returning a boolean result.

  `list-index` applies PRED to the first elements of the CLIST_I parameters. If this application returns true, `list-index` immediately returns zero. Otherwise, it iterates, applying PRED to the second elements of the CLIST_I parameters, then the third, and so forth. When it finds a tuple of list elements that cause PRED to return true, it stops and returns the zero-based index of that position in the lists.

  The iteration stops when one of the lists runs out of values; in this case, `list-index` returns `#f`.

      (list-index even? '(3 1 4 1 5 9)) => 2
      (list-index < '(3 1 4 1 5 9 2 5 6) '(2 7 1 8 2)) => 1
      (list-index = '(3 1 4 1 5 9 2 5 6) '(2 7 1 8 2)) => #f

`(member x list [=]) -> list` procedure

  `member` is extended from its R5RS definition to allow the client to pass in an optional equality procedure = used to compare keys.

  The comparison procedure is used to compare the elements E_I of LIST to the key X in this way:

  `(= X E_I) ; list is (E1 ... En)`

  That is, the first argument is always X, and the second argument is one of the list elements. Thus one can reliably find the first element of LIST that is greater than five with `(member 5 LIST <)`

  Note that fully general list searching may be performed with the `find-tail` and `find` procedures, e.g.

      (find-tail even? list) ; Find the first elt with an even key.

### Deletion

`(delete x list [=]) -> list` procedure
`(delete! x list [=]) -> list` procedure

  `delete` uses the comparison procedure =, which defaults to `equal?`, to find all elements of LIST that are equal to X, and deletes them from LIST. The dynamic order in which the various applications of = are made is not specified.

  The list is not disordered -- elements that appear in the result list occur in the same order as they occur in the argument list. The result may share a common tail with the argument list.

  Note that fully general element deletion can be performed with the `remove` and `remove!` procedures, e.g.:

      ;; Delete all the even elements from LIS:
      (remove even? lis)

  The comparison procedure is used in this way: `(= X E_I)`. That is, X is always the first argument, and a list element is always the second argument. The comparison procedure will be used to compare each element of LIST exactly once; the order in which it is applied to the various E_I is not specified. Thus, one can reliably remove all the numbers greater than five from a list with `(delete 5 list <)`

  `delete!` is the linear-update variant of `delete`. It is allowed, but not required, to alter the cons cells in its argument list to construct the result.

`(delete-duplicates list [=]) -> list` procedure
`(delete-duplicates! list [=]) -> list` procedure

  `delete-duplicates` removes duplicate elements from the list argument. If there are multiple equal elements in the argument list, the result list only contains the first or leftmost of these elements in the result. The order of these surviving elements is the same as in the original list -- `delete-duplicates` does not disorder the list (hence it is useful for "cleaning up" association lists).

  The = parameter is used to compare the elements of the list; it defaults to `equal?`. If X comes before Y in LIST, then the comparison is performed `(= X Y)`. The comparison procedure will be used to compare each pair of elements in LIST no more than once; the order in which it is applied to the various pairs is not specified.

  Implementations of `delete-duplicates` are allowed to share common tails between argument and result lists -- for example, if the list argument contains only unique elements, it may simply return exactly this list.

  Be aware that, in general, `delete-duplicates` runs in time O(n^2) for N-element lists. Uniquifying long lists can be accomplished in O(n lg n) time by sorting the list to bring equal elements together, then using a linear-time algorithm to remove equal elements. Alternatively, one can use algorithms based on element-marking, with linear-time results.

  `delete-duplicates!` is the linear-update variant of `delete-duplicates`; it is allowed, but not required, to alter the cons cells in its argument list to construct the result.

      (delete-duplicates '(a b a c a b c z)) => (a b c z)

      ;; Clean up an alist:
      (delete-duplicates '((a . 3) (b . 7) (a . 9) (c . 1))
                         (lambda (x y) (eq? (car x) (car y))))
          => ((a . 3) (b . 7) (c . 1))

### Association lists

An "association list" (or "alist") is a list of pairs. The car of each pair contains a key value, and the cdr contains the associated data value. They can be used to construct simple look-up tables in Scheme. Note that association lists are probably inappropriate for performance-critical use on large data; in these cases, hash tables or some other alternative should be employed.

`(assoc key alist [=]) -> pair or #f` procedure

  `assoc` is extended from its R5RS definition to allow the client to pass in an optional equality procedure = used to compare keys.

  The comparison procedure is used to compare the elements E_I of LIST to the KEY parameter in this way:

  `(= KEY (car E_I)) ; list is (E1 ... En)`

  That is, the first argument is always KEY, and the second argument is one of the list elements. Thus one can reliably find the first entry of ALIST whose key is greater than five with `(assoc 5 ALIST <)`

  Note that fully general alist searching may be performed with the `find-tail` and `find` procedures, e.g.

      ;; Look up the first association in ALIST with an even key:
      (find (lambda (a) (even? (car a))) alist)

`(alist-cons key datum alist) -> alist` procedure

      (lambda (key datum alist) (cons (cons key datum) alist))

  Cons a new alist entry mapping KEY -> DATUM onto ALIST.

`(alist-copy alist) -> alist` procedure

  Make a fresh copy of ALIST. This means copying each pair that forms an association as well as the spine of the list, i.e.

      (lambda (a) (map (lambda (elt) (cons (car elt) (cdr elt))) a))

`(alist-delete key alist [=]) -> alist` procedure
`(alist-delete! key alist [=]) -> alist` procedure

  `alist-delete` deletes all associations from ALIST with the given KEY, using key-comparison procedure =, which defaults to `equal?`. The dynamic order in which the various applications of = are made is not specified.

  Return values may share common tails with the ALIST argument. The alist is not disordered -- elements that appear in the result alist occur in the same order as they occur in the argument alist.

  The comparison procedure is used to compare the element keys K_I of ALIST's entries to the KEY parameter in this way: `(= KEY K_I)`. Thus, one can reliably remove all entries of ALIST whose key is greater than five with `(alist-delete 5 ALIST <)`

  `alist-delete!` is the linear-update variant of `alist-delete`. It is allowed, but not required, to alter cons cells from the ALIST parameter to construct the result.

### Set operations on lists

These procedures implement operations on sets represented as lists of elements. They all take an = argument used to compare elements of lists. This equality procedure is required to be consistent with `eq?`. That is, it must be the case that

`(eq? X Y)` => `(= X Y)`.

Note that this implies, in turn, that two lists that are `eq?` are also set-equal by any legal comparison procedure. This allows for constant-time determination of set operations on `eq?` lists.

Be aware that these procedures typically run in time O(N * M) for N- and M-element list arguments. Performance-critical applications operating upon large sets will probably wish to use other data structures and algorithms.

`(lset<= = list_1 ...) -> boolean` procedure

  Returns true iff every LIST_I is a subset of LIST_I+1, using = for the element-equality procedure. List A is a subset of list B if every element in A is equal to some element of B. When performing an element comparison, the = procedure's first argument is an element of A; its second, an element of B.

      (lset<= eq? '(a) '(a b a) '(a b c c)) => #t

      (lset<= eq?) => #t             ; Trivial cases
      (lset<= eq? '(a)) => #t

`(lset= = list_1 list_2 ...) -> boolean` procedure

  Returns true iff every LIST_I is set-equal to LIST_I+1, using = for the element-equality procedure. "Set-equal" simply means that LIST_I is a subset of LIST_I+1, and LIST_I+1 is a subset of LIST_I. The = procedure's first argument is an element of LIST_I; its second is an element of LIST_I+1.

      (lset= eq? '(b e a) '(a e b) '(e e b a)) => #t

      (lset= eq?) => #t               ; Trivial cases
      (lset= eq? '(a)) => #t

`(lset-adjoin = list elt_1 ...) -> list` procedure

  Adds the ELT_I elements not already in the list parameter to the result list. The result shares a common tail with the list parameter. The new elements are added to the front of the list, but no guarantees are made about their order. The = parameter is an equality procedure used to determine if an ELT_I is already a member of LIST. Its first argument is an element of LIST; its second is one of the ELT_I.

  The list parameter is always a suffix of the result -- even if the list parameter contains repeated elements, these are not reduced.

      (lset-adjoin eq? '(a b c d c e) 'a 'e 'i 'o 'u) => (u o i a b c d c e)

`(lset-union = list_1 ...) -> list` procedure

  Returns the union of the lists, using = for the element-equality procedure.

  The union of lists A and B is constructed as follows:

  - If A is the empty list, the answer is B (or a copy of B).
  - Otherwise, the result is initialised to be list A (or a copy of A).
  - Proceed through the elements of list B in a left-to-right order. If B is such an element of B, compare every element R of the current result list to B: `(= R B)`. If all comparisons fail, B is consed onto the front of the result.

  However, there is no guarantee that = will be applied to every pair of arguments from A and B. In particular, if A is `eq`? to B, the operation may immediately terminate.

  In the n-ary case, the two-argument list-union operation is simply folded across the argument lists.

      (lset-union eq? '(a b c d e) '(a e i o u)) =>
          (u o i a b c d e)

      ;; Repeated elements in LIST1 are preserved.
      (lset-union eq? '(a a c) '(x a x)) => (x a a c)

      ;; Trivial cases
      (lset-union eq?) => ()
      (lset-union eq? '(a b c)) => (a b c)

`(lset-intersection = list_1 list_2 ...) -> list` procedure

  Returns the intersection of the lists, using = for the element-equality procedure.

  The intersection of lists A and B is comprised of every element of A that is = to some element of B: `(= A B)`, for A in A, and B in B. Note this implies that an element which appears in B and multiple times in list A will also appear multiple times in the result.

  The order in which elements appear in the result is the same as they appear in LIST_1 -- that is, `lset-intersection` essentially filters LIST_1, without disarranging element order. The result may share a common tail with LIST_1.

  In the n-ary case, the two-argument list-intersection operation is simply folded across the argument lists. However, the dynamic order in which the applications of = are made is not specified. The procedure may check an element of LIST_1 for membership in every other list before proceeding to consider the next element of LIST_1, or it may completely intersect LIST_1 and LIST_2 before proceeding to LIST_3, or it may go about its work in some third order.

      (lset-intersection eq? '(a b c d e) '(a e i o u)) => (a e)

      ;; Repeated elements in LIST1 are preserved.
      (lset-intersection eq? '(a x y a) '(x a x z)) => '(a x a)

      (lset-intersection eq? '(a b c)) => (a b c)     ; Trivial case

`(lset-difference = list_1 list_2 ...) -> list` procedure

  Returns the difference of the lists, using = for the element-equality procedure -- all the elements of LIST_1 that are not = to any element from one of the other LIST_I parameters.

  The = procedure's first argument is always an element of LIST_1; its second is an element of one of the other LIST_I. Elements that are repeated multiple times in the LIST_1 parameter will occur multiple times in the result. The order in which elements appear in the result is the same as they appear in LIST_1 -- that is, `lset-difference` essentially filters LIST_1, without disarranging element order. The result may share a common tail with LIST_1. The dynamic order in which the applications of = are made is not specified. The procedure may check an element of LIST_1 for membership in every other list before proceeding to consider the next element of LIST_1, or it may completely compute the difference of LIST_1 and LIST_2 before proceeding to LIST_3, or it may go about its work in some third order.

      (lset-difference eq? '(a b c d e) '(a e i o u)) => (b c d)

      (lset-difference eq? '(a b c)) => (a b c) ; Trivial case

`(lset-xor = list_1 ...) -> list` procedure

  Returns the exclusive-or of the sets, using = for the element-equality procedure. If there are exactly two lists, this is all the elements that appear in exactly one of the two lists. The operation is associative, and thus extends to the n-ary case -- the elements that appear in an odd number of the lists. The result may share a common tail with any of the LIST_I parameters.

  More precisely, for two lists A and B, A xor B is a list of

  - every element A of A such that there is no element B of B such that `(= A B)`, and
  - every element B of B such that there is no element A of A such that `(= B A)`.

  However, an implementation is allowed to assume that = is symmetric -- that is, that

  `(= A B)` => `(= B A)`.

  This means, for example, that if a comparison `(= A B)` produces true for some A in A and B in B, both A and B may be removed from inclusion in the result.

  In the n-ary case, the binary-xor operation is simply folded across the lists.

      (lset-xor eq? '(a b c d e) '(a e i o u)) => (d c b i o u)

      ;; Trivial cases.
      (lset-xor eq?) => ()
      (lset-xor eq? '(a b c d e)) => (a b c d e)

`(lset-diff+intersection = list_1 list_2 ...) -> [list list]` procedure

  Returns two values -- the difference and the intersection of the lists. Is equivalent to

      (values (lset-difference = LIST_1 LIST_2 ...)
              (lset-intersection = LIST_1
                                   (lset-union = LIST_2 ...)))

  but can be implemented more efficiently.

  The = procedure's first argument is an element of LIST_1; its second is an element of one of the other LIST_I.

  Either of the answer lists may share a common tail with LIST_1. This operation essentially partitions LIST_1.

`(lset-union! = list_1 ...) -> list` procedure
`(lset-intersection! = list_1 list_2 ...) -> list` procedure
`(lset-difference! = list_1 list_2 ...) -> list` procedure
`(lset-xor! = list_1 ...) -> list` procedure
`(lset-diff+intersection! = list_1 list_2 ...) -> [list list]` procedure

  These are linear-update variants. They are allowed, but not required, to use the cons cells in their first list parameter to construct their answer. `lset-union!` is permitted to recycle cons cells from any of its list arguments.

Previous: Unit irregex

Next: Unit srfi-4