TRANSLATION Rapport;
		     { Sortie HTML d'un document Rapport pour Thot }
	             { I. Vatton 		 Decembre 1995     }
                     { d'apres verion Ch. Rolland de Juin 94       }
		     { Ajout  Index              H. Richy 5/97     }

LINELENGTH 78;          { Longueur maximale d'une ligne }

BUFFERS
   NomImage(Picture);	{ Tampon pour le nom de l'image }

COUNTERS

   CptBiblio: Rank of Citation_biblio;
   CptFigure: Set 1 on Rapport  Add 1 on Figure;
   CptFormule: Set 1 on Rapport  Add 1 on Formule_num\351rot\351e;
   CptSect1: Rank of Section 1;
   CptSect2: Rank of Section 2;
   CptSect3: Rank of Section 3;
   CptSect4: Rank of Section 4;
   CptAnnexe: Rank of Annexe;
   CptNote: Rank of Note;
   CptAffiliation: Rank of Affiliation;

CONST
   BaliseF      = '">';				{ Fermeture de balise        }
   AncreDef     = '<a name="';			{ Arrivee d'un lien          }
   AncreRef     = '<a href="';			{ Depart d'un lien           }
   AncreFin     = '</a>';			{ Fermeture d'ancre de lien  }
   Base         = '<BASE HREF="http://www-bi.imag.fr/">\12'; {Base du serveur}
   SectFin      = 'fin';
   StartOfFile1 = '<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 3.2//EN">\12';
   StartOfFile2 = '<html>\12<head>\12<!-- Document generated by Thot -->\12';
   EndOfHead    = '</head>\12<body>\12';
   EndOfFile    = '\12</body>\12</html>\12';
   SuffixFinal  = 'X';
   IDtitre	= 'ti';
#ifdef MULTI_FILES
   Separ        = '<hr>\12<p>';
   ButtonSect   = '[Section ';
   EndButton    = ']';
   Space        = '   ';
   ButtonToC    = '[Table of contents]';
#endif

VAR

   IdSect1        : 'secta' Value(CptSect1);
   IdSect1Annexe  : 'app' Value(CptAnnexe, Uppercase) 'secta' Value(CptSect1);
   NumSect1       : Value(CptSect1);
   NumSect1Annexe : Value(CptAnnexe, Uppercase) '.' Value(CptSect1);
   IdSect2        : 'sectb' Value(CptSect1) Value(CptSect2);
   IdSect2Annexe  : 'app' Value(CptAnnexe, Uppercase) 'sectb' Value(CptSect1)
		    Value(CptSect2);
   NumSect2       : Value(CptSect1) '.' Value(CptSect2);
   NumSect2Annexe : Value(CptAnnexe, Uppercase) '.' Value(CptSect1) '.'
		    Value(CptSect2);
   IdSect3        : 'sectc' Value(CptSect1) Value(CptSect2) Value(CptSect3);
   IdSect3Annexe  : 'app' Value(CptAnnexe, Uppercase) 'sectc' Value(CptSect1)
		    Value(CptSect2) Value(CptSect3);
   NumSect3       : Value(CptSect1) '.' Value(CptSect2) '.' Value(CptSect3);
   NumSect3Annexe : Value(CptAnnexe, Uppercase) '.' Value(CptSect1) '.'
		    Value(CptSect2) '.' Value(CptSect3);
   IdSect4        : 'sectd' Value(CptSect1) Value(CptSect2) Value(CptSect3)
		    Value(CptSect4);
   IdSect4Annexe  : 'app' Value(CptAnnexe, Uppercase) 'sectd' Value(CptSect1)
		    Value(CptSect2) Value(CptSect3) Value(CptSect4);
   NumSect4       : Value(CptSect1) '.' Value(CptSect2) '.' Value(CptSect3) '.'
		    Value(CptSect4);
   NumSect4Annexe : Value(CptAnnexe, Uppercase) '.' Value(CptSect1) '.'
		    Value(CptSect2) '.' Value(CptSect3) '.' Value(CptSect4);
   IdFormule : 'math' Value(CptFormule);
   NumFormule: Value(CptFormule);
   IdBiblio  : 'bib' Value(CptBiblio);
   {NumBib    : '[' Value(CptBiblio) ']';}
   IdFigure  : 'fig' Value(CptFigure);
   NumFigure : Value(CptFigure);
   IdNote    : 'not' Value(CptNote);
   NumNote   : ' [' Value(CptNote) ']';
   IdAnnexe  : 'appendix' Value(CptAnnexe);
   NumAnnexe : Value(CptAnnexe, Uppercase);
   IdAffiliation: 'affil' Value(CptAffiliation);
   NumAffiliation: '(' Value(CptAffiliation, lowercase) ')';
#ifdef MULTI_FILES
   MainFileName  : FileName Value(CptSect1) Extension;
   MainFile      : FileDir FileName Value(CptSect1) Extension;
   LastFileName  : FileName SuffixFinal Extension;
   LastFile      : FileDir FileName SuffixFinal Extension;
   AncreTMSect   : 'a href="' FileName Value(CptSect1) Extension '#';
   AncreTMLast   : '<a href="' FileName SuffixFinal Extension '#';
   FichierTMname : FileDir FileName '.toc' Extension;
#endif
   AncreTM   : '<a href="' FileName Extension '#';
   FichierTM : FileDir FileName '.toc' Extension;
   LinkToC   : '<link href="' FileName '.toc' Extension '" rel="ToC">\12';
   LinkIndex : '<link href="' FileName '.idx1' Extension '" rel="Index">\12';

RULES

   Rapport :
	BEGIN
#ifndef MULTI_FILES
	Use ExtIndexH for ExtIndex;
#endif
	Use ParagraphH for Paragraphe;          { Utiliser schema externe   }
	Use RefBibH for RefBib;                 {        -- idem --         }
	Use FichierH for Fichier;
	Use DrawH for Draw;
	Use ArbreH for Arbre;
	Use Arbre2H for Arbre2;
	Use TableH for Table;
	Use Draw2H for Draw2;
	Create StartOfFile1;
        Create StartOfFile2;
	Create '<title>';
	Create DocumentName;
	Create '</title>\12';
	Create LinkToC;
	Create LinkIndex;
{***	Create Base;	****} { Serveur HTML    }
	Create EndOfHead;
	Get Notes After;                        { Mettre les notes a la fin }
#ifdef MULTI_FILES
	Create Separ After;
	Create AncreRef After;
	Create FichierTMname After;
	Create BaliseF After;
	Create ButtonToC After;
	Create AncreFin After;
#endif
	Create EndOfFile After;
        Create IN FichierTM StartOfFile1;
        Create IN FichierTM StartOfFile2;
	Create IN FichierTM '<title>';
	Create IN FichierTM DocumentName;
	Create IN FichierTM '.toc</title>\12';
	Create IN FichierTM '<link href="';
	Create IN FichierTM FileName;
	Create IN FichierTM Extension;
	Create IN FichierTM '" rel="Chapter">\12';
{****	Create IN FichierTM Base;	****}
	Create IN FichierTM EndOfHead;
	Create IN FichierTM EndOfFile After;
	END;

   Entete:
	BEGIN
	END;

   Titre_courant:
	BEGIN
	Remove;
	END;

   Auteurs_courants:
	BEGIN
	Remove;
	END;

   R\351f\351rence:
	BEGIN
	Create '<pre>\12Reference: ' ;
	Create '<em>';
	Create '</em></pre>\12' After;
	END;

   Statut:
	BEGIN
	  Create '<pre>\12<em>';
	  Create '</em></pre>\12' After;
	END;

   Date_de_mise_a_jour :
	BEGIN
	Create '<pre>\12Date: ' ;
	Create '</pre>\12' After;
	END;

   Titre :
	BEGIN
	Create '\12<h1>';
#ifdef MULTI_FILES
	Create AncreDef;
	Create IDtitre;
	Create BaliseF;
	Create AncreFin After;
#endif
	Create '</h1>\12' After;
	Create IN FichierTM '\12<h1>';
#ifdef MULTI_FILES
	Create IN FichierTM AncreTM;
	Create IN FichierTM IDtitre;
	Create IN FichierTM BaliseF;
#endif
	Create IN FichierTM Content;
#ifdef MULTI_FILES
	Create IN FichierTM AncreFin;
#endif
	Create IN FichierTM '</h1>';
	END;

   Auteurs:
	BEGIN
	END;

   Auteur :
	BEGIN
	Create '<address>';
	Create '</address>\12' After;
	END;

   Affiliations:
	BEGIN
	END;
	
   Affiliation :
	BEGIN
	Create '<code>';
	if referred
	   BEGIN
	   Create AncreDef;
	   Create IdAffiliation;
	   Create BaliseF;
	   Create NumAffiliation;
	   Create AncreFin;
	   END;
	Create '<br></code>\12' After;
	END;

   Ref_affiliation :
	BEGIN
	Create AncreRef;
	Create '#';
	Create Referred IdAffiliation;
	Create BaliseF;
	Create Referred NumAffiliation;
	Create AncreFin After;
	END;

   R\351sum\351 :
	BEGIN
	Create '<dl>\12<dt><b>Abstract:</b>\12<dd>';
	Create '</dl>\12' After;
	END;

   Mots_cl\351s :
	BEGIN
	Create '<dl>\12<dt><b>Keywords: </b>\12<dd>';
	Create '</dl>\12' After;
	END;

   Heading:
	BEGIN
	END;

   Title:
	BEGIN
	Create '<dl>\12<dt><b>Title: </b>\12<dd>';
	Create '</dl>\12' After;
	END;

   Abstract :
	BEGIN
	Create '<dl>\12<dt><b>R&eacute;sum&eacute; :</b>\12<dd>';
	Create '</dl>\12' After;
	END;

   Keywords :
	BEGIN
	Create '<dl>\12<dt><b>Mots cl&eacute; : </b>\12<dd>';
	Create '</dl>\12' After;
	END;

   Corps:
	BEGIN
	create '\12<hr>\12';
	END;

   Pr\351ambule :
        BEGIN
        END;

   Partie_finale :
        BEGIN
#ifdef MULTI_FILES
	Create Separ;
	Create AncreRef;
	Create LastFileName;
	Create BaliseF;
	Create '[Last section]';
	Create AncreFin;
	Create Space;
	Create AncreRef;
	Create FichierTMname;
	Create BaliseF;
	Create ButtonToC;
	Create AncreFin;
	Create EndOfFile;
	ChangeMainFile LastFile;

	Create StartOfFile1;
	Create StartOfFile2;
	Create '<title>';
	Create (DocumentName '.X');
	Create '</title>\12';
	Create LinkToC;
	Create EndOfHead;
#endif
        END;

   Sections_finales:
        BEGIN
        END;

   Suite_sections:
        BEGIN
        END;

   Section :
	BEGIN
#ifdef MULTI_FILES
	If not within Section and not within Partie_finale
	   BEGIN
	   Create Separ;
	   Create AncreRef;
	   Create MainFileName;
	   Create BaliseF;
	   Create ButtonSect;
	   Create NumSect1;
	   Create EndButton;
	   Create AncreFin;
	   Create Space;
	   Create AncreRef;
	   Create FichierTMname;
	   Create BaliseF;
	   Create ButtonToC;
	   Create AncreFin;
	   Create EndOfFile;
	   ChangeMainFile MainFile;

	   Create StartOfFile1;
	   Create StartOfFile2;
	   Create '<title>';
	   Create (DocumentName '.' Value(CptSect1));
	   Create '</title>\12';
	   Create LinkToC;
	   Create EndOfHead;
	   END;
#endif
	Create '\12<div class=Section>';
	If within Sections_finales
	   Create '\12<h2>';
	If not within Sections_finales and not within Section
	   Create '\12<h2>';
	If within 1 Section
	   Create '\12<h3>';
	If within 2 Section
	   Create '\12<h4>';
	If within >2 Section
	   Create '\12<h5>';
	Create AncreDef;
	If within Sections_finales
	   Create SectFin;
	If within 0 Section and not within Annexe
	   Create IdSect1;
	If within 0 Section and within Annexe
	   Create IdSect1Annexe;
	If within 1 Section and not within Annexe
	   Create IdSect2;
	If within 1 Section and within Annexe
	   Create IdSect2Annexe;
	If within 2 Section and not within Annexe
	   Create IdSect3;
	If within 2 Section and within Annexe
	   Create IdSect3Annexe;
	If within >2 Section and not within Annexe
	   Create IdSect4;
	If within >2 Section and within Annexe
	   Create IdSect4Annexe;
	Create BaliseF;
	If within 0 Section and not within Annexe
	   and not within Sections_finales
	   Create NumSect1;
	If within 0 Section and within Annexe
	   Create NumSect1Annexe;
	If within 1 Section and not within Annexe
	   and not within Sections_finales
	   Create NumSect2;
	If within 1 Section and within Annexe
	   Create NumSect2Annexe;
	If within 2 Section and not within Annexe
	   and not within Sections_finales
	   Create NumSect3;
	If within 2 Section and within Annexe
	   Create NumSect3Annexe;
	If within 3 Section and not within Annexe
	   and not within Sections_finales
	   Create NumSect4;
	If within 3 Section and within Annexe
	   Create NumSect4Annexe;
	Create AncreFin;
	Create ' ';
	IF Referred Create AncreDef;
	IF Referred Create RefId;
	IF Referred Create BaliseF;
	Get Included Titre_section;
	IF Referred Create AncreFin;
	If within Sections_finales
	   Create '</h2>\12';
	If not within Sections_finales and not within Section
	   Create '</h2>\12';
	If within 1 Section
	   Create '</h3>\12';
	If within 2 Section
	   Create '</h4>\12';
	If within >2 Section
	   Create '</h5>\12';
	Create '</div>\12' after;
	END;

   Titre_section:
	BEGIN
	If within 1 Section
	   Create IN FichierTM '\12\12<h2>';
	If within 2 Section
	   Create IN FichierTM '\12<h3>';
	If within 3 Section
	   Create IN FichierTM '\12<h4>';
	If within >3 Section
	   Create IN FichierTM '\12<h5>';
#ifdef MULTI_FILES
	If not within Partie_finale
	   Create IN FichierTM AncreTMSect;
	If within Partie_finale
	   Create IN FichierTM AncreTMLast;
#else
	Create IN FichierTM AncreTM;
#endif
	If within Sections_finales
	   Create IN FichierTM SectFin;
	If within 1 Section and not within Annexe
	   Create IN FichierTM IdSect1;
	If within 1 Section and within Annexe
	   Create IN FichierTM IdSect1Annexe;
	If within 2 Section and not within Annexe
	   Create IN FichierTM IdSect2;
	If within 2 Section and within Annexe
	   Create IN FichierTM IdSect2Annexe;
	If within 3 Section and not within Annexe
	   Create IN FichierTM IdSect3;
	If within 3 Section and within Annexe
	   Create IN FichierTM IdSect3Annexe;
	If within >3 Section and not within Annexe
	   Create IN FichierTM IdSect4;
	If within >3 Section and within Annexe
	   Create IN FichierTM IdSect4Annexe;
	Create IN FichierTM BaliseF;
	If within 1 Section and not within Annexe
	  and not within Sections_finales
	  Create IN FichierTM NumSect1;
	If within 1 Section and within Annexe
	  Create IN FichierTM NumSect1Annexe;
	If within 2 Section and not within Annexe
	  and not within Sections_finales
	  Create IN FichierTM NumSect2;
	If within 2 Section and within Annexe
	  Create IN FichierTM NumSect2Annexe;
	If within 3 Section and not within Annexe
	  and not within Sections_finales
	  Create IN FichierTM NumSect3;
	If within 3 Section and within Annexe
	  Create IN FichierTM NumSect3Annexe;
	If within >3 Section and not within Annexe
	  and not within Sections_finales
	  Create IN FichierTM NumSect4;
	If within >3 Section and within Annexe
	  Create IN FichierTM NumSect4Annexe;
	Create IN FichierTM '  ';
	Create IN FichierTM Content;
	Create IN FichierTM AncreFin;
	If within 1 Section
	  Create IN FichierTM '</h2>';
	If within 2 Section
	  Create IN FichierTM '</h3>';
	If within 3 Section
	  Create IN FichierTM '</h4>';
	If within >3 Section
	  Create IN FichierTM '</h5>';
	END;

   Ref_section :
	BEGIN
	Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   Create FileName;
	IF NOT ExternalRef and Target Within Partie_finale
	   Create SuffixFinal;
	IF NOT ExternalRef and not Target Within Partie_finale
	   and target within Suite_sections
	   Create Referred NumSect1;
	IF NOT ExternalRef
	   Create Extension;
#endif
	Create '#';
	IF ExternalRef
	   Create Referred RefId;
	IF not ExternalRef and target within Sections_finales
	   Create SectFin;
	IF not ExternalRef and target within 0 Section and not within Annexe
	   Create Referred IdSect1;
	IF not ExternalRef and target within 0 Section and within Annexe
	   Create Referred IdSect1Annexe;
	IF not ExternalRef and target within 1 Section and not within Annexe
	   Create Referred IdSect2;
	IF not ExternalRef and target within 1 Section and within Annexe
	   Create Referred IdSect2Annexe;
	IF not ExternalRef and target within 2 Section and not within Annexe
	   Create Referred IdSect3;
	IF not ExternalRef and target within 2 Section and within Annexe
	   Create Referred IdSect3Annexe;
	IF not ExternalRef and target within >2 Section and not within Annexe
	   Create Referred IdSect4;
	IF not ExternalRef and target within >2 Section and within Annexe
	   Create Referred IdSect4Annexe;
	Create BaliseF;
	If target within Sections_finales
	   Create '[ref]';
	If target within 0 Section and not within Annexe
	   and not target within Sections_finales
	   Create Referred NumSect1;
	If target within 0 Section and within Annexe
	   Create Referred NumSect1Annexe;
	If target within 1 Section and not within Annexe
	   and not target within Sections_finales
	   Create Referred NumSect2;
	If target within 1 Section and within Annexe
	   Create Referred NumSect2Annexe;
	If target within 2 Section and not within Annexe
	   and not target within Sections_finales
	   Create Referred NumSect3;
	If target within 2 Section and within Annexe
	   Create Referred NumSect3Annexe;
	If target within >2 Section and not within Annexe
	   and not target within Sections_finales
	   Create Referred NumSect4;
	If target within >2 Section and within Annexe
	   Create Referred NumSect4Annexe;
	Create AncreFin After;
	END;

  Suite_paragraphes:
        BEGIN
        END;

  Groupe_titr\351:
        BEGIN
        END;

  Titre_groupe:
	BEGIN
	Create '\12<h6>' before;
	Create '</h6>\12' after;
	END;

  Ref_groupe_titr\351:
	BEGIN
	END;

  Groupe:
	BEGIN
	END;

  Image:
	BEGIN
	END;

  Formule_num\351rot\351e :
	BEGIN
	IF Referred 
	   BEGIN
	   Create AncreDef;
	   Create IdFormule;
	   Create BaliseF;
	   END;
	Create '\12(';
	Create NumFormule;
	Create ')  ';
	IF Referred 
	   Create AncreFin;
	END;

   Ref_formule :
	BEGIN
	Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   Create FileName;
	IF NOT ExternalRef and Target Within Partie_finale
	   Create SuffixFinal;
	IF NOT ExternalRef and not Target Within Partie_finale
	   and target within Suite_sections
	   Create Referred NumSect1;
	IF NOT ExternalRef
	   Create Extension;
#endif
	Create '#';
	Create Referred IdFormule;
	Create BaliseF;
	Create Referred NumFormule;
	Create AncreFin;
	END;

   Math :
        BEGIN
        Use MathH;
        END;

   Figure :
	BEGIN
	Create '\12' After;
	END;

   Illustration :
	BEGIN
	END;

   Image\240:
	BEGIN
	END;

   L\351gende_figure :
	BEGIN
        Create '\12<p>';
	IF Referred 
	   BEGIN
	   Create AncreDef;
	   Create IdFigure;
	   Create BaliseF;
	   END;
	Create '\12Figure ';
	Create NumFigure;
	IF Referred 
	   Create AncreFin;
	Create ' - <em>';
	Create '</em>' After;
        Create '</p>' After;
	END;

   Ref_figure :
	BEGIN
        Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   Create FileName;
	IF NOT ExternalRef and Target Within Partie_finale
	   Create SuffixFinal;
	IF NOT ExternalRef and not Target Within Partie_finale
	   and target within Suite_sections
	   Create Referred NumSect1;
	IF NOT ExternalRef
	   Create Extension;
#endif
	Create '#';
	Create Referred IdFigure;
        Create BaliseF;
	Create ' ';
	Create Referred NumFigure;
	Create AncreFin;
	END;

   Notes:
	BEGIN
	Create '<h2>Footnotes</h2>';
        Create '\12<dl>\12';
	Create '\12</dl>\12' After;
	END;

   Note :
	BEGIN
	Create '\12<dt>';
	Create AncreDef;
	Create IdNote;
	Create BaliseF;
	Create NumNote;
	Create AncreFin;
	Create '\12<dd>';
	Create '</dd>\12' After;
	END;

   Ref_note :
	BEGIN
	Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   Create FileName;
	IF NOT ExternalRef and Target Within Partie_finale
	   Create SuffixFinal;
	IF NOT ExternalRef and not Target Within Partie_finale
	   and target within Suite_sections
	   Create Referred NumSect1;
	IF NOT ExternalRef
	   Create Extension;
#endif
	Create '#';
	Create Referred IdNote;
	Create BaliseF;
	Create Referred NumNote;
	Create AncreFin After;
	END;

   Indice :
	BEGIN
	END;

   Exposant :
	BEGIN
	END;

   Bibliographie :
	BEGIN
	Create '\12<h2><a name="biblio">References</a></h2>\12';
	Create '\12<dl>\12';
	Create '\12</dl>\12' After;
	Create IN FichierTM '\12<h2>';
#ifdef MULTI_FILES
	Create IN FichierTM AncreTMLast;
#else
	Create IN FichierTM AncreTM;
#endif
	Create IN FichierTM 'biblio">References</a></h2>\12';
	END;

   Citation_biblio :
	BEGIN
	Create '\12<dt>';
	Create AncreDef;
	Create IdBiblio;
	Create BaliseF;
	{Create NumBib;}
	{Create AncreFin;}
	END;

   RefBib:
	BEGIN
	END;

   Ref_biblio :
	BEGIN
	Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   BEGIN
	   Create FileName;
	   Create SuffixFinal;
	   Create Extension;
	   END;
#endif
	Create '#';
	Create Referred IdBiblio;
	Create BaliseF;
	Copy Referred Ident(RefBib);
	Create AncreFin After;
	END;

   Annexes :
	BEGIN
	Create '\12<hr>\12<div class=Section>\12<h1>Annexes</h1>\12';
	Create in FichierTM '\12<hr>\12<h1>Annexes</h1>\12';
	Create '</div>\12' after;
	END;

   Annexe:
	BEGIN
	create '<hr>';
	END;

   Titre_annexe:
	BEGIN
	Create '\12<h2>';
	Create AncreDef;
	Create IdAnnexe;
	Create BaliseF;
	Create NumAnnexe;
	Create AncreFin;
	Create '  ';
	Create '</h2>\12' After;

	Create in FichierTM '\12<h2>';
#ifdef MULTI_FILES
	Create IN FichierTM AncreTMLast;
#else
	Create IN FichierTM AncreTM;
#endif
	Create IN FichierTM IdAnnexe;
	Create IN FichierTM BaliseF;
	Create IN FichierTM NumAnnexe;
	Create IN FichierTM '  ';
	Create IN FichierTM Content;
	Create IN FichierTM '</a></h2>\12';
	END;

   Ref_annexe:
	BEGIN
	Create AncreRef;
	IF ExternalRef
	   BEGIN
	   Create Referred DocumentName;
	   Create Extension;
	   END;
#ifdef MULTI_FILES
	IF NOT ExternalRef
	   BEGIN
	   Create FileName;
	   Create SuffixFinal;
	   Create Extension;
	   END;
#endif
	Create '#';
	Create Referred IdAnnexe;
	Create BaliseF;
	Create Referred NumAnnexe;
	Create AncreFin After;
	END;

   Titre_courant_annexe:
	BEGIN
	Remove;
	END;

   GRAPHICS_UNIT :
	BEGIN
	Remove;
	END;

   PICTURE_UNIT :
	BEGIN
	Create '<img src="';
	Create NomImage After;
	Create '" alt="Image ' After;
	Create NomImage After;
	Create '">' After;
	END;

ATTRIBUTES

   Importance = D\351finition :
	BEGIN
	Create '<em>';
	Create '</em>' After;	
	END;

   Importance = Important :
	BEGIN
	Create '<strong>';
	Create '</strong>' After;	
	END;

   Num\351ro_prem_page:
	BEGIN
	END;

   Num\351ro_prem_section:
	BEGIN
	END;

   Type_auteur = Auteur_principal:
	BEGIN
	Create '<b>';
	Create '</b>' after;
	END;

   Type_auteur = Auteur_secondaire:
	BEGIN
	END;

PRESENTATION

   Style = Bold:
	BEGIN
	Create '<b>';
	Create '</b>' After;	
	END;

   Style = Italics:
	BEGIN
	Create '<i>';
	Create '</i>' After;	
	END;

   Font = Courier:
	BEGIN
	Create '<tt>';
	Create '</tt>' After;
	END;

TextTRANSLATE Latin
	BEGIN
	'<'    -> '&lt;';
	'>'    -> '&gt;';
	'&'    -> '&amp;';
	'\212' -> '<br>\12';
	'\230' -> 'oe'; { '&oelig;'}
	'\231' -> 'OE'; {'&OElig;'}
	'\240' -> ' ';      { '&nbsp;'}
	'\241' -> '&iexcl;';
	'\242' -> '&cent;';
	'\243' -> '&pound;';
	'\244' -> '&curren;';
	'\245' -> '&yen;';
	'\246' -> '&brvbar;';
	'\247' -> '&sect;';
	'\250' -> '&die;';
	'\251' -> '&copy;';
	'\252' -> '&ordf;';
	'\253' -> '&laquo;';
	'\254' -> '&not;';
	'\255' -> '&hyphen;';
	'\256' -> '&reg;';
	'\257' -> '&macr;';
	'\260' -> '&deg;';
	'\261' -> '&plusmn;';
	'\262' -> '&sup2;';
	'\263' -> '&sup3;';
	'\264' -> '&acute;';
	'\265' -> '&micro;';
	'\266' -> '&para;';
	'\267' -> '&middot;';
	'\270' -> '&cedil;';
	'\271' -> '&sup1;';
	'\272' -> '&ordm;';
	'\273' -> '&raquo;';
	'\274' -> '&frac14;';
	'\275' -> '&frac12;';
	'\276' -> '&frac34;';
	'\277' -> '&iquest;';
	'\300' -> '&Agrave;';
	'\301' -> '&Aacute;';
	'\302' -> '&Acirc;';
	'\303' -> '&Atilde;';
	'\304' -> '&Auml;';
	'\305' -> '&Aring;';
	'\306' -> '&AElig;';
	'\307' -> '&Ccedil;';
	'\310' -> '&Egrave;';
	'\311' -> '&Eacute;';
	'\312' -> '&Ecirc;';
	'\313' -> '&Euml;';
	'\314' -> '&Igrave;';
	'\315' -> '&Iacute;';
	'\316' -> '&Icirc;';
	'\317' -> '&Iuml;';
	'\320' -> '&Eth;';
	'\321' -> '&Ntilde;';
	'\322' -> '&Ograve;';
	'\323' -> '&Oacute;';
	'\324' -> '&Ocirc;';
	'\325' -> '&Otilde;';
	'\326' -> '&Ouml;';
	'\327' -> 'OE';  {'&times;';}
	'\330' -> '&Oslash;';
	'\331' -> '&Ugrave;';
	'\332' -> '&Uacute;';
	'\333' -> '&Ucirc;';
	'\334' -> '&Uuml;';
	'\335' -> '&Yacute;';
	'\336' -> '&THORN;';
	'\337' -> '&szlig;';
	'\340' -> '&agrave;';
	'\341' -> '&aacute;';
	'\342' -> '&acirc;';
	'\343' -> '&atilde;';
	'\344' -> '&auml;';
	'\345' -> '&aring;';
	'\346' -> '&aelig;';
	'\347' -> '&ccedil;';
	'\350' -> '&egrave;';
	'\351' -> '&eacute;';
	'\352' -> '&ecirc;';
	'\353' -> '&euml;';
	'\354' -> '&igrave;';
	'\355' -> '&iacute;';
	'\356' -> '&icirc;';
	'\357' -> '&iuml;';
	'\360' -> '&eth;';
	'\361' -> '&ntilde;';
	'\362' -> '&ograve;';
	'\363' -> '&oacute;';
	'\364' -> '&ocirc;';
	'\365' -> '&otilde;';
	'\366' -> '&ouml;';
	'\367' -> 'oe'; { '&divide;' }
	'\370' -> '&oslash;';
	'\371' -> '&ugrave;';
	'\372' -> '&uacute;';
	'\373' -> '&ucirc;';
	'\374' -> '&uuml;';
	'\375' -> '&yacute;';
	'\376' -> '&thorn;';
	'\377' -> '&yuml;';
	END;
END
