The Alternative Csound Reference Manual
Previous |  | Next

# rand

rand -- Generates a controlled random number series.

## Description

Output is a controlled random number series between -amp and +amp

## Syntax

ar rand xamp [, iseed] [, isel] [, ibase]

kr rand xamp [, iseed] [, isel] [, ibase]

## Initialization

iseed (optional, default=0.5) -- a seed value for the recursive pseudo-random formula. A value between 0 and 1 will produce an initial output of kamp * iseed. A value greater than 1 will be seeded from the system clock. A negative value will cause seed re-initialization to be skipped. The default seed value is .5.

isel (optional, default=0) -- if zero, a 16-bit number is generated. If non-zero, a 31-bit random number is generated. Default is 0.

ioffset (optional, default=0) -- a base value added to the random result. New in Csound version 4.03.

## Performance

kamp, xamp -- range over which random numbers are distributed.

kcps, xcps -- the frequency which new random numbers are generated.

The internal pseudo-random formula produces values which are uniformly distributed over the range kamp to -kamp. rand will thus generate uniform white noise with an R.M.S value of kamp / root 2.

The remaining units produce band-limited noise: the kcps and xcps parameters permit the user to specify that new random numbers are to be generated at a rate less than the sampling or control frequencies.

## Examples

Here is an example of the rand opcode. It uses the files rand.orc and rand.sco.

Example 1. Example of the rand opcode.

    /* rand.orc */
    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Choose a random frequency between 4,100 and 44,100.
      kfreq rand 20000
      kcps = kfreq + 24100

      a1 oscil 30000, kcps, 1
      out a1
    endin
    /* rand.orc */

    /* rand.sco */
    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    e
    /* rand.sco */

## See Also

randh, randi

## Credits

Example written by Kevin Conder.

Thanks to a note from John ffitch, I changed the names of the parameters.

Previous | Home | Next
pvsynth | Up | randh