lfo
Prev | Orchestra Opcodes and Operators | Next

## lfo

lfo — A low frequency oscillator of various shapes.

## Description

A low frequency oscillator of various shapes.

## Syntax

    kres lfo kamp, kcps [, itype]

    ares lfo kamp, kcps [, itype]

## Initialization

itype (optional, default=0) -- determine the waveform of the oscillator. Default is 0.

- itype = 0 - sine

- itype = 1 - triangles

- itype = 2 - square (bipolar)

- itype = 3 - square (unipolar)

- itype = 4 - saw-tooth

- itype = 5 - saw-tooth(down)

The sine wave is implemented as a 4096 table and linear interpolation. The others are calculated.

## Performance

kamp -- amplitude of output

kcps -- frequency of oscillator

## Examples

Here is an example of the lfo opcode. It uses the file lfo.csd.

Example 236. Example of the lfo opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o lfo.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      kamp = 10
      kcps = 5
      itype = 4

      k1 lfo kamp, kcps, itype
      ar oscil p4, p5+k1, 1
      out ar
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1: an ordinary sine wave.
    f 1 0 32768 10 1

    ; p4 = amplitude of the output signal.
    ; p5 = frequency (in cycles per second) of the output signal.
    ; Play Instrument #1 for two seconds.
    i 1 0 2 10000 220
    e

    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: John ffitch
University of Bath/Codemist Ltd.
Bath, UK
November 1998

New in Csound version 3.491

Prev | Up | Next
kweibull | Home | limit