##############################################################################
# temple.des: Entries for the Ecumenical Temple, and Temples themselves
##############################################################################


##############################################################################
# Temple entries
##############################################################################

NAME:   temple_hall
TAGS:   temple_entry
ORIENT: float
SUBST:  ? : c:20 x v b G:5
MAP
ccccccccc
c...O...c
c.......c
c.?...?.c
c.......c
c.......c
c.?...?.c
c.......c
c.......c
c.?...?.c
c.......c
c.......c
c.?...?.c
c.......c
c@..@..@c
ENDMAP

NAME:   temple_hall_moat
TAGS:   temple_entry no_pool_fixup no_monster_gen
WEIGHT: 1
ORIENT: float
SUBST:  ? : v b G:5
MAP
   ccc
   cOc
cccc+cccc
cwwG.Gwwc
cwww.wwwc
cw?w.w?wc
cwww.wwwc
cwww.wwwc
cw?w.w?wc
cwww.wwwc
cwww.wwwc
cw?w.w?wc
cwww.wwwc
cwww.wwwc
cw?w.w?wc
cwww.wwwc
c@..@..@c
ENDMAP

# stairs with fountains
NAME:   temple_fountains
TAGS:   temple_entry
ORIENT: float
SUBST:  ? : T:30 U
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
...?...
.......
.?.O.?.
.......
...?...
ENDMAP

# stairs with statues
NAME:   temple_statues
TAGS:   temple_entry
ORIENT: float
MAP
GOG
ENDMAP

NAME:   temple_green
TAGS:   temple_entry
ORIENT: float
SUBST:  ? = =+b
MAP
bbbb+bbbb
b.......b
b.......b
?...O...?
b.......b
b.......b
bbbb?bbbb
ENDMAP

# Hidden entry A: weight 1 (out of 10)
NAME:   temple_secret_doors_a
WEIGHT: 1
TAGS:   temple_entry
ORIENT: float
SUBST:  c:cxxx
SUBST:  ? : ?:40 T:30 U, ? = T:30 U
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
cccccccccc
ccccmmmmmc
ccccm?.?mc
@...=.O.mc
ccccm?.?mc
ccccmmmmmc
cccccccccc
ENDMAP

# Hidden entry B: weight 1 (out of 10)
NAME:   temple_secret_doors_b
WEIGHT: 1
TAGS:   temple_entry
ORIENT: float
SUBST:  ? : ?:40 T:30 U, ? = T:30 U
SUBST:  c:cxxx
NSUBST: X = 1:= / *=m=
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
ccccccccccc
cccmmmmmccc
cccm?.?mccc
@..X.O.X..@
cccm?.?mccc
cccmmmmmccc
ccccccccccc
ENDMAP

# Hidden entry C: weight 1 (out of 10)
NAME:   temple_secret_doors_c
WEIGHT: 1
TAGS:   temple_entry
ORIENT: float
SUBST:  ? : ?:40 T:30 U, ? = T:30 U
SUBST:  c:cxxx
NSUBST: X = 1:= / *=m=
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
ccccccccc
cccmmmmmc
cccm?.?mc
@..X.O.mc
cccm?.?mc
cccmmXmmc
ccccc.ccc
ccccc.ccc
ccccc@ccc
ENDMAP

# Hidden entry D: weight 1 (out of 10)
NAME:   temple_secret_doors_d
WEIGHT: 1
TAGS:   temple_entry
ORIENT: float
SUBST:  ? : ?:40 T:30 U, ? = T:30 U
SUBST:  c:cxxx
NSUBST: X = 1:= / *=m=
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
ccccccccccc
cccmmmmmccc
cccm?.?mccc
@..X.O.X..@
cccm?.?mccc
cccmmXmmccc
ccccc.ccccc
ccccc.ccccc
ccccc@ccccc
ENDMAP

# Hidden entry E: weight 6 (out of 10)
NAME:   temple_secret_doors_e
WEIGHT: 6
TAGS:   temple_entry no_rotate
ORIENT: float
SUBST:  ? : ?:40 T:30 U, ? = T:30 U
SUBST:  c:cxxx
NSUBST: X = 1:= / *=m=
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
cccccc@cccccc
cccccc.cccccc
cccccc.cccccc
ccccmmXmmcccc
ccccm?.?mcccc
@...X.O.X...@
ccccm?.?mcccc
ccccmmXmmcccc
cccccc.cccccc
cccccc.cccccc
cccccc@cccccc
ENDMAP

# Temple in pool A: weight 3 (out of 10)
NAME:    temple_pool_a
TAGS:    temple_entry no_monster_gen no_pool_fixup no_rotate
WEIGHT:  3
ORIENT:  float
SHUFFLE: XY
SUBST:   Y=w, X=.
MAP
.....wwwww......
...wwwwwwwww....
.wwwwwwwwwwwww..
wwwwww...wwwwww.
wwwwww.O.YYYYYY.
wwwwww...wwwwww.
wwwwwwwXwwwwwww.
.wwwwwwXwwwwww..
...wwwwXwwww....
.....wwXww......
................
ENDMAP

# Temple in pool B: weight 7 (out of 10)
NAME:    temple_pool_b
TAGS:    temple_entry no_monster_gen no_rotate
WEIGHT:  7
ORIENT:  float
SHUFFLE: ABCDEFGHIJKL
SUBST:   A=W, B=W, C=W, D=w, E=w, F=w, G=w, H=w, I=w, J=w, K=w, L=w
MAP
.....wwwww......
...wABwwwDEw....
.wwwCwwwwwFwww..
wwwwww...wwwwww.
wwwwww.O.wwwwww.
wwwwww...wwwwww.
wwwwLwwwwwGwwww.
.wwwKJwwwIHwww..
...wwwwwwwww....
.....wwwww......
................
ENDMAP

# The garden of good and evil
NAME:   temple_garden
TAGS:   temple_entry no_monster_gen
ORIENT: float
SUBST:  _=3., -=l.
SUBST:  . = .:900 3:30
SUBST:  ' = .:400 3:30
SUBST:  ! = .:100 3:30
SUBST:  ? = .:50  3:30 G:5 T:10 U:1 V:4
MONS:   angel, iron devil, plant
MAP
            ............................xxxxxxxx
        .............'''''...............-llxxxx
      ............'''''''''''...........-llllxxx
    ...........'''''''!!!'''''''........-lll2xxx
   .........''''''''!!!!!!!''''''''......-llllxx
   ........'''''''!!!!!!!!!!!'''''''.......-lllx
  ........'''''!!!!!!!!!!!!!!!!!'''''........llx
 ........'''''!!!!!!!!!?!!!!!!!!!'''''........lx
 .......'''''!!!!!!!!!???!!!!!!!!!'''''........x
