OAWK(1)

NAME
oawk - pattern scanning and processing language

SYNOPSIS
oawk [-Fc] [-f file | prog] [file . . .]

DESCRIPTION
Oawk scans each input file for lines that match any of a set of patterns specified in prog. With each pattern in prog there can be an associated action that will be performed when a line of a file matches the pattern. The set of patterns may appear literally as prog, or in a file specified as -f file.

Files are read in order; if there are no files, the standard input is read. The file name `-' means the standard input. Each line is matched against the pattern portion of every pattern-action statement; the associated action is performed for each matched pattern.

An input line is made up of fields separated by white space. (This default can be changed by using FS, vide infra.) The fields are denoted $1, $2, ... ; $0 refers to the entire line.

A pattern-action statement has the form

    pattern { action }

A missing { action } means print the line; a missing pattern always matches.

An action is a sequence of statements. A statement can be one of the following:

	if ( conditional ) statement [ else statement ]
	while ( conditional ) statement
	for ( expression ; conditional ; expression ) statement
	for ( var in array ) statement
	break
	continue
	{ [ statement ] ... }
	variable = expression
	print [ expression-list ] [ >expression ]
	printf format [ , expression-list ] [ >expression ]
	next	# skip remaining patterns on this input line
	exit	# skip the rest of the input

Statements are terminated by semicolons, newlines or right braces. An empty expression-list stands for the whole line. Expressions take on string or numeric values as appropriate, and are built using the operators +, -, *, /, %, and concatenation (indicated by a blank). The C operators ++, --, +=, -=, *=, /=, and %= are also available in expressions. Variables may be scalars, array elements (denoted x[i]) or fields. Variables are initialized to the null string. Array subscripts may be any string, not necessarily numeric; this allows for a form of associative memory. String constants are quoted "...".

The print statement prints its arguments on the standard output (or on a file if >file is present or on a pipe if |cmd is present), separated by the current output field separator, and terminated by the output record separator. The printf statement formats its expression list according to the format (see printf(3)).

There are mathematical built-in functions exp, log, sqrt, and int. The last truncates its argument to an integer. Other built-in functions are:

getline
    sets $0 to the next input record. It returns 1 for successful input, and 0 for end of file.

index(s,t)
    the position in s where the string t occurs, or 0 if it does not.

length(s)
    returns the length of its argument taken as a string, or of the whole line if no argument.

split(s, a, fs)
    splits the string s into array elements a[1], a[2], ..., a[n], and returns n. The separation is done with the character fs or with the field separator FS if fs is not given.

sprintf(fmt, expr, expr, ...)
    formats the expressions according to the printf(3) format given by fmt and returns the resulting string.

substr(s, m, n)
    returns the n-character substring of s that begins at position m.

Patterns are arbitrary Boolean combinations (!, ||, &&, and parentheses) of regular expressions and relational expressions. Regular expressions must be surrounded by slashes and are full regular expressions as described in egrep(1). Isolated regular expressions in a pattern apply to the entire line. Regular expressions may also occur in relational expressions.

A pattern may consist of two patterns separated by a comma; in this case, the action is performed for all lines between an occurrence of the first pattern and the next occurrence of the second.

A relational expression is one of the following:

	expression matchop regular-expression
	expression relop expression

where a relop is any of the six relational operators in C, and a matchop is either ~ (for contains) or !~ (for does not contain). A conditional is an arithmetic expression, a relational expression, or a Boolean combination of these.

The special patterns BEGIN and END may be used to capture control before the first input line is read and after the last. BEGIN must be the first pattern, END the last.

A single character c may be used to separate the fields by starting the program with

    BEGIN { FS = "c" }

or by using the -Fc option.

Other variable names with special meanings include NF, the number of fields in the current record; NR, the ordinal number of the current record; FILENAME, the name of the current input file; OFS, the output field separator (default blank); ORS, the output record separator (default newline); and OFMT, the output format for numbers (default "%.6g").

EXAMPLES

Print lines longer than 72 characters:

	length > 72

Print first two fields in opposite order:

	{ print $2, $1 }

Add up first column, print sum and average:

		{ s += $1 }
	END	{ print "sum is", s, " average is", s/NR }

Print fields in reverse order:

	{ for (i = NF; i > 0; --i) print $i }

Print all lines between start/stop pairs:

	/start/, /stop/

Print all lines whose first field is different from previous one:

	$1 != prev { print; prev = $1 }

ENVIRONMENT VARIABLES

LANG, LC_ALL
    See locale(7).

LC_COLLATE
    Determines the collation order used for string comparison.

LC_CTYPE
    Maps bytes to characters.

LC_NUMERIC
    Determine the radix character used when interpreting numeric input, performing conversions between numeric and string values and formatting numeric output. Regardless of locale, the period character (the decimal-point character of the C locale) is the decimal-point character recognized in processing awk programs.

SEE ALSO

egrep(1), nawk(1), sed(1), printf(3), locale(7)
A. V. Aho, B. W. Kernighan, P. J. Weinberger, Awk - a pattern scanning and processing language

NOTES
There are no explicit conversions between numbers and strings. To force an expression to be treated as a number add 0 to it; to force it to be treated as a string concatenate "" to it.