# menu.tcl --
#
# This demonstration script creates a window with a bunch of menus
# and cascaded menus using menubars.
#
# RCS: @(#) $Id: menu.tcl,v 1.1 1999/03/31 15:08:36 m-hirano Exp $

if {![info exists widgetDemo]} {
    error "This script should be run from the \"widget\" demo."
}

set w .menu
catch {destroy $w}
toplevel $w
wm title $w "Menu Demonstration"
wm iconname $w "menu"
positionWindow $w

label $w.msg -font $font -wraplength 4i -justify left 
if {$tcl_platform(platform) == "macintosh"} {
    $w.msg configure -text [langSel \
"This window contains a menubar with cascaded menus.  You can invoke entries with an accelerator by typing Command+x, where \"x\" is the character next to the command key symbol. The rightmost menu can be torn off into a palette by dragging outside of its bounds and releasing the mouse." \
"このウィンドウにはカスケードメニューをもつメニューバーがあります。Command-X のアクセラレータを使ってエントリを実行することができます。Xはメニューのコマンドキー記号の横に表示されている文字です。右端のメニューはその枠の外側をドラッグしてマウスを離すことにより切り離してパレットにすることができます。"]
} else {
    $w.msg configure -text [langSel \
"This window contains a menubar with cascaded menus.  You can post a menu from the keyboard by typing Alt+x, where \"x\" is the character underlined on the menu.  You can then traverse among the menus using the arrow keys.  When a menu is posted, you can invoke the current entry by typing space, or you can invoke any entry by typing its underlined character.  If a menu entry has an accelerator, you can invoke the entry without posting the menu just by typing the accelerator. The rightmost menu can be torn off into a palette by selecting the first item in the menu." \
"このウィンドウにはカスケードメニューをもつメニューバーがあります。Alt-X を入力すると、Xがメニューにアンダーライン付きで表示されている文字ならば、キーボードからの指定ができます。矢印キーでメニューのトラバースも可能です。メニューが指定された際には、スペースキーで実行することができます。あるいは、アンダーライン付きの文字を入力することでも実行できます。メニューのエントリがアクセラレータを持っている場合は、そのアクセラレータを入力することでメニューを指定することなしに実行することができます。右端のメニューは最初の項目を選択することにより切り離してパレットにすることができます。"]
}
pack $w.msg -side top

set menustatus "    "
frame $w.statusBar
label $w.statusBar.label -textvariable menustatus -relief sunken -bd 1 -font "Helvetica10" -anchor w
pack $w.statusBar.label -side left -padx 2 -expand yes -fill both
pack $w.statusBar -side bottom -fill x -pady 2

frame $w.buttons
pack $w.buttons -side bottom -fill x -pady 2m
button $w.buttons.dismiss -text [langSel Dismiss 了解] -command "destroy $w"
button $w.buttons.code -text [langSel "See Code" "コード参照"] -command "showCode $w"
pack $w.buttons.dismiss $w.buttons.code -side left -expand 1

menu $w.menu -tearoff 0

set m $w.menu.file
menu $m -tearoff 0
$w.menu add cascade -label [langSel "File" "ファイル(F)"] -menu $m -underline [langSel 0 5]
$m add command -label [langSel "Open..." "開く ..."] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"Open...\" entry" \
"これは、デモですので\"開く ...\"に対するアクションは定義されていません。"]
}
$m add command -label [langSel "New" "新規"] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"New\" entry" \
"これは、デモですので\"新規 ...\"に対するアクションは定義されていません。"]
}
$m add command -label [langSel "Save" "保存"] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"Save\" entry" \
"これは、デモですので\"保存 ...\"に対するアクションは定義されていません。"]
}
$m add command -label [langSel "Save As..." "名前を付けて保存 ..."] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"Save As...\" entry" \
"これは、デモですので\"名前を付けて保存 ...\"に対するアクションは定義されていません。"]
}
$m add separator
$m add command -label [langSel "Print Setup..." "印刷設定 ..."] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"Print Setup...\" entry" \
"これは、デモですので\"印刷設定 ...\"に対するアクションは定義されていません。"]
}
$m add command -label [langSel "Print..." "印刷 ..."] -command {
    error [langSel \
"this is just a demo: no action has been defined for the \"Print...\" entry" \
"これは、デモですので\"印刷 ...\"に対するアクションは定義されていません。"]
}
$m add separator
$m add command -label [langSel "Dismiss Menus Demo" "メニューデモ中止"] -command "destroy $w"

set m $w.menu.basic
$w.menu add cascade -label [langSel "Basic" "基本(B)"] -menu $m -underline [langSel 0 3]
menu $m -tearoff 0
$m add command -label [langSel "Long entry that does nothing" "何もしない長いエントリ"]
if {$tcl_platform(platform) == "macintosh"} {
    set modifier Command
} elseif {$tcl_platform(platform) == "windows"} {
    set modifier Control
} else {
    set modifier Meta
}
foreach i {A B C D E F} {
    $m add command -label [langSel "Print letter \"$i\"" "文字\"$i\"を印字"] -underline [langSel 14 3] \
	    -accelerator Meta+$i -command "puts $i" -accelerator $modifier+$i
    bind $w <$modifier-[string tolower $i]> "puts $i"
}

