Scilab Function

plot3d1 - représentation en couleurs d'une surface en 3D

### Sequence d'appel

  `plot3d1(x,y,z,[theta,alpha,leg,flag,ebox])`
  `plot3d1(xf,yf,zf,[theta,alpha,leg,flag,ebox])`

### Parametres

Voir `plot3d` pour une description complète. Il y a juste une petite différence, uniquement le signe de `flag(1)=mode` est utilisé : s'il est négatif la grille n'est pas dessinée.

### Description

`plot3d` dessine une surface `z=f(x,y)` dont la couleur en un point dépend de la hauteur.

Taper `plot3d1()` pour voir une démonstration de la fonction.

### Exemples

    // simple surface z=f(x,y)
    t=[0:0.3:2*%pi]'; z=sin(t)*cos(t');
    plot3d1(t,t,z)
    // même surface en utilisant genfac3d au préalable
    [xx,yy,zz]=genfac3d(t,t,z);
    xbasc()
    plot3d1(xx,yy,zz)
    // surfaces multiples
    xbasc()
    plot3d1([xx xx],[yy yy],[zz 4+zz])
    // changement du point de vue et des légendes
    xbasc()
    plot3d1(1:10,1:20,10*rand(10,20),35,45,"X@Y@Z",[2,2,3])
    // changement du point de vue et des légendes
    xbasc()
    plot3d1(1:10,1:20,10*rand(10,20),35,45,"X@Y@Z",[-2,2,3])
    // une sphère
    deff("[x,y,z]=sph(alp,tet)",["x=r*cos(alp).*cos(tet)+orig(1)*ones(tet)";..
      "y=r*cos(alp).*sin(tet)+orig(2)*ones(tet)";..
      "z=r*sin(alp)+orig(3)*ones(tet)"]);
    r=1; orig=[0 0 0];
    [xx,yy,zz]=eval3dp(sph,linspace(-%pi/2,%pi/2,40),linspace(0,%pi*2,20));
    xbasc()
    plot3d1(xx,yy,zz)

### Voir aussi

`plot3d`

### Auteur

J.Ph.C.