rand
Prev | Orchestra Opcodes and Operators | Next

## rand

rand — Generates a controlled random number series.

## Description

Output is a controlled random number series between -amp and +amp

## Syntax

    ares rand xamp [, iseed] [, isel] [, ioffset]

    kres rand xamp [, iseed] [, isel] [, ioffset]

## Initialization

iseed (optional, default=0.5) -- a seed value for the recursive pseudo-random formula. A value between 0 and 1 will produce an initial output of kamp * iseed. A value greater than 1 will be seeded from the system clock. A negative value will cause seed re-initialization to be skipped. The default seed value is .5.

isel (optional, default=0) -- if zero, a 16-bit number is generated. If non-zero, a 31-bit random number is generated. Default is 0.

ioffset (optional, default=0) -- a base value added to the random result. New in Csound version 4.03.

## Performance

kamp, xamp -- range over which random numbers are distributed.

The internal pseudo-random formula produces values which are uniformly distributed over the range kamp to -kamp. rand will thus generate uniform white noise with an R.M.S value of kamp / root 2.

## Examples

Here is an example of the rand opcode. It uses the file rand.csd.

Example 423. Example of the rand opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o rand.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Choose a random frequency between 4,100 and 44,100.
      kfreq rand 20000
      kcps = kfreq + 24100

      a1 oscil 30000, kcps, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

randh, randi

## Credits

Example written by Kevin Conder.

Thanks to a note from John ffitch, I changed the names of the parameters.

Prev | Up | Next
pyrun Opcodes | Home | randh