jitter2
Prev | Orchestra Opcodes and Operators | Next

## jitter2

jitter2 — Generates a segmented line with user-controllable random segments.

## Description

Generates a segmented line with user-controllable random segments.

## Syntax

    kout jitter2 ktotamp, kamp1, kcps1, kamp2, kcps2, kamp3, kcps3

## Performance

ktotamp -- Resulting amplitude of jitter2

kamp1 -- Amplitude of the first jitter component

kcps1 -- Speed of random variation of the first jitter component (expressed in cps)

kamp2 -- Amplitude of the second jitter component

kcps2 -- Speed of random variation of the second jitter component (expressed in cps)

kamp3 -- Amplitude of the third jitter component

kcps3 -- Speed of random variation of the third jitter component (expressed in cps)

jitter2 also generates a segmented line such as jitter, but in this case the result is similar to the sum of three randi opcodes, each one with a different amplitude and frequency value (see randi for more details), that can be varied at k-rate. Different effects can be obtained by varying the input arguments.

jitter2 can be used to make more natural and “analog-sounding” some static, dull sound. For best results, it is suggested to keep its amplitude moderate.

## Examples

Here is an example of the jitter2 opcode. It uses the file jitter2.csd.

Example 262. Example of the jitter2 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o jitter2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 2

    ; Instrument #1 -- plain instrument.
    instr 1
      aplain vco 20000, 220, 2, 0.83

      outs aplain, aplain
    endin

    ; Instrument #2 -- instrument with jitter.
    instr 2
      ; Create a signal modulated with the jitter2 opcode.
      ktotamp init 2
      kamp1 init 0.66
      kcps1 init 3
      kamp2 init 0.66
      kcps2 init 3
      kamp3 init 0.66
      kcps3 init 3
      kj jitter2 ktotamp, kamp1, kcps1, kamp2, kcps2, \
                 kamp3, kcps3

      aplain vco 20000, 220, 2, 0.83
      ajitter vco 20000, 220+kj, 2, 0.83

      outs aplain, ajitter
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for 3 seconds.
    i 1 0 3
    ; Play Instrument #2 for 3 seconds.
    i 2 3 3
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

jitter, vibr, vibrato

## Credits

Author: Gabriel Maldonado

Example written by Kevin Conder.

New in Version 4.15

Prev | Up | Next
jitter | Home | jspline