# filebox.tcl --
#
# This demonstration script prompts the user to select a file.
#
# RCS: @(#) $Id: filebox.tcl,v 1.1 1999/03/31 15:08:30 m-hirano Exp $

if {![info exists widgetDemo]} {
    error "This script should be run from the \"widget\" demo."
}

set w .filebox
catch {destroy $w}
toplevel $w
wm title $w "File Selection Dialogs"
wm iconname $w "filebox"
positionWindow $w

label $w.msg -font $font -wraplength 4i -justify left -text [langSel \
"Enter a file name in the entry box or click on the \"Browse\" buttons to select a file name using the file selection dialog." \
"エントリにファイル名を入力するか、\"選択\"ボタンを押してファイル選択ダイアログでファイル名を選択してください。"]
pack $w.msg -side top

frame $w.buttons
pack $w.buttons -side bottom -fill x -pady 2m
button $w.buttons.dismiss -text [langSel Dismiss 了解] -command "destroy $w"
button $w.buttons.code -text [langSel "See Code" "コード参照"] -command "showCode $w"
pack $w.buttons.dismiss $w.buttons.code -side left -expand 1

foreach i {open save} {
    set f [frame $w.$i]
    label $f.lab -text [langSel \
	    "Select a file to $i: " \
	    [if {$i == "open"} {concat "開くファイル: "} else {concat "保存するファイル: "}]] \
	    -anchor e
    entry $f.ent -width 20
    button $f.but -text [langSel "Browse ..." "選択 ..."] -command "fileDialog $w $f.ent $i"
    pack $f.lab -side left
    pack $f.ent -side left -expand yes -fill x
    pack $f.but -side left
    pack $f -fill x -padx 1c -pady 3
}

if ![string compare $tcl_platform(platform) unix] {
    checkbutton $w.strict -text [langSel "Use Motif Style Dialog" "Motif 風ダイアログを使用"] \
	-variable tk_strictMotif -onvalue 1 -offvalue 0
    pack $w.strict -anchor c
}

proc fileDialog {w ent operation} {
    #   Type names		Extension(s)	Mac File Type(s)
    #
    #---------------------------------------------------------
    set types [langSel {
	{"Text files"		{.txt .doc}	}
	{"Text files"		{}		TEXT}
	{"Tcl Scripts"		{.tcl}		TEXT}
	{"C Source Files"	{.c .h}		}
	{"All Source Files"	{.tcl .c .h}	}
	{"Image Files"		{.gif}		}
	{"Image Files"		{.jpeg .jpg}	}
	{"Image Files"		""		{GIFF JPEG}}
	{"All files"		*}
    } {
	{"テキストファイル"	{.txt .doc}	}
	{"テキストファイル"	{}		TEXT}
	{"Tcl スクリプト"	{.tcl}		TEXT}
	{"C ソースファイル"	{.c .h}		}
	{"全てのソースファイル"	{.tcl .c .h}	}
	{"画像ファイル"		{.gif}		}
	{"画像ファイル"		{.jpeg .jpg}	}
	{"画像ファイル"		""		{GIFF JPEG}}
	{"全てのファイル"	*}
    }]
    if {$operation == "open"} {
	set file [tk_getOpenFile -filetypes $types -parent $w]
    } else {
	set file [tk_getSaveFile -filetypes $types -parent $w \
	    -initialfile Untitled -defaultextension .txt]
    }
    if [string compare $file ""] {
	$ent delete 0 end
	$ent insert 0 $file
	$ent xview end
    }
}
