# Theory FuncSet

Up to index of Isabelle/HOL/HOL-Algebra

theory FuncSet
imports Main
begin

    (*  Title:      HOL/Library/FuncSet.thy
        ID:         $Id: FuncSet.thy,v 1.10 2004/08/18 09:10:01 nipkow Exp $
        Author:     Florian Kammueller and Lawrence C Paulson
    *)

    header {* Pi and Function Sets *}

    theory FuncSet
    imports Main
    begin

    constdefs
      Pi :: "['a set, 'a => 'b set] => ('a => 'b) set"
      "Pi A B == {f. ∀x. x ∈ A --> f x ∈ B x}"

      extensional :: "'a set => ('a => 'b) set"
      "extensional A == {f. ∀x. x~:A --> f x = arbitrary}"

      "restrict" :: "['a => 'b, 'a set] => ('a => 'b)"
      "restrict f A == (%x. if x ∈ A then f x else arbitrary)"

    syntax
      "@Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
      funcset :: "['a set, 'b set] => ('a => 'b) set"      (infixr "->" 60)
      "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)

    syntax (xsymbols)
      "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3Π _∈_./ _)"   10)
      funcset :: "['a set, 'b set] => ('a => 'b) set"  (infixr "->" 60)
      "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3λ_∈_./ _)" [0,0,3] 3)

    syntax (HTML output)
      "@Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3Π _∈_./ _)"   10)
      "@lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3λ_∈_./ _)" [0,0,3] 3)

    translations
      "PI x:A. B" => "Pi A (%x. B)"
      "A -> B" => "Pi A (_K B)"
      "%x:A. f" == "restrict (%x. f) A"

    constdefs
      "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)"
      "compose A g f == λx∈A. g (f x)"

    print_translation {* [("Pi", dependent_tr' ("@Pi", "funcset"))] *}

    subsection{*Basic Properties of @{term Pi}*}

    lemma Pi_I: "(!!x. x ∈ A ==> f x ∈ B x) ==> f ∈ Pi A B"
      by (simp add: Pi_def)

    lemma funcsetI: "(!!x. x ∈ A ==> f x ∈ B) ==> f ∈ A -> B"
      by (simp add: Pi_def)

    lemma Pi_mem: "[|f: Pi A B; x ∈ A|] ==> f x ∈ B x"
      by (simp add: Pi_def)

    lemma funcset_mem: "[|f ∈ A -> B; x ∈ A|] ==> f x ∈ B"
      by (simp add: Pi_def)

    lemma funcset_image: "f ∈ A->B ==> f ` A ⊆ B"
    by (auto simp add: Pi_def)

    lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (∃x∈A. B(x) = {})"
    apply (simp add: Pi_def, auto)
    txt{*Converse direction requires Axiom of Choice to exhibit a function
    picking an element from each non-empty @{term "B x"}*}
    apply (drule_tac x = "%u. SOME y. y ∈ B u" in spec, auto)
    apply (cut_tac P= "%y. y ∈ B x" in some_eq_ex, auto)
    done

    lemma Pi_empty [simp]: "Pi {} B = UNIV"
      by (simp add: Pi_def)

    lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
      by (simp add: Pi_def)

    text{*Covariance of Pi-sets in their second argument*}
    lemma Pi_mono: "(!!x. x ∈ A ==> B x <= C x) ==> Pi A B <= Pi A C"
      by (simp add: Pi_def, blast)

    text{*Contravariance of Pi-sets in their first argument*}
    lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
      by (simp add: Pi_def, blast)

    subsection{*Composition With a Restricted Domain: @{term compose}*}

    lemma funcset_compose:
        "[| f ∈ A -> B; g ∈ B -> C |]==> compose A g f ∈ A -> C"
      by (simp add: Pi_def compose_def restrict_def)

    lemma compose_assoc:
        "[| f ∈ A -> B; g ∈ B -> C; h ∈ C -> D |]
          ==> compose A h (compose A g f) = compose A (compose B h g) f"
      by (simp add: expand_fun_eq Pi_def compose_def restrict_def)

    lemma compose_eq: "x ∈ A ==> compose A g f x = g(f(x))"
      by (simp add: compose_def restrict_def)

    lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
      by (auto simp add: image_def compose_eq)

    subsection{*Bounded Abstraction: @{term restrict}*}

    lemma restrict_in_funcset: "(!!x. x ∈ A ==> f x ∈ B) ==> (λx∈A. f x) ∈ A -> B"
      by (simp add: Pi_def restrict_def)

    lemma restrictI: "(!!x. x ∈ A ==> f x ∈ B x) ==> (λx∈A. f x) ∈ Pi A B"
      by (simp add: Pi_def restrict_def)

    lemma restrict_apply [simp]:
        "(λy∈A. f y) x = (if x ∈ A then f x else arbitrary)"
      by (simp add: restrict_def)

    lemma restrict_ext:
        "(!!x. x ∈ A ==> f x = g x) ==> (λx∈A. f x) = (λx∈A. g x)"
      by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)

    lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
      by (simp add: inj_on_def restrict_def)

    lemma Id_compose:
        "[|f ∈ A -> B;  f ∈ extensional A|] ==> compose A (λy∈B. y) f = f"
      by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)

    lemma compose_Id:
        "[|g ∈ A -> B;  g ∈ extensional A|] ==> compose A g (λx∈A. x) = g"
      by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)

    lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
      by (auto simp add: restrict_def)

    subsection{*Bijections Between Sets*}

    text{*The basic definition could be moved to @{text "Fun.thy"}, but most of
    the theorems belong here, or need at least @{term Hilbert_Choice}.*}

    constdefs
      bij_betw :: "['a => 'b, 'a set, 'b set] => bool"         (*bijective*)
        "bij_betw f A B == inj_on f A & f ` A = B"

    lemma bij_betw_imp_inj_on: "bij_betw f A B ==> inj_on f A"
    by (simp add: bij_betw_def)

    lemma bij_betw_imp_funcset: "bij_betw f A B ==> f ∈ A -> B"
    by (auto simp add: bij_betw_def inj_on_Inv Pi_def)

    lemma bij_betw_Inv: "bij_betw f A B ==> bij_betw (Inv A f) B A"
    apply (auto simp add: bij_betw_def inj_on_Inv Inv_mem)
    apply (simp add: image_compose [symmetric] o_def)
    apply (simp add: image_def Inv_f_f)
    done

    lemma inj_on_compose:
        "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
      by (auto simp add: bij_betw_def inj_on_def compose_eq)

    lemma bij_betw_compose:
        "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
    apply (simp add: bij_betw_def compose_eq inj_on_compose)
    apply (auto simp add: compose_def image_def)
    done

    lemma bij_betw_restrict_eq [simp]:
         "bij_betw (restrict f A) A B = bij_betw f A B"
      by (simp add: bij_betw_def)

    subsection{*Extensionality*}

    lemma extensional_arb: "[|f ∈ extensional A; x∉ A|] ==> f x = arbitrary"
      by (simp add: extensional_def)

    lemma restrict_extensional [simp]: "restrict f A ∈ extensional A"
      by (simp add: restrict_def extensional_def)

    lemma compose_extensional [simp]: "compose A f g ∈ extensional A"
      by (simp add: compose_def)

    lemma extensionalityI:
        "[| f ∈ extensional A; g ∈ extensional A;
          !!x. x∈A ==> f x = g x |] ==> f = g"
      by (force simp add: expand_fun_eq extensional_def)

    lemma Inv_funcset: "f ` A = B ==> (λx∈B. Inv A f x) : B -> A"
      by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)

    lemma compose_Inv_id:
        "bij_betw f A B ==> compose A (λy∈B. Inv A f y) f = (λx∈A. x)"
      apply (simp add: bij_betw_def compose_def)
      apply (rule restrict_ext, auto)
      apply (erule subst)
      apply (simp add: Inv_f_f)
      done

    lemma compose_id_Inv:
        "f ` A = B ==> compose B f (λy∈B. Inv A f y) = (λx∈B. x)"
      apply (simp add: compose_def)
      apply (rule restrict_ext)
      apply (simp add: f_Inv_f)
      done

    subsection{*Cardinality*}

    lemma card_inj: "[|f ∈ A->B; inj_on f A; finite B|] ==> card(A) ≤ card(B)"
    apply (rule card_inj_on_le)
    apply (auto simp add: Pi_def)
    done

    lemma card_bij:
         "[|f ∈ A->B; inj_on f A;
            g ∈ B->A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
    by (blast intro: card_inj order_antisym)

    end

