Scilab Function

Matplot1 - représentation d'une matrice dans le plan en pseudo-couleurs

### Calling Sequence

  `Matplot1(a,rect)`

### Parameters

- `a` : matrice réelle de taille (n1,n2).
- `rect` : `[xmin;ymin,xmax,ymax]`

### Description

Les termes de la matrice `int(a)` sont utilisés comme indices de couleur dans la table des couleurs courante. `rect` spécifie un rectangle dans l'échelle courante et la matrice est dessinée dans ce rectangle. Chaque terme de la matrice est représenté comme un petit rectangle rempli avec la couleur associée.

### Examples

    //--- premier exemple
    //  on fixe l'échelle courante
    xsetech(frect=[0,0,10,10])
    xrect(0,10,10,10)
    a=5*ones(11,11); a(2:10,2:10)=4; a(5:7,5:7)=2;
    // première matrice dans le rectangle [1,1,3,3]
    Matplot1(a,[1,1,3,3])
    a=ones(10,10); a= 3*tril(a)+ 2*a;
    // deuxième matrice dans le rectangle [5,6,7,8]
    Matplot1(a,[5,6,7,8])
    xset('default')
    xbasc()
    //--- deuxième exemple
    xsetech(frect=[0,0,10,10])
    xrect(0,10,10,10)
    n=100;
    xset('pixmap',1)
    driver('X11');
    for k=-n:n,
      a=ones(n,n);
      a= 3*tril(a,k)+ 2*a;
      a= a + a';
      k1= 3*(k+100)/200;
      Matplot1(a,[k1,2,k1+7,9])
      xset('wshow')
      xset('wwpc')
    end
    xset('pixmap',0)
    xset('default')
    xbasc()

### See Also

`colormap` , `plot2d` , `Matplot` ,

### Author

J.Ph.C.