.......'''''!!!!!!!!!?????!!!!!!!!!'''''........
.......''''!!!!!!!!!???????!!!!!!!!!''''........
.......'''!!!!!!!!!????O????!!!!!!!!!'''........
.......''''!!!!!!!!!???????!!!!!!!!!''''........
.......'''''!!!!!!!!!?????!!!!!!!!!'''''.......
x.......'''''!!!!!!!!!???!!!!!!!!!'''''........
x........'''''!!!!!!!!!?!!!!!!!!!'''''.........
xx._......'''''!!!!!!!!!!!!!!!!!'''''.........
xxxxm......'''''''!!!!!!!!!!!'''''''..........
xxxxxm......''''''''!!!!!!!''''''''..........
xxxx1m_........'''''''!!!'''''''.............
xxxxxxm_..........'''''''''''...............
xxxxxxxxxx...........'''''................
xxxxxxxxxxxx...........................
ENDMAP

# Firewalk A: weight 3 (out of 10)
# To reach the Temple, you just have to walk straight. Note that the
# frequency of the flames is low enough that you have to spend a fair
# amount of time off the path to get hit by one. And at this depth
# they should not be fatal to anyone. -LP
NAME:    lemuel_temple_firewalk
TAGS:    temple_entry uniq_firewalk no_item_gen no_monster_gen
ORIENT:  float
WEIGHT:  3
ITEM:    nothing, nothing, nothing
SHUFFLE: def
MARKER:  d = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 3, delay = 20, start_clouds = 1, \
             size = 1, walk_dist = 1, spread_rate= 0 }
MARKER:  e = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 4, delay = 39, start_clouds = 1, \
             size = 1, walk_dist = 1, spread_rate= 0 }
MARKER:  f = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 5, delay = 47, start_clouds = 1, \
             size = 1, walk_dist = 1, spread_rate= 0 }
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
xxxxxxxG@Gxxxxxxx
x...............x
x...............x
x.d..e.....f..d.x
x...............x
x...............x
x...............x
x.e..f.....d..e.x
x...............x
x...............x
x...............x
x.f..d.....e..f.x
x...............x
x...............x
x...............x
x.d..e.....f..d.x
x...............x
x.......O.......x
xxxxxxxxxxxxxxxxx
ENDMAP

# Firewalk B: weight 7 (out of 10)
# New version, with the safe path marked. Personally I don't think
# it's necessary, but it does make it harder to kill yourself. -LP
NAME:    lemuel_temple_firewalk_marked
TAGS:    temple_entry uniq_firewalk no_item_gen no_monster_gen
WEIGHT:  7
ORIENT:  float
ITEM:    nothing, nothing, nothing, nothing
SHUFFLE: def
MARKER:  d = lua:fog_machine { cloud_type = "flame", \
              pow_min = 2, pow_max = 3, delay = 39, start_clouds = 1, \
              size = 1, walk_dist = 2, spread_rate= 0 }
MARKER:  e = lua:fog_machine { cloud_type = "flame", \
              pow_min = 2, pow_max = 5, delay = 59, start_clouds = 1, \
              size = 1, walk_dist = 2, spread_rate= 0 }
MARKER:  f = lua:fog_machine { cloud_type = "flame", \
              pow_min = 2, pow_max = 7, delay = 79, start_clouds = 1, \
              size = 1, walk_dist = 2, spread_rate= 0 }
COLOUR:  g = yellow
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
xxxxxxxG@Gxxxxxxx
x...f..ggg....e.x
x......ggg......x
x.d....ggg..f...x
x......ggg......x
x...e..ggg....d.x
x......ggg......x
x.e....ggg..d...x
x......ggg......x
x...f..ggg....e.x
x......ggg......x
x.f....ggg..e...x
x......ggg......x
x...d..ggg....f.x
x......ggg......x
x.d....ggg..f...x
x......ggg......x
x...e..gOg....d.x
xxxxxxxxxxxxxxxxx
ENDMAP

NAME:   minmay_temple_entry_fiery
TAGS:   temple_entry no_monster_gen
ORIENT: float
SUBST:  ' : .'l
SUBST:  ' = .l
SUBST:  l : l w:1
MAP
xxx.@..xx
xxl'...xx
xxll..xxx
xlll'.xxx
xll'.'lxx
xxl.'llxx
xxx'.lxxx
xxxx.xxxx
xccc+cccx
xcG...Gcx
xc.....cx
xc..O..cx
xc.....cx
xcG...Gcx
xcccccccx
xxxxxxxxx
ENDMAP

NAME:   minmay_temple_entry_poolview
TAGS:   temple_entry no_pool_fixup
ORIENT: float
SUBST:  ? : lw
SUBST:  c : cx
MAP
ccccccccccccc
c???????????c
c???????????c
c???????????c
c???nnnnn???c
c???n...nnnnc
c???n.O.....@
c???n...nnnnc
c???nnnnn???c
c???????????c
c???????????c
c???????????c
ccccccccccccc
ENDMAP

NAME:   minmay_temple_entry_overgrown
TAGS:   temple_entry
ORIENT: float
MONS:   plant, bush
SUBST:  ?=.1, !=...1, 1:123, 2=2.., 3=12
MAP
!!!!!
!???!
!?O?!
!???!
!!!!!
ENDMAP

NAME:   minmay_temple_entry_junction
TAGS:   temple_entry
ORIENT: float
SUBST:  T = TV U:1
SUBST:  X : xc v:1 b:1
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
xxx...xxx
xxX.T.Xxx
xXX...XXx
.........
.T..O..T.
.........
xXX...XXx
xxX.T.Xxx
xxx...xxx
ENDMAP

NAME:   minmay_temple_entry_glass
TAGS:   temple_entry
ORIENT: float
SUBST:  m : mb
MAP
...........
.m.m.m.m.m.
...........
.m.......m.
...........
.m...O...m.
...........
.m.......m.
...........
.m.m.m.m.m.
...........
ENDMAP

NAME:   minmay_temple_entry_trees
TAGS:   temple_entry
ORIENT: float
SUBST:  t : t1
MONS:   bush
MAP
.....
.t.t.
..O..
.t.t.
.....
ENDMAP

NAME:   minmay_temple_entry_spiral
TAGS:   temple_entry
ORIENT: float
MAP
cncncncnc@c
n.......n.n
c.cncnc.c.c
n.n...n.n.n
c.c.c.c.c.c
n.n.nOn.n.n
c.c.cnc.c.c
n.n.....n.n
c.cncncnc.c
n.........n
cncncncncnc
ENDMAP

NAME:   minmay_temple_entry_butterflies
TAGS:   temple_entry
ORIENT: float
MONS:   butterfly
SUBST:  . = .1
MAP
...
.O.
...
ENDMAP

NAME:   minmay_temple_entry_metal_lava
TAGS:   temple_entry
WEIGHT: 1
ORIENT: float
KMASK:  l = no_monster_gen
MAP
vvvvvvv
vlvlvlv
@..O..@
vlvlvlv
vvvvvvv
ENDMAP