### Basic Properties of @{term Pi}

lemma Pi_I:

      (!!x. x ∈ A ==> f x ∈ B x) ==> f ∈ Pi A B

lemma funcsetI:

      (!!x. x ∈ A ==> f x ∈ B) ==> f ∈ A -> B

lemma Pi_mem:

      [| f ∈ Pi A B; x ∈ A |] ==> f x ∈ B x

lemma funcset_mem:

      [| f ∈ A -> B; x ∈ A |] ==> f x ∈ B

lemma funcset_image:

      f ∈ A -> B ==> f ` A ⊆ B

lemma Pi_eq_empty:

      ((Π x∈A. B x) = {}) = (∃x∈A. B x = {})

lemma Pi_empty:

      Pi {} B = UNIV

lemma Pi_UNIV:

      A -> UNIV = UNIV

lemma Pi_mono:

      (!!x. x ∈ A ==> B x ⊆ C x) ==> Pi A B ⊆ Pi A C

lemma Pi_anti_mono:

      A' ⊆ A ==> Pi A B ⊆ Pi A' B

### Composition With a Restricted Domain: @{term compose}

lemma funcset_compose:

      [| f ∈ A -> B; g ∈ B -> C |] ==> compose A g f ∈ A -> C

lemma compose_assoc:

      [| f ∈ A -> B; g ∈ B -> C; h ∈ C -> D |]
      ==> compose A h (compose A g f) = compose A (compose B h g) f

lemma compose_eq:

      x ∈ A ==> compose A g f x = g (f x)

lemma surj_compose:

      [| f ` A = B; g ` B = C |] ==> compose A g f ` A = C

