sandpaper
Prev | Orchestra Opcodes and Operators | Next

## sandpaper

sandpaper — Semi-physical model of a sandpaper sound.

## Description

sandpaper is a semi-physical model of a sandpaper sound. It is one of the PhISEM percussion opcodes. PhISEM (Physically Informed Stochastic Event Modeling) is an algorithmic approach for simulating collisions of multiple independent sound producing objects.

## Syntax

    ares sandpaper iamp, idettack [, inum] [, idamp] [, imaxshake]

## Initialization

iamp -- Amplitude of output. Note: As these instruments are stochastic, this is only a approximation.

idettack -- period of time over which all sound is stopped

inum (optional) -- The number of beads, teeth, bells, timbrels, etc. If zero, the default value is 128.

idamp (optional) -- the damping factor, as part of this equation:

damping_amount = 0.998 + (idamp * 0.002)

The default damping_amount is 0.999 which means that the default value of idamp is 0.5. The maximum damping_amount is 1.0 (no damping). This means the maximum value for idamp is 1.0.

The recommended range for idamp is usually below 75% of the maximum value.

imaxshake (optional) -- amount of energy to add back into the system. The value should be in range 0 to 1.

## Examples

Here is an example of the sandpaper opcode. It uses the file sandpaper.csd.

Example 451. Example of the sandpaper opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o sandpaper.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ;orchestra ---------------

      sr =           44100
      kr =            4410
      ksmps =              10
      nchnls =               1

    instr 01                  ;an example of sandpaper blocks
      a1      line 2, p3, 2                             ;preset amplitude increase
      a2      sandpaper p4, 0.01            ;sandpaper needs a little amp help at these settings
      a3      product a1, a2                               ;increase amplitude
              out a3
              endin

    </CsInstruments>
    <CsScore>

    ;score -------------------

       i1 0 1 26000
       e

    </CsScore>
    </CsoundSynthesizer>

## See Also

cabasa, crunch, sekere, stix

## Credits

Author: Perry Cook, part of the PhOLIES (Physically-Oriented Library of Imitated Environmental Sounds)
Adapted by John ffitch
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 4.07

Added notes by Rasmus Ekman on May 2002.

Prev | Up | Next
samphold | Home | scanhammer