integ
Prev | Orchestra Opcodes and Operators | Next

## integ

integ — Modify a signal by integration.

## Description

Modify a signal by integration.

## Syntax

    ares integ asig [, iskip]

    kres integ ksig [, iskip]

## Initialization

iskip (optional) -- initial disposition of internal save space (see reson). The default value is 0.

## Performance

integ and diff perform integration and differentiation on an input control signal or audio signal. Each is the converse of the other, and applying both will reconstruct the original signal. Since these units are special cases of low-pass and high-pass filters, they produce a scaled (and phase shifted) output that is frequency-dependent. Thus diff of a sine produces a cosine, with amplitude 2 * sin(pi * Hz / sr) that of the original (for each component partial); integ will inversely affect the magnitudes of its component inputs. With this understanding, these units can provide useful signal modification.

## Examples

Here is an example of the integ opcode. It uses the file integ.csd.

Example 228. Example of the integ opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o integ.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1 -- a differentiated signal.
    instr 1
      ; Generate a band-limited pulse train.
      asrc buzz 20000, 440, 20,  1

      ; Differentiate the signal.
      adiff diff asrc

      out adiff
    endin

    ; Instrument #2 -- a re-integrated signal.
    instr 2
      ; Generate a band-limited pulse train.
      asrc buzz 20000, 440, 20,  1

      ; Differentiate the signal.
      adiff diff asrc

      ; Re-integrate the previously differentiated signal.
      a1 integ adiff

      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    ; Play Instrument #2 for one second.
    i 2 1 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

diff, downsamp, interp, samphold, upsamp

## Credits

Example written by Kevin Conder.

Prev | Up | Next
int | Home | interp