Scilab Function

drawaxis - dessine un axe

### Calling Sequence

  `drawaxis([options])`
  `// options: x,y,dir,sub_int,fontsize,format_n,seg,textcolor,ticscolor,tics`

### Parameters

- `dir=chaîne` : utilisé pour spécifier la direction des graduations. `chaîne` peut être choisi parmi 'u','r','d','l' ('l' est la valeur par défaut). Les valeurs 'u','r','d','l' signifient up (en haut), right (à droite) , down (en bas) , left (à gauche).
- `tics=chaîne` : valeur décrivant comment sont données les graduations. `chaîne` peut être choisi parmi 'v','r', et 'i' ('v' est la valeur par défaut).
- `x,y` : deux vecteurs donnant les positions des graduations.
- `val=chaîne` : une matrice de chaînes de caractères donnant les labels à dessiner en face des graduations.
- `fontsize=int` : spécifie la taille de la police utilisée pour dessiner les labels des graduations. La valeur par défaut est `-1` (taille courante de police).
- `format_n=chaîne` : format utilisé pour afficher les nombres au dessus des graduations.
- `seg= 1 ou 0` : valeur contrôlant l'affichage du segment de base de l'axe (1 par défaut).
- `sub_int=entier` : un entier donnant le nombre de sous-graduations
- `textcolor=entier` : spécifie la couleur à utiliser pour afficher les valeurs sur l'axe. La valeur par défaut est `-1` (couleur courante).
- `ticscolor=entier` : spécifie la couleur à utiliser pour dessiner les graduations. La valeur par défaut est `-1` (couleur courante).

### Description

`drawaxis` est utilisée pour dessiner un axe vertical ou horizontal. La direction de l'axe est donnée par dir `dir = 'u'` ou `'d'` donne un axe horizontal avec des graduations dirigées vers le haut (`'u'` ) ou le bas (`'d'` ). `dir = 'r'` ou `'l'` donne un axe vertical avec des graduations allant vers la droite (`'r'` ) ou vers la gauche (`'l'` ).

`x` et `y` donnent les positions des graduations. Si l'axe est horizontal alors `y` doit être un scalaire ou peut être omis et `x` est un vecteur. La signification de `x` est contrôlée par `tics` .

Si `tics='v'` alors `x` donne les positions des graduations sur l'axe des x.

Si `tics='r'` alors `x` doit être de taille 3. `x=[xmin,xmax,n]` et `n` donne le nombre d'intervalles.

Si `tics='i'` alors `x` doit être de taille 4, `x=[k1,k2,a,n]` . Dans ce cas `xmin=k1*10^a` , `xmax=k2*10^a` et `n` donne le nombre d'intervalles.

Si `y` est omis alors l'axe est positionné en haut du cadre si `dir='u'` ou en bas si `dir='d'`

Par défaut, les nombres sont dessinés sur l'axe. Ils sont dessinés en utilisant un format par défaut qui peut être changé avec `format_n` . Il est aussi possible d'afficher des chaînes de caractères données au lieu des nombres, si `val` est fourni en argument. La taille de `val` doit alors être égale au nombre de graduations.

### Examples

    plot2d(1:10,1:10,1,"020")
    // axe horizontal
    drawaxis(x=2:7,y=4,dir='u',tics='v')
    // axe horizontal en haut du cadre
    drawaxis(x=2:7,dir='u',tics='v')
    // axe horizontal en bas du cadre
    drawaxis(x=2:7,dir='d',tics='v')

    // axe horizontal donné par une plage de variation
    drawaxis(x=[2,7,3],y=4,dir='d',tics='r')

    // axe vertical
    drawaxis(x=4,y=2:7,dir='r',tics='v')
    drawaxis(x=2,y=[2,7,3],dir='l',tics='r')
    drawaxis(y=2:7,dir='r',tics='v')
    drawaxis(y=2:7,dir='l',tics='v')

    // axe horizontal avec chaînes de caractères au dessus des graduations
    drawaxis(x=2:7,y=8,dir='u',tics='v',val='A'+string(1:6));
    // axe vertical avec chaînes de caractères au dessus des graduations
    drawaxis(x=8,y=2:7,dir='r',tics='v',val='B'+string(1:6));

    // axe horizontal avec 'i'
    drawaxis(x=[2,5,0,3],y=9,dir='u',tics='i');
    drawaxis(x=9,y=[2,5,0,3],dir='r',tics='i',sub_int=5);

    // encore un axe horizontal
    drawaxis(x=2:7,y=4,dir='u',tics='v',fontsize=10,textcolor=9,ticscolor=7,seg=0,sub_int=20)

### Author

J.Ph.C.