>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary

Length / Angle | *. 0 0 0 | LCM (And)

`*.y` is a two-element list of the length and angle (in radians) of the hypotenuse of a triangle with base and altitude equal to the real and imaginary parts`y` .`` For example,`*. 3j4` is`5 0.927295`.

`x*.y` is the least common multiple of`x` and`y` .`` For boolean arguments (`0` and`1`) it is equivalent to and. Thus:

       0 1 *./ 0 1
    0 0
    0 1

Some properties of the length / angle are illustrated in the following, including the fact that the length (i.e. magnitude) of the product of two complex numbers is the product of their lengths, and the angle of the product is the sum of their angles:

       (| ; *. ; r./@*.) y=: 3j4
    +-+----------+---+
    |5|5 0.927295|3j4|
    +-+----------+---+

       x=: 2j_6
       *. x,y                               NB. Polar coordinates
    6.32456 _1.24905
          5 0.927295

       f=: */@:({."1) , +/@:(}."1)          NB. Product over first col and sum over last
       f *. x , y
    31.6228 _0.321751

       *. x * y                             NB. Length and angle of product
    31.6228 _0.321751

The least common multiple is the product divided by the GCD. For example:

       24 (+. ; *. ; */ % +.) 60
    +--+---+---+
    |12|120|120|
    +--+---+---+

>> << Ndx Usr Pri Phr Dic Rel Voc !: wd Help Dictionary