Scilab Function

gda - Return handle of default axes.

### Calling Sequence

  `a = gda()`
  `a = get("default_axes")`

### Parameters

- `a` : handle, the handle of the default axes.

### Description

The default axes is a graphic entity which is never drawn. It is used as a reference for the axes properties default values. These default properties values are used to initialize new axes inside figures.

The `gda` function returns the handle on the default axes. The user can use this handle to set or get the axes properties default values.

Note that an equivalent default graphic entity exists for figure entities too (see `gdf` ).

### Examples

        a=gda() // get the handle of the model axes
          // setting its' properties
        a.background=31;
        a.box="off";
        a.rotation_angles=[70 10];
        a.tics_color=2;
        a.labels_font_size=3;
        a.labels_font_color=5;
        a.sub_tics=[5 5 3];
        a.x_location="top";
        set("figure_style","new")
        subplot(211)
        plot2d() //create an axes entity
        subplot(212)
        plot3d1() //create a second axes entity
        a.grids=[5 5 5]; // setting other model's properties
        clf()
        t=0:0.1:5*%pi;
        plot2d(sin(t),cos(t),t/10)
        set(a,"default_values",1); // return to the  default values of the model
                                   // see sda() function
        clf()
        plot2d(sin(t),cos(t),t/10)

### See Also

`gdf` , `sda` , `sdf` , `clf` , `gca` , `get` , `graphics_entities` ,

### Author

Djalel ABDEMOUCHE