### Bounded Abstraction: @{term restrict}

lemma restrict_in_funcset:

      (!!x. x ∈ A ==> f x ∈ B) ==> restrict f A ∈ A -> B

lemma restrictI:

      (!!x. x ∈ A ==> f x ∈ B x) ==> restrict f A ∈ Pi A B

lemma restrict_apply:

      restrict f A x = (if x ∈ A then f x else arbitrary)

lemma restrict_ext:

      (!!x. x ∈ A ==> f x = g x) ==> restrict f A = restrict g A

lemma inj_on_restrict_eq:

      inj_on (restrict f A) A = inj_on f A

lemma Id_compose:

      [| f ∈ A -> B; f ∈ extensional A |] ==> compose A (λy∈B. y) f = f

lemma compose_Id:

      [| g ∈ A -> B; g ∈ extensional A |] ==> compose A g (λx∈A. x) = g

lemma image_restrict_eq:

      restrict f A ` A = f ` A

### Bijections Between Sets

lemma bij_betw_imp_inj_on:

      bij_betw f A B ==> inj_on f A

lemma bij_betw_imp_funcset:

      bij_betw f A B ==> f ∈ A -> B

lemma bij_betw_Inv:

      bij_betw f A B ==> bij_betw (Inv A f) B A

lemma inj_on_compose:

      [| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A

lemma bij_betw_compose:

      [| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C

lemma bij_betw_restrict_eq:

      bij_betw (restrict f A) A B = bij_betw f A B

### Extensionality

lemma extensional_arb:

      [| f ∈ extensional A; x ∉ A |] ==> f x = arbitrary

lemma restrict_extensional:

      restrict f A ∈ extensional A

lemma compose_extensional:

      compose A f g ∈ extensional A

lemma extensionalityI:

      [| f ∈ extensional A; g ∈ extensional A; !!x. x ∈ A ==> f x = g x |] ==> f = g

lemma Inv_funcset:

      f ` A = B ==> restrict (Inv A f) B ∈ B -> A

lemma compose_Inv_id:

      bij_betw f A B ==> compose A (restrict (Inv A f) B) f = (λx∈A. x)

lemma compose_id_Inv:

      f ` A = B ==> compose B f (restrict (Inv A f) B) = (λx∈B. x)

### Cardinality

lemma card_inj:

      [| f ∈ A -> B; inj_on f A; finite B |] ==> card A ≤ card B

lemma card_bij:

      [| f ∈ A -> B; inj_on f A; g ∈ B -> A; inj_on g B; finite A; finite B |]
      ==> card A = card B