# Title

SRFI 28: Basic Format Strings

# Author

Scott G. Miller

# Status

This SRFI is currently in ``final'' status. To see an explanation of each status that a SRFI can hold, see here. You can access the discussion on this SRFI via the archive of the mailing list.

- Draft: 2002/03/23-2002/05/23
- Final: 2002/06/25

# Abstract

This document specifies Format Strings, a method of interpreting a Scheme string which contains a number of escape sequences that are replaced with other string data according to the semantics of each sequence.

# Rationale

Many Scheme systems provide access to a function called `format.` This function takes as arguments a format string, an ordinary Scheme string containing zero or more escape sequences, followed zero or more Scheme values. The procedure processes the format string and performs string replacement on the escape sequences according to the rules for each code. This SRFI defines a basic version of `format` which should allow portable code to be written using the function without much (if any) effort on the part of Scheme implementors.

# Specification

`format` `format-string [obj ...] -> string`

> Accepts a message template (a Scheme String), and processes it, replacing any escape sequences in order with one or more characters, the characters themselves dependent on the semantics of the escape sequence encountered.

> An escape sequence is a two character sequence in the string where the first character is a tilde '~'. Each escape code's meaning is as follows:

> - `~a` The corresponding value is inserted into the string as if printed with `display`.
> - `~s` The corresponding value is inserted into the string as if printed with `write`.
> - `~%` A newline is inserted.
> - `~~` A tilde '~' is inserted.

> `~a` and `~s`, when encountered, require a corresponding Scheme value to be present after the format string. The values provided as operands are used by the escape sequences in order. It is an error if fewer values are provided than escape sequences that require them.

> `~%` and `~~` require no corresponding value.

## Examples

    (format "Hello, ~a" "World!")
    ; => "Hello, World!"

    (format "Error, list is too short: ~s~%" '(one "two" 3))
    ; => "Error, list is too short: (one \"two\" 3))"

# Implementation

The implementation below requires SRFI-6 (Basic string ports) and SRFI-23 (Error reporting mechanism).

    (define format
      (lambda (format-string . objects)
        (let ((buffer (open-output-string)))
          (let loop ((format-list (string->list format-string))
                     (objects objects))
            (cond ((null? format-list) (get-output-string buffer))
                  ((char=? (car format-list) #\~)
                   (if (null? (cdr format-list))
                       (error 'format "Incomplete escape sequence")
                       (case (cadr format-list)
                         ((#\a)
                          (if (null? objects)
                              (error 'format "No value for escape sequence")
                              (begin
                                (display (car objects) buffer)
                                (loop (cddr format-list) (cdr objects)))))
    	             ((#\s)
                          (if (null? objects)
                              (error 'format "No value for escape sequence")
                              (begin
                                (write (car objects) buffer)
                                (loop (cddr format-list) (cdr objects)))))
                         ((#\%)
                          (newline buffer)
                          (loop (cddr format-list) objects))
                         ((#\~)
                          (write-char #\~ buffer)
                          (loop (cddr format-list) objects))
                         (else
                          (error 'format "Unrecognized escape sequence")))))
                  (else (write-char (car format-list) buffer)
                        (loop (cdr format-list) objects)))))))

# Copyright

Copyright (C) Scott G. Miller (2002). All Rights Reserved.

This document and translations of it may be copied and furnished to others, and derivative works that comment on or otherwise explain it or assist in its implementation may be prepared, copied, published and distributed, in whole or in part, without restriction of any kind, provided that the above copyright notice and this paragraph are included on all such copies and derivative works. However, this document itself may not be modified in any way, such as by removing the copyright notice or references to the Scheme Request For Implementation process or editors, except as needed for the purpose of developing SRFIs in which case the procedures for copyrights defined in the SRFI process must be followed, or as required to translate it into languages other than English.

The limited permissions granted above are perpetual and will not be revoked by the authors or their successors or assigns.

This document and the information contained herein is provided on an "AS IS" basis and THE AUTHOR AND THE SRFI EDITORS DISCLAIM ALL WARRANTIES, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO ANY WARRANTY THAT THE USE OF THE INFORMATION HEREIN WILL NOT INFRINGE ANY RIGHTS OR ANY IMPLIED WARRANTIES OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.

Last modified: Mon Apr 8 06:54:37 CDT 2002