Scilab Function

plot2d - représentation de courbes dans le plan

### Sequence d'appel

  `plot2d([x],y)`
  `plot2d([x],y,<opt_args>)`
  `plot2d([logflag],x,y,[style,strf,leg,rect,nax])`

### Parametres

- `x,y` : deux matrices ou vecteurs.

- `-` Si `y` est un vecteur, `x` doit être un vecteur de même taille. Si `x` n'est pas donné, il est supposé être égal au vecteur 1:<taille de `y`>.
- `-` Si `y` est une matrice, `x` peut être :

- `+` un vecteur de taille égale au nombre de lignes de `y` (chaque colonne de `y` est représentée par rapport à `x`)
- `+` une matrice de mêmes dimensions que `y` (chaque colonne de `y` est représentée par rapport à la colonne correspondante de `x`)
- `+` Si `x` n'est pas donné, il est supposé être égal au vecteur 1:<nombre de lignes de `y`>

- `<opt_args>` : Représente une suite d'affectations `key1=value1, key2=value2`,... où `key1`, `key2,...` peut prendre les valeurs :

- `style` : donne le style de chaque courbe (voir ci-dessous)
- `leg` : donne la légende de chaque courbe. Si ce paramètre est spécifié et que `strf` n'est pas donné alors le caractère `x` de `strf` est supposé être `1` (voir ci-dessous)
- `rect` : définit les bornes du dessin. Si ce paramètre est donné et que ni `frameflag` ni `strf` ne sont donnés alors le caractère `y` de `strf` est supposé être `7` (voir ci-dessous)
- `nax` : définition des graduations. Si ce paramètre est donné et que ni `axesflag` ni `strf` ne sont donnés alors le caractère `z` de `strf` est supposé être `1` (voir ci-dessous)
- `logflag` : définit le type d'échelle (linéaire ou logarithmique) des axes (voir ci-dessous)
- `frameflag` : spécifie comment est calculé le cadre du dessin. Cette valeur est un entier entre 0 et 8. Il correspond au caractère `y` de `strf` (voir ci-dessous)
- `axesflag` : spécifie le type d'axe dessiné autour du dessin. Cette valeur est un entier entre 0 et 5. Il correspond au caractère `z` de `strf` (voir ci-dessous)

- `style` : est un vecteur ligne de taille nc. Le style à utiliser pour la courbe `i` est défini par `style(i)`. Le style par défaut est `1:nc` (1 pour la première courbe, 2 pour la deuxième ...)

- `-` si `style(i)` est négatif ou nul, la courbe est dessinée en utilisant le marqueur de code `abs(style(i))`; utiliser `xset()` pour voir les codes des marqueurs et xget('mark') pour avoir le code du marqueur courant.
- `-` si `style(i)` > 0, une ligne de couleur d'indice `style(i)` ou en pointillés de code `style(i)` est utilisée; utiliser `xset()` pour voir les indices des couleurs.
- `-` Quand une seule courbe est dessinée, `style` peut être le vecteur ligne de taille 2 `[sty,pos]` où `sty` est utilisé pour spécifier le style et `pos` est un entier entre 1 et 6 spécifiant la position à utiliser pour les légendes. Cela peut être utile si l'utilisateur veut dessiner des courbes multiples en appelant la fonction `plot2d` plusieurs fois et veut avoir une légende différente à chaque fois.

- `strf` : est une chaîne de caractères de longueur 3 `"xyz"`.

- `La valeur par défaut est`
- `x` : contrôle l'affichage des légendes

- `x=0` : pas de légende.
- `x=1` : Les légendes sont affichées. Elles sont données par l'argument optionnel `leg`.

- `y` : Contrôle le calcul des bornes du dessin :

| bornes du | bornes | bornes
| dessin | données | calculées
| précédent | dans rect | à partir de x et y
-------------- | ------------ | --------- | ------------------
Échelle |  |  |
standard | y=0 | y=1 | y=2
-------------- | ------------ | --------- | ------------------
Échelle |  |  |
isométrique |  | y=3 | y=4
en X et Y |  |  |
-------------- | ------------ | --------- | ------------------
Échelle |  |  |
élargie pour |  | y=5 | y=6
graduations |  |  |
simplifiées |  |  |
-------------- | ------------ | --------- | ------------------
Superposition |  |  |
avec le dessin |  | y=7 | y=8
courant |  |  |
-------------- | ------------ | --------- | ------------------

- `z` : contrôle l'affichage des informations sur le cadre autour du dessin. Si les axes sont requis, le nombre de graduations peut être spécifié par le paramètre optionnel `nax`

