% THIS IS THE OFFICIAL COMPUTER MODERN SOURCE FILE textit.mf BY D E KNUTH.
% IT MUST NOT BE MODIFIED IN ANY WAY UNLESS THE FILE NAME IS CHANGED!

% The Computer Modern Text Italic family (by D. E. Knuth, 1979--1985)

mode_setup; font_setup;

input itall;  % lower case (minuscules)
input italsp;  % lowercase specials (dotless \i, ligature \ae, etc.)
if ligs>1: font_coding_scheme:="TeX text";
 spanish_shriek=oct"074"; spanish_query=oct"076";
 input italig;  % letter ligatures
else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
  else: "TeX text without f-ligatures" fi;
 spanish_shriek=oct"016"; spanish_query=oct"017"; fi

font_slant slant; font_x_height x_height#;
if monospace: font_normal_space 9u#; % no stretching or shrinking
 font_quad 18u#;
 font_extra_space 9u#;
 letter_fit#:=letter_fit:=0;
else: font_normal_space 6u#+2letter_fit#;
 font_normal_stretch 3u#; font_normal_shrink 2u#;
 font_quad 18u#+4letter_fit#;
 font_extra_space 2u#; fi

input romanu;  % upper case (majuscules)
input greeku;  % upper case greek letters
input itald;  % numerals
input italp;  % ampersand, question marks, currency sign
input romspu;  % uppercase specials (\AE, \OE, \O)
input punct;  % punctuation symbols common to roman and italic text
input accent;  % accents common to roman and italic text
if ligs>0: input comlig; fi  % ligatures common with roman text
if ligs<=1: input romsub; fi  % substitutes for ligatures

ligtable "!": "`" =: spanish_shriek;
ligtable "?": "`" =: spanish_query;

if not monospace:
 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
 ligtable "d": "w": "l": "l" kern +u#;
 ligtable "F": "V": "o" kern kk#, "e" kern kk#,
   "u" kern kk#, "r" kern kk#, "a" kern kk#, "A" kern kkk#,
  "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
 ligtable "T": "y" kern kk#,
  "Y": "e" kern kk#, "o" kern kk#, "r" kern kk#, "a" kern kk#, "u" kern kk#,
  "P": "W": "A" kern kk#;
 ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
   "V" kern k#, "Y" kern k#;
 ligtable "A": "R": "n" kern k#, "l" kern k#, "r" kern k#, "u" kern k#,
   "m" kern k#, "t" kern k#, "i" kern k#, "C" kern k#, "O" kern k#, "G" kern k#,
   "h" kern k#, "b" kern k#, "U" kern k#, "k" kern k#, "v" kern k#, "w" kern k#,
   "Q" kern k#, "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#,
  "b": "c": "e": "o": "p": "r": "e" kern -u#, "a" kern -u#, "o" kern -u#,
   "d" kern -u#, "c" kern -u#, "g" kern -u#, "q" kern -u#;
 ligtable "n": "'" kern kkk#; fi
% there are ligature/kern programs for |"f"| in the {\tt italig} file
% and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
bye.
