linseg
Prev | Orchestra Opcodes and Operators | Next

## linseg

linseg — Trace a series of line segments between specified points.

## Description

Trace a series of line segments between specified points.

## Syntax

    ares linseg ia, idur1, ib [, idur2] [, ic] [...]

    kres linseg ia, idur1, ib [, idur2] [, ic] [...]

## Initialization

ia -- starting value.

ib, ic, etc. -- value after dur1 seconds, etc.

idur1 -- duration in seconds of first segment. A zero or negative value will cause all initialization to be skipped.

idur2, idur3, etc. -- duration in seconds of subsequent segments. A zero or negative value will terminate the initialization process with the preceding point, permitting the last-defined line or curve to be continued indefinitely in performance. The default is zero.

## Performance

These units generate control or audio signals whose values can pass through 2 or more specified points. The sum of dur values may or may not equal the instrument's performance time: a shorter performance will truncate the specified pattern, while a longer one will cause the last-defined segment to continue on in the same direction.

| Note
A common error with this opcode is to assume that the last value is held after the total duration. linseg does not automatically end or stop at the end of the total duration. If your note length is longer than the sum of all idur values, kres (or ares) will not come to rest at the last given value, but will instead continue to rise or fall with the current rate. You can add a final segment at the same previous value to create a held final value.

## Examples

Here is an example of the linseg opcode. It uses the file linseg.csd.

Example 267. Example of the linseg opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o linseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv linseg 0, p3*0.25, 1, p3*0.75, 0
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin

    instr 2
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv linseg 0, 0.25, 1, 0.75, 0  ; kenv will go into negative if p3 > 1
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin

    instr 3
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv linseg 0, 0.25, 1, 0.75, 0, 1, 0  ; kenv will stay at 0 indefinetely at the end
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin
    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for a half-second, p4=8.00
    i 1 0 0.5 8.00
    ; Play Instrument #1 for a half-second, p4=8.01
    i 1 1 0.5 8.01
    ; Play Instrument #1 for a half-second, p4=8.02
    i 1 2 0.5 8.02
    ; Play Instrument #1 for a half-second, p4=8.03
    i 1 3 0.5 8.03

    i 2 4  1.5 8.00 ; Notice the problem with linseg

    i 3 6  1.5 8.00  ; this is the solution (instr 3)
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

expon, expseg, expsegr, line, linsegr transeg

## Credits

Example written by Kevin Conder.

Prev | Up | Next
linrand | Home | linsegr