# Title

SRFI 11: Syntax for receiving multiple values

# Author

Lars T Hansen

# Status

This SRFI is currently in ``final'' status. To see an explanation of each status that a SRFI can hold, see here. You can access the discussion via the archive of the mailing list.

- Received: 1999/09/10
- Draft: 1999/09/14-1999/11/12
- Revised: 1999/11/01
- Revised: 2000/03/15
- Final: 2000/03/15

# Abstract

The SRFI introduces syntactic forms LET-VALUES and LET*-VALUES that bind the values of expressions that return multiple values.

# Issues

None.

# Rationale

LET-VALUES and LET*-VALUES reduce the clutter of the CALL-WITH-VALUES notation for receiving multiple values.

# Specification

`(LET-VALUES ((<formals> <expression>) ...) <body>)`
Syntax

  Each <formals> should be a formal arguments list as for a LAMBDA expression, cf section 4.1.4 of the R5RS.

  The <expression>s are evaluated in the current environment, the variables of the <formals> are bound to fresh locations, the return values of the <expression>s are stored in the variables, the <body> is evaluated in the extended environment, and the values of the last expression of <body> are returned. The <body> is a <tail body>, cf section 3.5 of the R5RS.

  The matching of each <formals> to values is as for the matching of <formals> to arguments in a LAMBDA expression, and it is an error for an <expression> to return a number of values that does not match its corresponding <formals>.

                   (let-values (((a b . c) (values 1 2 3 4))))
                     (list a b c))            --> (1 2 (3 4))

                   (let ((a 'a) (b 'b) (x 'x) (y 'y))
                     (let-values (((a b) (values x y))
                                  ((x y) (values a b)))
                       (list a b x y)))       --> (x y a b)

`(LET*-VALUES ((<formals> <expression>) ...) <body>)`
Syntax

  Each <formals> should be a formal arguments list as for a LAMBDA expression, cf section 4.1.4 of the R5RS.

  LET*-VALUES is similar to LET-VALUES, but the bindings are performed sequentially from left to right, and the region of a binding indicated by (<formals> <expression>) is that part of the LET*-VALUES expression to the right of the binding. Thus the second binding is done in an environment in which the first binding is visible, and so on.

                   (let ((a 'a) (b 'b) (x 'x) (y 'y))
                     (let*-values (((a b) (values x y))
                                   ((x y) (values a b)))
                       (list a b x y)))       --> (x y x y)

# Implementation

The following implementation is written in R5RS Scheme. It is not compatible with the IEEE Scheme standard because the IEEE standard does not contain the high-level macro system.

The implementation assumes that some top-level names defined by the R5RS are bound to their original values.

    (define-syntax let-values
      (syntax-rules ()
        ((let-values (?binding ...) ?body0 ?body1 ...)
         (let-values "bind" (?binding ...) () (begin ?body0 ?body1 ...)))

        ((let-values "bind" () ?tmps ?body)
         (let ?tmps ?body))

        ((let-values "bind" ((?b0 ?e0) ?binding ...) ?tmps ?body)
         (let-values "mktmp" ?b0 ?e0 () (?binding ...) ?tmps ?body))

        ((let-values "mktmp" () ?e0 ?args ?bindings ?tmps ?body)
         (call-with-values
           (lambda () ?e0)
           (lambda ?args
             (let-values "bind" ?bindings ?tmps ?body))))

        ((let-values "mktmp" (?a . ?b) ?e0 (?arg ...) ?bindings (?tmp ...) ?body)
         (let-values "mktmp" ?b ?e0 (?arg ... x) ?bindings (?tmp ... (?a x)) ?body))

        ((let-values "mktmp" ?a ?e0 (?arg ...) ?bindings (?tmp ...) ?body)
         (call-with-values
           (lambda () ?e0)
           (lambda (?arg ... . x)
             (let-values "bind" ?bindings (?tmp ... (?a x)) ?body))))))

    (define-syntax let*-values
      (syntax-rules ()
        ((let*-values () ?body0 ?body1 ...)
         (begin ?body0 ?body1 ...))

        ((let*-values (?binding0 ?binding1 ...) ?body0 ?body1 ...)
         (let-values (?binding0)
           (let*-values (?binding1 ...) ?body0 ?body1 ...)))))

# Copyright

Copyright (C) Lars T Hansen (1999). All Rights Reserved.

This document and translations of it may be copied and furnished to others, and derivative works that comment on or otherwise explain it or assist in its implementation may be prepared, copied, published and distributed, in whole or in part, without restriction of any kind, provided that the above copyright notice and this paragraph are included on all such copies and derivative works. However, this document itself may not be modified in any way, such as by removing the copyright notice or references to the Scheme Request For Implementation process or editors, except as needed for the purpose of developing SRFIs in which case the procedures for copyrights defined in the SRFI process must be followed, or as required to translate it into languages other than English.

The limited permissions granted above are perpetual and will not be revoked by the authors or their successors or assigns.

This document and the information contained herein is provided on an "AS IS" basis and THE AUTHOR AND THE SRFI EDITORS DISCLAIM ALL WARRANTIES, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO ANY WARRANTY THAT THE USE OF THE INFORMATION HEREIN WILL NOT INFRINGE ANY RIGHTS OR ANY IMPLIED WARRANTIES OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE.

Last modified: Wed Aug 13 12:17:04 CDT 2003