The Alternative Csound Reference Manual
Previous |  | Next

# areson

areson -- A notch filter whose transfer functions are the complements of the reson opcode.

## Description

A notch filter whose transfer functions are the complements of the reson opcode.

## Syntax

ar areson asig, kcf, kbw [, iscl] [, iskip]

## Initialization

iscl (optional, default=0) -- coded scaling factor for resonators. A value of 1 signifies a peak response factor of 1, i.e. all frequencies other than kcf are attenuated in accordance with the (normalized) response curve. A value of 2 raises the response factor so that its overall RMS value equals 1. (This intended equalization of input and output power assumes all frequencies are physically present; hence it is most applicable to white noise.) A zero value signifies no scaling of the signal, leaving that to some later adjustment (see balance). The default value is 0.

iskip (optional, default=0) -- initial disposition of internal data space. Since filtering incorporates a feedback loop of previous output, the initial status of the storage space used is significant. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

## Performance

ar -- the output signal at audio rate.

asig -- the input signal at audio rate.

kcf -- the center frequency of the filter, or frequency position of the peak response.

kbw -- bandwidth of the filter (the Hz difference between the upper and lower half-power points).

areson is a filter whose transfer functions is the complement of reson. Thus areson is a notch filter whose transfer functions represents the "filtered out" aspects of their complements. However, power scaling is not normalized in areson but remains the true complement of the corresponding unit. Thus an audio signal, filtered by parallel matching reson and areson units, would under addition simply reconstruct the original spectrum.

This property is particularly useful for controlled mixing of different sources (see lpreson). Complex response curves such as those with multiple peaks can be obtained by using a bank of suitable filters in series. (The resultant response is the product of the component responses.) In such cases, the combined attenuation may result in a serious loss of signal power, but this can be regained by the use of balance.

## Examples

Here is an example of the areson opcode. It uses the files areson.orc and areson.sco.

Example 1. Example of the areson opcode.

    /* areson.orc */
    ; Initialize the global variables.
    sr = 22050
    kr = 2205
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - an unfiltered noise waveform.
    instr 1
      ; Generate a white noise signal.
      asig rand 20000

      out asig
    endin

    ; Instrument #2 - a filtered noise waveform.
    instr 2
      ; Generate a white noise signal.
      asig rand 20000

      ; Filter it using the areson opcode.
      kcf init 1000
      kbw init 100
      afilt areson asig, kcf, kbw

      ; Clip the filtered signal's amplitude to 85 dB.
      a1 clip afilt, 2, ampdb(85)
      out a1
    endin
    /* areson.orc */

    /* areson.sco */
    ; Play Instrument #1 for two seconds.
    i 1 0 2
    ; Play Instrument #2 for two seconds.
    i 2 2 2
    e
    /* areson.sco */

## See Also

aresonk, atone, atonek, port, portk, reson, resonk, tone, tonek

Previous | Home | Next
apow | Up | aresonk