NAME:   minmay_temple_entry_nine_rooms
TAGS:   temple_entry
ORIENT: float
NSUBST: A = 1:O / *=T:40 VU
NSUBST: B = 1:. / *:c
NSUBST: C = 1:. / *:c
NSUBST: D = 1:. / *:c
NSUBST: E = 1:. / *:c
NSUBST: F = 1:. / *:c
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
ccBcccBcccBcc
c...c...c...c
B.A.D.A.E.A.B
c...c...c...c
ccDccc.cccEcc
c...c...c...c
B.A...A...A.B
c...c...c...c
ccCccc.cccFcc
c...c...c...c
B.A.C.A.F.A.B
c...c...c...c
ccBcccBcccBcc
ENDMAP

NAME:   minmay_temple_entry_steam
TAGS:   temple_entry
ORIENT: float
# This steam is essentially harmless; hopefully players will figure that out.
MARKER: l = lua:fog_machine { cloud_type = "steam", pow_min = 1, \
        pow_max = 3, delay = 10, start_clouds = 1, size_min = 1, \
        size_max = 3, spread_rate = -1 }
KMASK:  W = no_monster_gen
KMASK:  l = no_monster_gen
MAP
..WWW..
.WWlWW.
WWWWWWW
WlWOWlW
WWWWWWW
.WWlWW.
..WWW..
ENDMAP

NAME:   minmay_temple_entry_grid
TAGS:   temple_entry
ORIENT: float
SUBST:  m : bm
MAP
.........
...m.m...
..m.m.m..
.m.m.m.m.
..m.O.m..
.m.m.m.m.
..m.m.m..
...m.m...
.........
ENDMAP

NAME:   minmay_temple_entry_hall
TAGS:   temple_entry
ORIENT: float
SUBST:  c : c:80 xv
SUBST:  T = T:80 UV
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
ccc+ccc
c.....c
c.T.T.c
+..O..+
c.T.T.c
c.....c
ccc+ccc
ENDMAP

NAME:   minmay_temple_entry_purple_smoke
TAGS:   temple_entry
ORIENT: float
MARKER: O = lua:fog_machine { cloud_type = "purple smoke", pow_min = 1, \
        pow_max = 3, delay_min = 1, delay_max = 10, start_clouds = 5,  \
        size_min = 1, size_max = 2, spread_rate = 1 }
MAP
.....
.....
..O..
.....
.....
ENDMAP

NAME:   minmay_temple_entry_statues_fountains
TAGS:   temple_entry
ORIENT: float
SUBST:  T = T:80 UV
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
.......
.G.G.G.
..T.T..
.G.O.G.
..T.T..
.G.G.G.
.......
ENDMAP

NAME:   minmay_temple_entry_large_hall
TAGS:   temple_entry
ORIENT: float
SUBST:  x : xxxc
SUBST:  T = T:80 UV
KMASK:  T = no_monster_gen
KMASK:  U = no_monster_gen
MAP
xx@xx@xx@xx
x.........x
@.........@
x..T...T..x
x.........x
@....O....@
x.........x
x..T...T..x
@.........@
x.........x
xx@xx@xx@xx
ENDMAP

NAME:   minmay_temple_entry_secret_door
TAGS:   temple_entry
ORIENT: float
NSUBST: m = 1:= / *:m
MAP
xxx+xxx
x.....x
x.mmm.x
+.mOm.+
x.mmm.x
x.....x
xxx+xxx
ENDMAP

NAME:   minmay_temple_entry_steel_oval
TAGS:   temple_entry
WEIGHT: 1
ORIENT: float
MAP
 ....vvv....
...vv...vv...
..v..vvv..v..
.v..v...v..v.
.v.v.vvv.v.v.
v.v.v...v.v.v
v.v.v.O.v.v.v
v.v.v...v.v.v
.v.v.vvv.v.v.
.v..v...v..v.
..v..vvv..v..
...vv...vv...
 ....vvv....
ENDMAP

NAME:   minmay_temple_entry_levitate
TAGS:   temple_entry
DEPTH:  D:6-7
WEIGHT: 1
ORIENT: float
SUBST:  < : <>
KMASK:  l = no_monster_gen
MAP
clclclclc
l.......l
c.clclc.c
l.l...l.l
c.c<O<c.c
l.l...l.l
c.clclc.c
l.......l
clclclclc
ENDMAP

NAME:   minmay_temple_entry_oklob
TAGS:   temple_entry
DEPTH:  D:7
WEIGHT: 1
ORIENT: float
MONS:   plant, oklob plant
MAP
....1..
1.111.1
.11.11.
.1.O211
11.1111
.111.1.
1..11..
ENDMAP

##############################################################################
# Temple maps
##############################################################################

# Maps for the main temple (Ecumenical Temple branch) come here, use
# PLACE:  Temple
# ORIENT: encompass
# Altars are to be placed as B glyphs, modification a la SUBST or SHUFFLE are
# allowed. You could place any number of altars between one and the number of
# guaranteed gods. However, don't make temple maps with less than six altars.
#
# Guaranteed gods not present in a temple will get altars in the dungeon.
# See altar.des.

##########################################################################
# Circular temple (David Ploog). 1 x 12 = 12 gods.