set m $w.menu.cascade
$w.menu add cascade -label [langSel "Cascades" "カスケード(C)"] -menu $m -underline [langSel 0 6]
menu $m -tearoff 0
$m add command -label [langSel "Print hello" "こんにちは(H)"] \
	-command {puts stdout "Hello"} -accelerator $modifier+H -underline [langSel 6 6]
bind $w <$modifier-h> {puts stdout "Hello"}
$m add command -label [langSel "Print goodbye" "さようなら(G)"] -command {\
    puts stdout "Goodbye"} -accelerator $modifier+G -underline [langSel 6 6]
bind $w <$modifier-g> {puts stdout "Goodbye"}
$m add cascade -label [langSel "Check buttons" "チェックボタン(C)"] \
	-menu $w.menu.cascade.check -underline [langSel 0 8]
$m add cascade -label [langSel "Radio buttons" "ラジオボタン(R)"] \
	-menu $w.menu.cascade.radio -underline [langSel 0 7]

set m $w.menu.cascade.check
menu $m -tearoff 0
$m add check -label [langSel "Oil checked" "オイル点検"] -variable oil
$m add check -label [langSel "Transmission checked" "トランスミッション点検"] -variable trans
$m add check -label [langSel "Brakes checked" "ブレーキ点検"] -variable brakes
$m add check -label [langSel "Lights checked" "ライト点検"] -variable lights
$m add separator
$m add command -label [langSel "Show current values" "現在の値を表示"] \
    -command "showVars $w.menu.cascade.dialog oil trans brakes lights"
$m invoke 1
$m invoke 3

set m $w.menu.cascade.radio
menu $m -tearoff 0
$m add radio -label [langSel "10 point" "10 ポイント"] -variable pointSize -value 10
$m add radio -label [langSel "14 point" "14 ポイント"] -variable pointSize -value 14
$m add radio -label [langSel "18 point" "18 ポイント"] -variable pointSize -value 18
$m add radio -label [langSel "24 point" "24 ポイント"] -variable pointSize -value 24
$m add radio -label [langSel " point" "32 ポイント"] -variable pointSize -value 32
$m add sep
$m add radio -label [langSel "Roman" "ローマン"] -variable style -value roman
$m add radio -label [langSel "Bold" "ボールド"] -variable style -value bold
$m add radio -label [langSel "Italic" "イタリック"] -variable style -value italic
$m add sep
$m add command -label [langSel "Show current values" "現在の値を表示"] \
	-command "showVars $w.menu.cascade.dialog pointSize style"
$m invoke 1
$m invoke 7

set m $w.menu.icon
$w.menu add cascade -label [langSel "Icons" "アイコン(I)"] -menu $m -underline [langSel 0 5]
menu $m -tearoff 0
$m add command \
    -bitmap @[file join $tk_library demos.jp images pattern.bmp] \
    -hidemargin 1 \
    -command {
	tk_dialog .pattern {Bitmap Menu Entry} [langSel \
{The menu entry you invoked displays a bitmap rather than a text string.  Other than this, it is just like any other menu entry.} \
{今あなたが選択したメニューの項目はテキストではなくビットマップを表示していました。それ以外の点では他のメニュー項目と変わりません。}] \
{} 0 [langSel OK 了解]
}
foreach i {info questhead error} {
    $m add command -bitmap $i -command "puts {You invoked the $i bitmap}" -hidemargin 1
}
$m entryconfigure 2 -columnbreak 1

set m $w.menu.more
$w.menu add cascade -label [langSel "More" "その他(M)"] -menu $m -underline [langSel 0 4]
menu $m -tearoff 0
foreach i [langSel \
{{An entry} {Another entry} {Does nothing} {Does almost nothing} {Make life meaningful}} \
{{エントリ} {別のエントリ} {何もしない} {ほとんど何もしない} {人生を意義あるものに}}] {
    $m add command -label $i -command [list puts "You invoked \"$i\""]
}

set m $w.menu.colors
$w.menu add cascade -label [langSel "Colors" "色(O)"] -menu $m -underline [langSel 1 2]
menu $m
foreach i [langSel {red orange yellow green blue} {{赤 red} {橙 orange} {黄 yellow} {緑 green} {青 blue}}] {
    $m add command -label [lindex $i 0] -background [lindex $i end] \
	    -command [list puts "You invoked \"$i\""]
}

$w configure -menu $w.menu

bind Menu <<MenuSelect>> {
    global $menustatus
    if {[catch {%W entrycget active -label} label]} {
	set label "    "
    }
    set menustatus $label
    update idletasks
}
