#  Copyright (c) 1997-2009
#  Ewgenij Gawrilow, Michael Joswig (Technische Universitaet Darmstadt, Germany)
#  http://www.polymake.de
#
#  This program is free software; you can redistribute it and/or modify it
#  under the terms of the GNU General Public License as published by the
#  Free Software Foundation; either version 2, or (at your option) any
#  later version: http://www.gnu.org/licenses/gpl.txt.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#-------------------------------------------------------------------------------
#  $Project: polymake $$Id: Tempfile.pm 9298 2009-09-02 23:10:56Z gawrilow $

use strict;
use namespaces;

package Polymake::Tempfile;

my $dir;
foreach ($ENV{TMPDIR}, "/tmp", "/var/tmp", $UserSettings::dir, ".") {
   $dir=$_, last  if  $_  and  -d $_  and  -w _;
}
if (!defined $dir) {
   die "Tempfile:: cannot find a writable working directory; set TMPDIR variable to a proper path\n";
}

sub new {
   bless \(my $name), shift;
}

my $cnt="aaaa0000";
my $rename_cnt=0;

sub unique_name { "poly".$$."T".(++$cnt) }

use overload '""' => sub { $ {$_[0]} ||= "$dir/".unique_name; };

sub dir { $dir }
sub basename { $ {$_[0]} =~ m|/(poly[^/]+)$|; $1 }
sub rename { my $name="$_[0]"; ++$rename_cnt; $name=~s/T(?=\w+$)/N${rename_cnt}_/; $name }

sub DESTROY {
   my ($self)=@_;
   if (defined($$self)) {
      if (my @files=glob $$self."*") {
	 if ($DebugLevel && $@) {
	    warn_print( "temporary files kept: @files\n" );
	 } else {
	    unlink @files;
	 }
      }
   }
}

#################################################################################
package Polymake::OverwriteFile;
use Symbol;

use Polymake::Struct (
   [ new => '$' ],
   [ '$dst' => '#1' ],
   '$tempname',
   [ '$handle' => 'undef' ],
);

sub new {
   my $self=&_new;
   my ($dir)= $self->dst =~ $directory_re;
   $self->tempname="$dir/" . Tempfile->unique_name;
   open $self->handle, ">", $self->tempname
      or die "can't create a new copy of ", $self->dst, ": $!\n";
   ($self->handle, $self);
}

sub DESTROY {
   my ($self)=@_;
   if (defined(fileno($self->handle))) {
      close($self->handle);
      if ($@) {
	 if ($DebugLevel) {
	    warn_print( "incomplete new copy of ", $self->dst, " kept as ", $self->tempname );
	 } else {
	    unlink $self->tempname;
	 }
      } else {
	 unlink $self->tempname;
	 Carp::croak( "creation of new copy of ", $self->dst, " is not properly completed" );
      }
   } elsif (!rename($self->tempname, $self->dst)) {
      warn_print( "could not rename temporary file ", $self->tempname, " to destination ", $self->dst, ": $!" );
   }
}

1