NAME:   circular_temple
PLACE:  Temple
WEIGHT: 50
TAGS:   no_rotate
ORIENT: encompass
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxcccccccccccccxxxxxxxxxxxxxxxx
xxxxxxxxxxxxccccc.....<.....cccccxxxxxxxxxxxx
xxxxxxxxxcccc...................ccccxxxxxxxxx
xxxxxxxccc.........................cccxxxxxxx
xxxxxccc..............B..............cccxxxxx
xxxxcc.........B.............B.........ccxxxx
xxxcc...................................ccxxx
xxcc.....................................ccxx
xxc........B.....................B........cxx
xcc.................T...T.................ccx
xc.........................................cx
xc.........................................cx
xc(......B.......T.........T.......B......{cx
xc.........................................cx
xc.........................................cx
xcc.................T...T.................ccx
xxc........B.....................B........cxx
xxcc.....................................ccxx
xxxcc...................................ccxxx
xxxxcc.........B.............B.........ccxxxx
xxxxxccc..............B..............cccxxxxx
xxxxxxxccc.........................cccxxxxxxx
xxxxxxxxxcccc...................ccccxxxxxxxxx
xxxxxxxxxxxxccccc.....[.....cccccxxxxxxxxxxxx
xxxxxxxxxxxxxxxxcccccccccccccxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP


##############################################################################
# Three leaves temple (David Ploog). 3 x 4 = 12 gods.

NAME:   three_leaves__temple
PLACE:  Temple
TAGS:   no_rotate
ORIENT: encompass
WEIGHT: 3
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxbbbxxxxxxxxxxxxxxxbbbxxxxxxx
xxxxxxbbb.bbxxxxxxxxxxxxxbb.bbbxxxxx
xxxxxbb....bbxxxxxxxxxxxbb....bbxxxx
xxxxbb......bbbxxxxxxxbbb......bbxxx
xxxbb.....B...bbxxxxxbb...B.....bbxx
xxbb..B........bbbxbbb........B..bbx
xxbb.............bbb.............bbx
xbb....B....B.....b.....B....B....bb
xbb............{.....[............bb
xxbbbbbbbb........b........bbbbbbbbx
xxxxxxxxxbbbbbbbb...bbbbbbbbxxxxxxxx
xxxxxxxxxxxxxxxbb.(.bbxxxxxxxxxxxxxx
xxxxxxxxxxxxxxbb.....bbxxxxxxxxxxxxx
xxxxxxxxxxxxxbb.......bbxxxxxxxxxxxx
xxxxxxxxxxxxbb....B....bbxxxxxxxxxxx
xxxxxxxxxxxbb...........bbxxxxxxxxxx
xxxxxxxxxxbb....B...B....bbxxxxxxxxx
xxxxxxxxxbb.......B.......bbxxxxxxxx
xxxxxxxxxxbbb...........bbbxxxxxxxxx
xxxxxxxxxxxxbbbb.....bbbbxxxxxxxxxxx
xxxxxxxxxxxxxxxbbbbbbbxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##############################################################################
# Twelve chambers temple (David Ploog). 12 x 1 = 12 gods.

NAME:   twelve_chambers_temple
PLACE:  Temple
TAGS:   no_rotate
ORIENT: encompass
WEIGHT: 5
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvxx
xvvvvvvvvvvv..................................vvvvvvvvvxx
xvvvvvvv.....vvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvv.....vvvvvxx
xvvvvv...vvvvv.....vvv.....vvv.....vvv.....vvvvvv...vvvxx
xvvvvv.vvvvvv...B...v...B...v...B...v...B...vvvvvvv.vvvxx
xvv.....vvvvv.......v.......v.......v.......vvvvv.....vvx
xv.......vvvvv.....vvv.....vvv.....vvv.....vvvvv.......vx
xv..B....vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv....B..vx
xv........vvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvv........vx
xvv.....v..vvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvv..v.....vvx
xvvvv.vvvv.....................................vvvv.vvvvx
xvvv..vvvv.....................................vvvv..vvvx
xvvv.vvvvv......T.......(...{...[.......T......vvvvv.vvvx
xvvv..vvvv.....................................vvvv..vvvx
xvvvv.vvvv.....................................vvvv.vvvvx
xvv.....v..vvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvv..v.....vvx
xv........vvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvv........vx
xv..B....vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv....B..vx
xv.......vvvvv.....vvv.....vvv.....vvv.....vvvvv.......vx
xvv.....vvvvv.......v.......v.......v.......vvvvv.....vvx
xvvvvv.vvvvvv...B...v...B...v...B...v...B...vvvvvv.vvvvxx
xvvvvv...vvvvv.....vvv.....vvv.....vvv.....vvvvv...vvvvxx
xvvvvvvv.....vvv.vvvvvvv.vvvvvvv.vvvvvvv.vvv.....vvvvvvxx
xvvvvvvvvvvv.................................vvvvvvvvvvxx
xvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##############################################################################
# Fourteen chambers temple (David Ploog). 14 x 1 = 14 gods.

NAME:   fourteen_chambers_temple
PLACE:  Temple
TAGS:   no_rotate
ORIENT: encompass
WEIGHT: 5
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvxx
xvvvvvvvvvvv..........................................vvvvvvvvvxx
xvvvvvvv.....vvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvv.....vvvvvxx
xvvvvv...vvvvv.....vvv.....vvv.....vvv.....vvv.....vvvvvv...vvvxx
xvvvvv.vvvvvv...B...v...B...v...B...v...B...v...B...vvvvvvv.vvvxx
xvv.....vvvvv.......v.......v.......v.......v.......vvvvv.....vvx
xv.......vvvvv.....vvv.....vvv.....vvv.....vvv.....vvvvv.......vx
xv..B....vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv....B..vx
xv........vvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvv........vx
xvv.....v..vvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvv..v.....vvx
xvvvv.vvvv.............................................vvvv.vvvvx
xvvv..vvvv.............................................vvvv..vvvx
xvvv.vvvvv........T.........(...{...[.........T........vvvvv.vvvx
xvvv..vvvv.............................................vvvv..vvvx
xvvvv.vvvv.............................................vvvv.vvvvx
xvv.....v..vvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvv..v.....vvx
xv........vvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvv........vx
xv..B....vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv....B..vx
xv.......vvvvv.....vvv.....vvv.....vvv.....vvv.....vvvvv.......vx
xvv.....vvvvv.......v.......v.......v.......v.......vvvvv.....vvx
xvvvvv.vvvvvv...B...v...B...v...B...v...B...v...B...vvvvvv.vvvvxx
xvvvvv...vvvvv.....vvv.....vvv.....vvv.....vvv.....vvvvv...vvvvxx
xvvvvvvv.....vvv.vvvvvvv.vvvvvvv.vvvvvvv.vvvvvvv.vvv.....vvvvvvxx
xvvvvvvvvvvv.........................................vvvvvvvvvvxx
xvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##########################################################################
# Another temple (David Ploog). 12 + 3 = 1 + 2 + 3 + 4 + 5 => 12 gods.

NAME:   triangle_temple
PLACE:  Temple
WEIGHT: 20
TAGS:   no_rotate
ORIENT: encompass
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllll...lllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllll.......lllllllllllllllllllllllllllx
xllllllllllllllllllllllllll.........llllllllllllllllllllllllllx
xlllllllllllllllllllllllll...........lllllllllllllllllllllllllx
xllllllllllllllllllllllll......{......llllllllllllllllllllllllx
xlllllllllllllllllllllll...............lllllllllllllllllllllllx
xllllllllllllllllllllll.................llllllllllllllllllllllx
xlllllllllllllllllllll......B.....B......lllllllllllllllllllllx
xllllllllllllllllllll.....................llllllllllllllllllllx
xlllllllllllllllllll.......................lllllllllllllllllllx
xllllllllllllllllll...B.................B...llllllllllllllllllx
xlllllllllllllllll.............B.............lllllllllllllllllx
xllllllllllllllll.............................llllllllllllllllx
xlllllllllllllll...............................lllllllllllllllx
xllllllllllllll.................................llllllllllllllx
xlllllllllllll.....B.......B.......B.......B.....lllllllllllllx
xllllllllllll.....................................llllllllllllx
xlllllllllll.......................................lllllllllllx
xllllllllll.........................................llllllllllx
xlllllllll....(.........B.............B.........[....lllllllllx
xllllllll......................B.....................lllllllllx
xllllllll............................................lllllllllx
xlllllllll..........................................llllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xlllllllllllllllllllllllllllllllllllllllllllllllllllllllllllllx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##########################################################################
# Watery temple (Darshan Shaligram). 12 gods.
NAME:   water_temple
TAGS:   no_pool_fixup no_rotate
WEIGHT: 20
PLACE:  Temple
ORIENT: encompass
MAP
xcccccccccccccccccccccccccccccccccccccccccccccccccccx
xcwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwcx
xcwwwwwwwwwwww.........................wwwwwwwwwwwwcx
xcwwwwwwww.................................wwwwwwwwcx
xcwwwww...................B...................wwwwwcx
xcwww......B.............................B......wwwcx
xcwww.............B...............B.............wwwcx
xcww......................(......................wwcx
xcww.............................................wwcx
xcww...B......B...........T...........B......B...wwcx
xcww.............................................wwcx
xcww...................[.....{...................wwcx
xcwww.............B...............B.............wwwcx
xcwww......B.............................B......wwwcx
xcwwwww...................B...................wwwwwcx
xcwwwwwwww.................................wwwwwwwwcx
xcwwwwwwwwwwww.........................wwwwwwwwwwwwcx
xcwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwcx
xcccccccccccccccccccccccccccccccccccccccccccccccccccx
ENDMAP

##########################################################################
# Zaba's temple. 12 gods.
NAME:    zaba_temple_1
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
COLOUR:  c = magenta
SHUFFLE: {[
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxcccccccccccccccccccccccccccccccccccccccccccxx
xxcccc.......ccccccc.......ccccccc.......ccccxx
xxcc...B...B...ccc...B...B...ccc...B...B...ccxx
xxc.............c.............c.............cxx
xxcc...........ccc...........ccc...........ccxx
xxcccc...(.............[.............{....cccxx
xxcc...........ccc...........ccc...........ccxx
xxc.............c.............c.............cxx
xxcc...B...B...ccc...B...B...ccc...B...B...ccxx
xxcccc.......ccccccc.......ccccccc.......ccccxx
xxcccccccccccccccccccccccccccccccccccccccccccxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##########################################################################
# Loop temple (David Ploog). 16 = 12 + 4. 12 gods.
NAME:    loop_temple
PLACE:   Temple
TAGS:    no_rotate no_pool_fixup
ORIENT:  encompass
SHUFFLE: AC
SUBST:   A = B
NSUBST:  C = 1:( / 1:{ / 1:[ / 1:<
#
: local arnd = crawl.random2(6)
: if arnd == 0 then
SUBST:   W : mvbG
: elseif arnd < 3 then
SUBST:   W = w
NSUBST:  w = 6:1 / *:w
KFEAT:   1 = w
KMONS:   1 = giant goldfish / electric eel / big fish
: else
SUBST:   W = w
:end
KPROP: wW1 = no_submerge
#
: local brnd = crawl.random2(10)
: if brnd == 0 then
SUBST:  w = l
COLOUR: m = lightred
COLOUR: c = lightred
: elseif brnd < 4 then
SUBST:  m = c
: else
COLOUR: m = blue
COLOUR: c = blue
:end
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxcccccccccccccxxxxxxxxxxxxxxxx
xxxxxxxxxxxxccccc...........cccccxxxxxxxxxxxx
xxxxxxxxxcccc...................ccccxxxxxxxxx
xxxxxxxccc............A............cccxxxxxxx
xxxxxccc.......B.............B.......cccxxxxx
xxxxcc.................................ccxxxx
xxxcc.....C........mmmmmmm........C.....ccxxx
xxcc............mmmmwwwwwmmmm............ccxx
xxc...........mmmwwwwwwwwwwwmmm...........cxx
xcc....B.....mmwwwwwwwWwwwwwwwmm.....B....ccx
xc..........mmwwwwwwwwwwwwwwwwwmm..........cx
xc..........mwwwwwwwwwwwwwwwwwwwm..........cx
xc....A.....mwwwwWwwwwwwwwwWwwwwm.....A....cx
xc..........mwwwwwwwwwwwwwwwwwwwm..........cx
xc..........mmwwwwwwwwwwwwwwwwwmm..........cx
xcc....B.....mmwwwwwwwWwwwwwwwmm.....B....ccx
xxc...........mmmmwwwwwwwwwwmmm...........cxx
xxcc.............mmmwwwwwmmmm............ccxx
xxxcc.....C........mmmmmmm........C.....ccxxx
xxxxcc.................................ccxxxx
xxxxxccc.......B.............B.......cccxxxxx
xxxxxxxccc............A............cccxxxxxxx
xxxxxxxxxcccc...................ccccxxxxxxxxx
xxxxxxxxxxxxccccc...........cccccxxxxxxxxxxxx
xxxxxxxxxxxxxxxxcccccccccccccxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP


##########################################################################
# Five rooms temple (David Ploog). 12 + 3 = 5 x 3 => 12 gods.
#
# Todo: would be nice to have the altars in each room follow a theme.
#       That's harder with the random temples but perhaps there is a way.
#
NAME:    five_temple
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
KFEAT:   X : G / U / T
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxx.......xxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxx........x........xxxxxxxxxxxxxxx
xxxxxxxxxx........xxxxx+xxxxx........xxxxxxxxxx
xxxxxxx.....xxxxxxxxx.....xxxxxxxxx.....xxxxxxx
xxxxxx...xxxxxxxxxx.........xxxxxxxxxx...xxxxxx
xxxxx..xxxxxxxxxxx..(.....[..xxxxxxxxxxx..xxxxx
xxxx..xxxxxxxxxxxx.....X.....xxxxxxxxxxxx..xxxx
xxx..xxxxxxxxxxxxx...........xxxxxxxxxxxxx..xxx
xxx..xxx.....xxxxxx....{....xxxxxx.....xxx..xxx
xx..+x..B......xxxxxx.....xxxxxx......B..x+..xx
xx..x...........xxxxxxxxxxxxxxx...........x..xx
x..xx.....X..B..xxxxxxxxxxxxxxx..B..X.....xx..x
x..xx...........xxxxxxxxxxxxxxx...........xx..x
x..xxx..B......xxxxxxxxxxxxxxxxx......B..xxx..x
x..xxxxx.....xxxxxxxxxxxxxxxxxxxxx.....xxxxx..x
x..xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx..x
x..xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx..x
x..xxxxxxxxxx.....xxxxxxxxxxx.....xxxxxxxxxx..x
xx..xxxxxxx......B..xxxxxxx..B......xxxxxxx..xx
xx..xxxxxx.B.........xxxxx.........B.xxxxxx..xx
xxx..xxxxx.....X.....xxxxx.....X.....xxxxx..xxx
xxx..xxxxx...........xxxxx...........xxxxx..xxx
xxxx..xxxxx......B..xxxxxxx..B......xxxxx..xxxx
xxxxx..xxxxxx.....xxxxxxxxxxx.....xxxxxx..xxxxx
xxxxxx...xxx+xxxxxxxxxxxxxxxxxxxxx+xxx...xxxxxx
xxxxxxxx....xxxxxxxxxxxxxxxxxxxxxxx....xxxxxxxx
xxxxxxxxxx........xxxxxxxxxxx........xxxxxxxxxx
xxxxxxxxxxxxxxx........x........xxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxx.......xxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

##########################################################################
# Eino's temples. 12 gods.
NAME:    temple_eino_lava_a
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  5
SHUFFLE: {([
COLOUR:  c = red
MAP
ccccccccccccccccccccccccc
cccccccclccccccclcccccccc
cccccccl.lcclccl.lccccccc
cccclll...c...c...lllcccc
ccclll..B.G...G.B..lllccc
cccll.......B.......llccc
cccl.................lccc
ccl...................lcc
cl..B...............B..lc
ccl...................lcc
ccccG...............Gcccc
ccc..........[........ccc
ccl..B.....(.......B..lcc
ccc..........{........ccc
ccccG...............Gcccc
ccl...................lcc
cl..B...............B..lc
ccl...................lcc
cccl.................lccc
cccll.......B.......llccc
ccclll..B.G...G.B..lllccc
cccclll...c...c...lllcccc
cccccccl.lcclccl.lccccccc
cccccccclccccccclcccccccc
ccccccccccccccccccccccccc
ENDMAP

# 8 gods.
NAME:    temple_eino_lava_b
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  5
SHUFFLE: {([
COLOUR:  c = red
MAP
ccccccccccccccccccccccccc
cccccccclccccccclcccccccc
cccccccl.lcclccl.lccccccc
cccclll...c...c...lllcccc
ccclll..B.G...G.B..lllccc
cccll.......B.......llccc
cccl.................lccc
ccccG...............Gcccc
ccc...................ccc
ccl..B....{.(.[....B..lcc
ccc...................ccc
ccccG...............Gcccc
cccl.................lccc
cccll.......B.......llccc
ccclll..B.G...G.B..lllccc
cccclll...c...c...lllcccc
cccccccl.lcclccl.lccccccc
cccccccclccccccclcccccccc
ccccccccccccccccccccccccc
ENDMAP

# 12 gods.
NAME:    temple_eino_water
PLACE:   Temple
TAGS:    no_pool_fixup no_rotate
ORIENT:  encompass
SHUFFLE: {([
MAP
ccccccccccccccccccccccccccccccccc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwww...wwwwwwwwwwwwwwc
cwwwwwwwwwwwww..B..wwwwwwwwwwwwwc
cwwwwwwwwwww.........wwwwwwwwwwwc
cwwwwwwwwww..B.....B..wwwwwwwwwwc
cwwwwwwwwwww.........wwwwwwwwwwwc
cwwwwwwwwwww...www...wwwwwwwwwwwc
cwwwwwwwwww...wwwww...wwwwwwwwwwc
cwwwwwwwww...ww...ww...wwwwwwwwwc
cwwwwwwwww......B......wwwwwwwwwc
cwwwwwwww..B.........B..wwwwwwwwc
cwwwwwwwww...www.......wwwwwwwwwc
cwwwwwwwwwwwwwwww...wwwwwwwwwwwwc
cwwwwwwwwwwwwwwwww...wwwwwwwwwwwc
cwwwwwwwwwwwwwwwwww...wwwwwwwwwwc
cwwwwwwwwwwwwwwwwww...wwwwwwwwwwc
cwwwwwwwwwwwwwwwww...wwwwwwwwwwwc
cwwwwwwwwwwwwwwww...wwwwwwwwwwwwc
cwwwwwwwwww...........wwwwwwwwwwc
cwwwwwwwww..G.{.[.(.G..wwwwwwwwwc
cwwwwwwwwww...........wwwwwwwwwwc
cwwwwwwwwwwww...wwwwwwwwwwwwwwwwc
cwwwwwwwwwww...wwwwwwwwwwwwwwwwwc
cwwwwwwwwww...wwwwwwwwwwwwwwwwwwc
cwwwwwwwwww...wwwwwwwwwwwwwwwwwwc
cwwwwwwwwwww...wwwwwwwwwwwwwwwwwc
cwwwwwwwwwwww...wwwwwwwwwwwwwwwwc
cwwwwwwwww.......www...wwwwwwwwwc
cwwwwwwww..B.........B..wwwwwwwwc
cwwwwwwwww......B......wwwwwwwwwc
cwwwwwwwww...ww...ww...wwwwwwwwwc
cwwwwwwwwww...wwwww...wwwwwwwwwwc
cwwwwwwwwwww...www...wwwwwwwwwwwc
cwwwwwwwwwww.........wwwwwwwwwwwc
cwwwwwwwwww..B.....B..wwwwwwwwwwc
cwwwwwwwwwww.........wwwwwwwwwwwc
cwwwwwwwwwwwww..B..wwwwwwwwwwwwwc
cwwwwwwwwwwwwww...wwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
cwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwwc
ccccccccccccccccccccccccccccccccc
ENDMAP

# 12 gods.
NAME:    temple_eino_crystal_narrow_a
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
SHUFFLE: {([
WEIGHT:  3
MAP
bbbbbbbbbbbbbbbbbbbbbbbbbbbbb
bbbbbbbbbbbbb...bbbbbbbbbbbbb
bbbbbbb...b..bbb..b...bbbbbbb
bbbbbbb.B..bbbbbbb..B.bbbbbbb
bbbbbbb...bbbbbbbbb...bbbbbbb
bbbbbbbbbb.bbbbbbb.bbbbbbbbbb
bbbbbbbbbbb.bbbbb.bbbbbbbbbbb
bbbbbbbbbbbb.bbb.bbbbbbbbbbbb
bb...bbbbbbbb...bbbbbbbb...bb
bb.B.bbbbbbbb.B.bbbbbbbb.B.bb
bb...bbbbbbbb...bbbbbbbb...bb
bbb.b.bbbbbbbb.bbbbbbbb.b.bbb
bbb.bb.bbbbbbb.bbbbbbb.bb.bbb
bb.bbbb.bbbbb...bbbbb.bbbb.bb
bb.bbbbb.bbbb.[.bbbb.bbbbb.bb
b.bbbbbbb...b...b...bbbbbbb.b
b.bbbbbbb.B...{...B.bbbbbbb.b
b.bbbbbbb...b...b...bbbbbbb.b
bb.bbbbb.bbbb.(.bbbb.bbbbb.bb
bb.bbbb.bbbbb...bbbbb.bbbb.bb
bbb.bb.bbbbbbb.bbbbbbb.bb.bbb
bbb.b.bbbbbbbb.bbbbbbbb.b.bbb
bb...bbbbbbbb...bbbbbbbb...bb
bb.B.bbbbbbbb.B.bbbbbbbb.B.bb
bb...bbbbbbbb...bbbbbbbb...bb
bbbbbbbbbbbb.bbb.bbbbbbbbbbbb
bbbbbbbbbbb.bbbbb.bbbbbbbbbbb
bbbbbbbbbb.bbbbbbb.bbbbbbbbbb
bbbbbbb...bbbbbbbbb...bbbbbbb
bbbbbbb.B..bbbbbbb..B.bbbbbbb
bbbbbbb...b..bbb..b...bbbbbbb
bbbbbbbbbbbbb...bbbbbbbbbbbbb
bbbbbbbbbbbbbbbbbbbbbbbbbbbbb
ENDMAP

# 12 gods.
NAME:    temple_eino_crystal_narrow_b
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
SHUFFLE: {([
WEIGHT:  2
MAP
bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb
bbbbbbbbbbbbbbb...bbbbbbbbbbbbbbb
bbbbbbbbbbbbbbb.B.bbbbbbbbbbbbbbb
bbbbbbbbbbbbbbb...bbbbbbbbbbbbbbb
bbbbbbbbbbbbbb.b.b.bbbbbbbbbbbbbb
bbbbbbbbbbbbb.bb.bb.bbbbbbbbbbbbb
bbbbbbbbbbbb.bbb.bbb.bbbbbbbbbbbb
bbbbbbbbbbb.bbbb.bbbb.bbbbbbbbbbb
bbbbbbbb...bbbbb.bbbbb...bbbbbbbb
bbbbbbbb.B.bbbbb.bbbbb.B.bbbbbbbb
bbbbbbbb...bbbb...bbbb...bbbbbbbb
bbbbbbb.bbb.bbb.B.bbb.bbb.bbbbbbb
bbbbbb.bbbbb.bb...bb.bbbbb.bbbbbb
bbbbb.bbbbbbb.bb.bb.bbbbbbb.bbbbb
bbbb.bbbbbbbbb.b.b.bbbbbbbbb.bbbb
b...bbbbbb...bb.[.bb...bbbbbb...b
b.B........B.........B........B.b
b...bbbbbb...bb{.(bb...bbbbbb...b
bbbb.bbbbbbbbb.b.b.bbbbbbbbb.bbbb
bbbbb.bbbbbbb.bb.bb.bbbbbbb.bbbbb
bbbbbb.bbbbb.bb...bb.bbbbb.bbbbbb
bbbbbbb.bbb.bbb.B.bbb.bbb.bbbbbbb
bbbbbbbb...bbbb...bbbb...bbbbbbbb
bbbbbbbb.B.bbbbb.bbbbb.B.bbbbbbbb
bbbbbbbb...bbbbb.bbbbb...bbbbbbbb
bbbbbbbbbbb.bbbb.bbbb.bbbbbbbbbbb
bbbbbbbbbbbb.bbb.bbb.bbbbbbbbbbbb
bbbbbbbbbbbbb..b.bb.bbbbbbbbbbbbb
bbbbbbbbbbbbbb.b.b.bbbbbbbbbbbbbb
bbbbbbbbbbbbbbb...bbbbbbbbbbbbbbb
bbbbbbbbbbbbbbb.B.bbbbbbbbbbbbbbb
bbbbbbbbbbbbbbb...bbbbbbbbbbbbbbb
bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb
ENDMAP

# 10 gods.
NAME:    temple_eino_crystal_wide_a
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  2
SHUFFLE: {([
MAP
            bbbbb
          bbb...bbb
          b...(...b
    bbbbbbb.b...b.bbbbbbb
    b...b...........b...b
bbbbb.{.....b.T.b.....[.bbbbb
b...b.....B.......B.....b...b
b.B....bb...b...b...bb....B.b
b...b...b.....B.....b...b...b
bbbbb.B....bb...bb....B.bbbbb
    b...b...b...b...b...b
    bbbbb.B.......B.bbbbb
        b...b...b...b
        bbbbb.B.bbbbb
            b...b
            bbbbb
ENDMAP

# 13 gods.
NAME:    temple_eino_crystal_wide_b
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  3
SHUFFLE: {([
MAP
            bbbbb
            b...b
            b.(.b
        bbbbb...bbbbb
        b...bb.bb...b
        b.B.......B.b
    bbbbb...b...b...bbbbb
    b...bb.bb.B.bbbbb...b
bbbbb.{.b...b...b.....[.bbbbb
b...b...b.B.bbbbb.B.b...b...b
b.B....bb...........bb....B.b
b...b...bbbbb.B.bbbbb...b...b
bbbbb.B....bb...bb....B.bbbbb
    b...b...bbbbb...b...b
    bbbbb.B.......B.bbbbb
        b...b...b...b
        bbbbb.B.bbbbb
            b...b
            bbbbb
ENDMAP

# 12 gods.
NAME:    temple_eino_006a
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
SHUFFLE: {([
WEIGHT:  1
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
x..x...xxx....xxxxxxx....xxx...x..x
x.x.....x.......xxx.......x.....x.x
xx...B..x..B.....x.....B..x..B...xx
x.......x.................x.......x
xx.....xxx.......{.......xxx.....xx
xxx...xxxxx...xx...xx...xxxxx...xxx
xx.....xxx.....xx.xx.....xxx.....xx
x.......x.......x.x.......x.......x
x..B.........B..x(x..B.........B..x
x.......x.......x.x.......x.......x
xx.....xxx.....xx.xx.....xxx.....xx
xxx...xxxxx...xx...xx...xxxxx...xxx
xx.....xxx.......[.......xxx.....xx
x.......x.................x.......x
xx...B..x..B.....x.....B..x..B...xx
x.x.....x.......xxx.......x.....x.x
x..x...xxx....xxxxxxx....xxx...x..x
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

# 10 gods
NAME:    temple_eino_006b
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
SHUFFLE: {([
WEIGHT:  1
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
x..x...xxx....xxxxxxx....xxx...x..x
x.x.....x.......xxx.......x.....x.x
xx...B..x..B.....x.....B..x..B...xx
x.......x.................x.......x
xx.....xxx.......{.......xxx.....xx
xxx...xxxxx...xx...xx...xxxxx...xxx
xx.....xxx...xxxx.xxxx...xxx.....xx
x.......x...xxxx...xxxx...x.......x
x..B.......xxxx..(..xxxx.......B..x
x.......x...xxxx...xxxx...x.......x
xx.....xxx...xxxx.xxxx...xxx.....xx
xxx...xxxxx...xx...xx...xxxxx...xxx
xx.....xxx.......[.......xxx.....xx
x.......x.................x.......x
xx...B..x..B.....x.....B..x..B...xx
x.x.....x.......xxx.......x.....x.x
x..x...xxx....xxxxxxx....xxx...x..x
xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP


# 8 gods.
NAME:    temple_eino_rhombus_a
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  3
SHUFFLE: {([
MAP
            xxxxx     xxxxx
           xx...xx   xx...xx
          xx..x..xx xx..x..xx
         xx..x.x..xxx..x.x..xx
        xx..x...x..x..x...x..xx
       xx..x..B..x...x..B..x..xx
      xx....x...x..x..x...x....xx
     xx...x..x.x..x.x..x.x..x...xx
    xx...x.x..x..x...x..x..x.x...xx
   xx...x...x...x..B..x...x...x...xx
  xx...x.....x...x...x...x.....x...xx
 xx...x...x...x...x.x...x...x...x...xx
xx...x...x.x...x.x.x.x.x...x.x...x...xx
x...x...x...x...x.....x...x...x...x...x
x..x...x..B..x...[.(.{...x..B..x...x..x
x...x...x...x...x.....x...x...x...x...x
xx...x...x.x...x.x.x.x.x...x.x...x...xx
 xx...x...x...x...x.x...x...x...x...xx
  xx...x.....x...x...x...x.....x...xx
   xx...x...x...x..B..x...x...x...xx
    xx...x.x..x..x...x..x..x.x...xx
     xx...x..x.x..x.x..x.x..x...xx
      xx....x...x..x..x...x....xx
       xx..x..B..x...x..B..x..xx
        xx..x...x..x..x...x..xx
         xx..x.x..xxx..x.x..xx
          xx..x..xx xx..x..xx
           xx...xx   xx...xx
            xxxxx     xxxxx
ENDMAP

# 14 gods.
NAME:    temple_eino_rhombus_b
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  3
SHUFFLE: {([
MAP
                  xxx
                 xx[xx
            xxxxxx{.(xxxxxx
           xx...x.....x...xx
          xx..x..x...x..x..xx
         xx..x.x..x.x..x.x..xx
        xx..x...x..x..x...x..xx
       xx..x..B..x...x..B..x..xx
      xx....x...x..x..x...x....xx
     xx...x..x.x..x.x..x.x..x...xx
    xx...x.x..x..x...x..x..x.x...xx
   xx...x...x...x..B..x...x...x...xx
  xx...x..B..x...x...x...x..B..x...xx
 xx..x..x...x..x..x.x..x..x...x..x..xx
xx..x.x..x.x..x.x..x..x.x..x.x..x.x..xx
x..x...x..x..x...x...x...x..x..x...x..x
x.x..B..x...x..B..x.x..B..x...x..B..x.x
x..x...x..x..x...x...x...x..x..x...x..x
xx..x.x..x.x..x.x..x..x.x..x.x..x.x..xx
 xx..x..x...x..x..x.x..x..x...x..x..xx
  xx...x..B..x...x...x...x..B..x...xx
   xx...x...x...x..B..x...x...x...xx
    xx...x.x..x..x...x..x..x.x...xx
     xx...x..x.x..x.x..x.x..x...xx
      xx....x...x..x..x...x....xx
       xx..x..B..x...x..B..x..xx
        xx..x...x..x..x...x..xx
         xx..x.x..xxx..x.x..xx
          xx..x..xx xx..x..xx
           xx...xx   xx...xx
            xxxxx     xxxxx
ENDMAP

# 12 gods.
NAME:    temple_eino_rhombus_c
PLACE:   Temple
TAGS:    no_rotate
ORIENT:  encompass
WEIGHT:  4
SHUFFLE: {([
MAP
             xxx
            xx[xx
       xxxxxx{.(xxxxxx
      xx...x.....x...xx
     xx..x..x...x..x..xx
    xx..x.x..x.x..x.x..xx
   xx..x...x..x..x...x..xx
  xx..x..B..x...x..B..x..xx
 xx....x...x..x..x...x....xx
xx...x..x.x..x.x..x.x..x...xx
x...x.x..x..x...x..x..x.x...x
x..x...x...x..B..x...x...x..x
x.x..B..x...x...x...x..B..x.x
x..x...x..x..x.x..x..x...x..x
xx..x.x..x.x..x..x.x..x.x..xx
 xx..x..x...x...x...x..x..xx
  xx...x..B..x.x..B..x...xx
 xx..x..x...x...x...x..x..xx
xx..x.x..x.x..x..x.x..x.x..xx
x..x...x..x..x.x..x..x...x..xx
x.x..B..x...x...x...x..B..x..x
x..x...x...x..B..x...x...x...x
x...x.x..x..x...x..x..x.x...xx
xx...x..x.x..x.x..x.x..x...xx
 xx....x...x..x..x...x....xx
  xx..x..B..x...x..B..x..xx
   xx..x...x..x..x...x..xx
    xx..x.x..xxx..x.x..xx
     xx..x..xx xx..x..xx
      xx...xx   xx...xx
       xxxxx     xxxxx
ENDMAP

# 14 gods
NAME:    mini_greek_temple
PLACE:   Temple
WEIGHT:  20
TAGS:    no_rotate
ORIENT:  encompass
SHUFFLE: {([
NSUBST:  . = 15:1 / 12:2 / 2:t / *:.
SUBST:   ' = .
COLOUR:  " : darkgrey w:3 / white w:1 / none
SUBST:   " = .
MONS:    plant, bush
MAP
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
tttttttttttt....1111tttttttttttttttttttttttttttttttttttttttt
tttttttt.........1111....tttttttttttt.........tttttttttttttt
tttt.......................1tttttt.......t.........ttttttttt
tt.........2........t..........''''''...............2222tttt
tt.....{..21...t...............''ccccccccccccccc.....22.tttt
ttt...........ttt.......(......''G'c"""""""""""ctt..t..ttttt
tttt......2....................''''c"B"B"B"B"B"ctt......tttt
tttttt.....................t...''G'c"""""""""""cttt.....tttt
ttttttttt..1.....2...t.........''''+"""B"B"B"B"ctt...t....tt
tttttttt.....[.................''G'c"""""""""""ct...ttt..ttt
ttttttttt...................1..''''c"B"B"B"B"B"ct..tttt.tttt
ttttttttttttttt....2....t......''G'c"""""""""""ct....t..tttt
ttttttttttttttttt..............''ccccccccccccccct.......2ttt
tttttttttttttttttt..........t.........t......ttt......2ttttt
ttttttttttttttttttttt...............................22tttttt
ttttttttttttttttttttttt............t..........t....ttttttttt
tttttttttttttttttttttttttttt...........t.........ttttttttttt
ttttttttttttttttttttttttttttttt..............ttttttttttttttt
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
tttttttttttttttttttttttttttttttttttttttttttttttttttttttttttt
ENDMAP

# 2 gods (plus Lugonu and possibly more)
NAME:     corrupted_temple
PLACE:    Temple
ORIENT:   encompass
SUBST:    O = OOC
KFEAT:    O = altar_lugonu
# C doesn't work in the Temple.
KFEAT:    C = altar_makhleb / altar_xom / altar_beogh / altar_vehumet
MONS:     plant col:random name:demonic name_adjective
SUBST:    . = . x:1 w:1 l:1
SUBST:    x = xxxcv
SUBST:    ' = .

: local brnd = crawl.random2(4)
: if brnd == 0 then
LROCKCOL: magenta
: elseif brnd == 1 then
LROCKCOL: lightblue
: elseif brnd == 2 then
LROCKCOL: lightcyan
: else
LROCKCOL: lightred
: end
MAP
       xxxxx
      xx.O.xx
      x.'...x
      xO...Ox
      x.'.'.x
      xx.'.xx
 xxxxx x'..x xxxxx
xx.O.xxx.'.xxx.O.xx
x...'''''.'.'..'..x
xO.'.......'.'''.Bx
x.'.......'.....'.x
xx.O.xxx.'.xxx.B.xx
 xxxxx x..'x xxxxx
       x.'.x
       x..'x
       x..'x
       x.'.x
       x[.(x
       x1{1x
       xxxxx
ENDMAP

#############################################################################
# Overflow temples
##############################################################################

# To make an overflow temple for N altars, give it the tag
# "temple_overflow_N".

##############################################################################
# Overflow temples with one altar, must have tag "temple_overflow_1"
#
NAME:   overflow_temple_1_a
TAGS:   temple_overflow_1 allow_dup
MAP
B
ENDMAP
