The Alternative Csound Reference Manual
Previous |  | Next

# deltapxw

deltapxw -- Mixes the input signal to a delay line.

## Description

deltapxw mixes the input signal to a delay line. This opcode can be mixed with reading units (deltap, deltapn, deltapi, deltap3, and deltapx) in any order; the actual delay time is the difference of the read and write time. This opcode can read from and write to a delayr/delayw delay line with interpolation.

## Syntax

deltapxw ain, adel, iwsize

## Initialization

iwsize -- interpolation window size in samples. Allowed values are integer multiplies of 4 in the range 4 to 1024. iwsize = 4 uses cubic interpolation. Increasing iwsize improves sound quality at the expense of CPU usage, and minimum delay time.

## Performance

ain -- Input signal

adel -- Delay time in seconds.

    a1      delayr idlr
            deltapxw a2, adl1, iws1
    a3      deltapx adl2, iws2
            deltapxw a4, adl3, iws3
            delayw a5

Minimum and maximum delay times:

    idlr >= 1/kr                                Delay line length

    adl1 >= (iws1/2)/sr                         Write before read
    adl1 <= idlr - (1 + iws1/2)/sr              (allows shorter delays)

    adl2 >= 1/kr + (iws2/2)/sr                  Read time
    adl2 <= idlr - (1 + iws2/2)/sr
    adl2 >= adl1 + (iws1 + iws2) / (2*sr)
    adl2 >= 1/kr + adl3 + (iws2 + iws3) / (2*sr)

    adl3 >= (iws3/2)/sr                         Write after read
    adl3 <= idlr - (1 + iws3/2)/sr              (allows feedback)

| Note
| Window sizes for opcodes other than deltapx are: deltap, deltapn: 1, deltapi: 2 (linear), deltap3: 4 (cubic)

## Examples

    a1      phasor 300.0
    a1      =  a1 - 0.5
    a_      delayr 1.0
    adel    phasor 4.0
    adel    =  sin (2.0 * 3.14159265 * adel) * 0.01 + 0.2
            deltapxw a1, adel, 32
    adel    phasor 2.0
    adel    =  sin (2.0 * 3.14159265 * adel) * 0.01 + 0.2
            deltapxw a1, adel, 32
    adel    =  0.3
    a2      deltapx adel, 32
    a1      =  0
            delayw a1

            out a2 * 20000.0

## See Also

deltapx

## Credits

Author: Istvan Varga
August 2001

New in version 4.13

Previous | Home | Next
deltapx | Up | diff