butterhp
Prev | Orchestra Opcodes and Operators | Next

## butterhp

butterhp — A high-pass Butterworth filter.

## Description

Implementation of second-order high-pass Butterworth filter. This opcode can also be written as buthp.

## Syntax

    ares butterhp asig, kfreq [, iskip]

## Initialization

iskip (optional, default=0) -- Skip initialization if present and non-zero.

## Performance

These filters are Butterworth second-order IIR filters. They are slightly slower than the original filters in Csound, but they offer an almost flat passband and very good precision and stopband attenuation.

asig -- Input signal to be filtered.

kfreq -- Cutoff or center frequency for each of the filters.

## Examples

Here is an example of the butterhp opcode. It uses the file butterhp.csd.

Example 57. Example of the butterhp opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    Silent
    -odac           -idac     -d    ;;;realtime output
    ; For Non-realtime ouput leave only the line below:
    ; -o butterhp.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 22050
    kr = 2205
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - an unfiltered noise waveform.
    instr 1
      ; White noise signal
      asig rand 22050

      out asig
    endin

    ; Instrument #2 - a filtered noise waveform.
    instr 2
      ; White noise signal
      asig rand 22050

      ; Filter it, passing frequencies above 250 Hz.
      ahp butterhp asig, 250

      out ahp
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    ; Play Instrument #2 for two seconds.
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

butterbp, butterbr, butterlp

## Credits

Author: Paris Smaragdis
MIT, Cambridge
1995

Prev | Up | Next
butterbr | Home | butterlp