butterbr
Prev | Orchestra Opcodes and Operators | Next

## butterbr

butterbr — A band-reject Butterworth filter.

## Description

Implementation of a second-order band-reject Butterworth filter. This opcode can also be written as butbr.

## Syntax

    ares butterbr asig, kfreq, kband [, iskip]

## Initialization

iskip (optional, default=0) -- Skip initialization if present and non-zero.

## Performance

These filters are Butterworth second-order IIR filters. They are slightly slower than the original filters in Csound, but they offer an almost flat passband and very good precision and stopband attenuation.

asig -- Input signal to be filtered.

kfreq -- Cutoff or center frequency for each of the filters.

kband -- Bandwidth of the bandpass and bandreject filters.

## Examples

Here is an example of the butterbr opcode. It uses the file butterbr.csd.

Example 66. Example of the butterbr opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o butterbr.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 22050
    kr = 2205
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - an unfiltered noise waveform.
    instr 1
      ; White noise signal
      asig rand 22050

      out asig
    endin

    ; Instrument #2 - a filtered noise waveform.
    instr 2
      ; White noise signal
      asig rand 22050

      ; Filter it, cutting 2000 to 6000 Hz.
      abr butterbr asig, 4000, 2000

      out abr
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    ; Play Instrument #2 for two seconds.
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

butterbp, butterhp, butterlp

## Credits

Author: Paris Smaragdis
MIT, Cambridge
1995

Existed in 3.30

Prev | Up | Next
butterbp | Home | butterhp