- `z=0` : rien n'est dessiné autour du dessin
- `z=1` : les axes sont dessinés, l'axe y est dessiné à gauche.
- `z=2` : le dessin est entouré d'une boîte sans graduations.
- `z=3` : les axes sont dessinés, l'axe y est dessiné à droite
- `z=4` : les axes sont dessinés au milieu du cadre
- `z=5` : les axes sont dessinés de manière à se croiser au point `(0,0)`. Si ce point `(0,0)` ne se situe pas dans le cadre, les axes n'apparaissent pas.

- `leg` : une chaîne de caractères. Elle est utilisée quand le caractère x de l'argument `strf` vaut 1. `leg` a la forme `"leg1@leg2@...."` où `leg1`, `leg2`, etc. sont respectivement la légende de la première courbe, de la deuxième, etc. La valeur par défaut est `" "`.
- `rect` : Cet argument est utilisé quand le caractère y de l'argument `strf` vaut 1, 3 ou 5. C'est un vecteur ligne de taille 4 donnant les bornes du cadre : `rect=[xmin,ymin,xmax,ymax]`.
- `nax` : Cet argument est utilisé quand le caractère z de l'argument `strf` vaut 1. C'est un vecteur ligne de taille 4 donnant les graduations `[nx,Nx,ny,Ny]` où `nx` (`ny`) est le nombre de sous-graduations sur l'axe x (y) et `Nx` (`Ny`) est le nombre de graduations sur l'axe x (y).
- `logflag` : une chaîne de caractères formée par deux caractères h (pour horizontal) et v (pour vertical). Chacun de ces deux caractères peut prendre les valeurs "n" ou "l". "l" pour avoir une échelle logarithmique et "n" pour une échelle linéaire. Par exemple "ll" sera utilisé pour un graphe en échelle log-log. La valeur par défaut est "nn".

### Description

`plot2d` dessine dans le plan un ensemble de courbes linéaires par morceaux.

Par défaut, les dessins successifs sont superposés. Pour effacer le dessin précédent, utiliser `xbasc()`.

Voir les définitions des paramètres ci-dessus pour une description complète.

Taper `plot2d()` pour voir une démonstration de la fonction.

D'autres fonctions de haut niveau du type plot2d existent :

- plot2d2 : comme `plot2d` mais la fonction est supposée constante par morceaux
- plot2d3 : comme `plot2d` mais la courbe est dessinée avec des barres verticales
- plot2d4 : comme `plot2d` mais la courbe est dessinée avec des flèches.

### Exemples

    // dessin tout bête
    x=[0:0.1:2*%pi]';
    plot2d(sin(x))
    xbasc()
    plot2d(x,sin(x))
    // plusieurs courbes
    xbasc()
    plot2d(x,[sin(x) sin(2*x) sin(3*x)])
    // plusieurs courbes en fixant les bornes
    // ancienne et nouvelle syntaxe
    xbasc()
    plot2d(x,[sin(x) sin(2*x) sin(3*x)],1:3,"011"," ",[0,0,6,0.5])
    xbasc()
    plot2d(x,[sin(x) sin(2*x) sin(3*x)],rect=[0,0,6,0.5])
    // plusieurs courbes avec légendes et graduations
    // ancienne et nouvelle syntaxe
    xbasc()
    plot2d(x,[sin(x) sin(2*x) sin(3*x)],..
      [1,2,3],"111","L1@L2@L3",[0,-2,2*%pi,2],[2,10,2,10])
    xbasc()
    plot2d(x,[sin(x) sin(2*x) sin(3*x)],..
      [1,2,3],leg="L1@L2@L3",nax=[2,10,2,10],rect=[0,-2,2*%pi,2])
    // échelle isométrique
    xbasc()
    plot2d(x,sin(x),1,"041")
    //
    xbasc()
    plot2d(x,sin(x),1,"061")
    // mise à l'échelle avec les dessins précédents
    xbasc()
    plot2d(x,sin(x),1)
    plot2d(x,2*sin(x),2)
    plot2d(2*x,cos(x),3)
    // axe à droite
    xbasc()
    plot2d(x,sin(x),1,"183","sin(x)")
    // axe centré
    xbasc()
    plot2d(x,sin(x),1,"184","sin(x)")
    // axe centré en (0,0)
    xbasc()
    plot2d(x-4,sin(x),1,"185","sin(x)")

### Voir aussi

`plot2d1` `plot2d2` `plot2d3` `plot2d4` `xbasc` `xset`

### Auteur

J.Ph.C.