Search processing.org:

Reference for Processing version 1.0+. If you have a previous version, use the reference included with your software. If you see any errors or have any comments, let us know.

Name | ### noise()
Examples |
    float xoff = 0.0;
    void draw()
    {
      background(204);
      xoff = xoff + .01;
      float n = noise(xoff) * width;
      line(n, 0, n, height);
    }
    float noiseScale=0.02;
    void draw() {
      background(0);
      for(int x=0; x < width; x++) {
        float noiseVal = noise((mouseX+x)*noiseScale,
                                mouseY*noiseScale);
        stroke(noiseVal*255);
        line(x, mouseY+noiseVal*80, x, height);
      }
    }
Description | Returns the Perlin noise value at specified coordinates. Perlin noise is a random sequence generator producing a more natural ordered, harmonic succession of numbers compared to the standard random() function. It was invented by Ken Perlin in the 1980s and been used since in graphical applications to produce procedural textures, natural motion, shapes, terrains etc. The main difference to the random() function is that Perlin noise is defined in an infinite n-dimensional space where each pair of coordinates corresponds to a fixed semi-random value (fixed only for the lifespan of the program). The resulting value will always be between 0.0 and 1.0. Processing can compute 1D, 2D and 3D noise, depending on the number of coordinates given. The noise value can be animated by moving through the noise space as demonstrated in the example above. The 2nd and 3rd dimension can also be interpreted as time. The actual noise is structured similar to an audio signal, in respect to the function's use of frequencies. Similar to the concept of harmonics in physics, perlin noise is computed over several octaves which are added together for the final result. Another way to adjust the character of the resulting sequence is the scale of the input coordinates. As the function works within an infinite space the value of the coordinates doesn't matter as such, only the distance between successive coordinates does (eg. when using noise() within a loop). As a general rule the smaller the difference between coordinates, the smoother the resulting noise sequence will be. Steps of 0.005-0.03 work best for most applications, but this will differ depending on use.
Syntax |
    noise(x)
    noise(x, y)
    noise(x, y, z)
Parameters |
x | float: x coordinate in noise space
y | float: y coordinate in noise space
z | float: z coordinate in noise space
Returns | float
Usage | Web & Application
Related | noiseDetail() random()

Updated on November 22, 2008 08:39:25pm PST