# Theory ZornLemma

Up to index of Isabelle/HOL/HOL-Complex/HahnBanach

theory ZornLemma
imports Zorn
begin

    (*  Title:      HOL/Real/HahnBanach/ZornLemma.thy
        ID:         $Id: ZornLemma.thy,v 1.12 2005/06/17 14:13:10 haftmann Exp $
        Author:     Gertrud Bauer, TU Munich
    *)

    header {* Zorn's Lemma *}

    theory ZornLemma imports Zorn begin

    text {*
      Zorn's Lemmas states: if every linear ordered subset of an ordered
      set @{text S} has an upper bound in @{text S}, then there exists a
      maximal element in @{text S}.  In our application, @{text S} is a
      set of sets ordered by set inclusion. Since the union of a chain of
      sets is an upper bound for all elements of the chain, the conditions
      of Zorn's lemma can be modified: if @{text S} is non-empty, it
      suffices to show that for every non-empty chain @{text c} in @{text
      S} the union of @{text c} also lies in @{text S}.
    *}

    theorem Zorn's_Lemma:
      assumes r: "!!c. c ∈ chain S ==> ∃x. x ∈ c ==> \<Union>c ∈ S"
        and aS: "a ∈ S"
      shows "∃y ∈ S. ∀z ∈ S. y ⊆ z --> y = z"
    proof (rule Zorn_Lemma2)
      txt_raw {* \footnote{See
      \url{http://isabelle.in.tum.de/library/HOL/HOL-Complex/Zorn.html}} \isanewline *}
      show "∀c ∈ chain S. ∃y ∈ S. ∀z ∈ c. z ⊆ y"
      proof
        fix c assume "c ∈ chain S"
        show "∃y ∈ S. ∀z ∈ c. z ⊆ y"
        proof cases

          txt {* If @{text c} is an empty chain, then every element in
          @{text S} is an upper bound of @{text c}. *}

          assume "c = {}"
          with aS show ?thesis by fast

          txt {* If @{text c} is non-empty, then @{text "\<Union>c"} is an upper
          bound of @{text c}, lying in @{text S}. *}

        next
          assume c: "c ≠ {}"
          show ?thesis
          proof
            show "∀z ∈ c. z ⊆ \<Union>c" by fast
            show "\<Union>c ∈ S"
            proof (rule r)
              from c show "∃x. x ∈ c" by fast
            qed
          qed
        qed
      qed
    qed

    end

theorem Zorn's_Lemma:

      [| !!c. [| c ∈ chain S; ∃x. x ∈ c |] ==> Union c ∈ S; a ∈ S |]
      ==> ∃y∈S. ∀z∈S. y ⊆ z --> y = z