##############################################################################
# mini_features.des: This is the place for minivaults without monsters.
#           So all vaults in this file should have neiter ORIENT nor MONS or
#           KMONS lines. Exceptions are made for vaults with may have no
#           monsters or are supposed to look as if they had no monsters.
#
#           Vaults with ORIENT lines are stored in float.des or large.des.
#           Minivaults with monsters go to mini_monsters.des.
#           Maps for the Vault branch, including Vaults:8 are in vaults.des.
###############################################################################

default-depth: D, Vault, Elf, Crypt

############################################################################
#
# Flavour vaults: no items, no monsters. Statues, glass, fountains, water...
#
############################################################################

NAME:   glass_columns_a
DEPTH:  D, Elf, Crypt
TAGS:   extra luniq_mini
WEIGHT: 5
MAP
.....
.m.m.
.....
.m.m.
.....
ENDMAP

NAME:   glass_columns_b
DEPTH:  D, Elf, Crypt
TAGS:   extra luniq_mini
WEIGHT: 3
MAP
.......
.m.m.m.
.......
.m.m.m.
.......
.m.m.m.
.......
ENDMAP

NAME:   glass_columns_c
DEPTH:  D, Elf, Crypt
TAGS:   extra luniq_mini
WEIGHT: 2
MAP
.........
.m.m.m.m.
.........
.m.m.m.m.
.........
.m.m.m.m.
.........
.m.m.m.m.
.........
ENDMAP

NAME: columned_hall_lemuel
TAGS: extra luniq_mini ruin_lair
DEPTH: D, Lair, Elf, Crypt
MAP
xxxxxxxxxxxxxxxxxxxxxxxxxxxxx
@...........................@
..x..x..x..x..x..x..x..x..x..
@...........................@
..x..x..x..x..x..x..x..x..x..
@...........................@
xxxxxxxxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

# Small statue alley (Eino)
NAME:   small_statue_alley_a
TAGS:   uniq_statue_alley extra luniq_mini
DEPTH:  D:10-20
WEIGHT: 7
SUBST:  F = G:100 F:1
KMONS:  F = orange crystal statue / silver statue / ice statue
MAP
  xxxxxxx
xxxcccccx
...G...G@
.G.F.G.G.
.G.G.F.G.
@G...G...
xcccccxxx
xxxxxxx
ENDMAP

NAME:   small_statue_alley_b
TAGS:   uniq_statue_alley extra luniq_mini
DEPTH:  D:3-10
WEIGHT: 2
MAP
  xxxxxxx
xxxcccccx
...G...G@
.G.G.G.G.
.G.G.G.G.
@G...G...
xcccccxxx
xxxxxxx
ENDMAP

NAME:   small_statue_alley_c
TAGS:   uniq_statue_alley extra luniq_mini
DEPTH:  Orc
WEIGHT: 1
MAP
  xxxxxxx
xxxcccccx
...I...I@
.I.I.I.I.
.I.I.I.I.
@I...I...
xcccccxxx
xxxxxxx
ENDMAP

# Small intersection with statues (Eino)
NAME:    small_statue_intersection
DEPTH:   D:2-26, Elf, Crypt, Lair
TAGS:    mini_float allow_dup no_hmirror no_vmirror extra luniq_mini
TAGS:    ruin_lair abyss ruin_abyss
MAP
xx.xx
xG.Gx
.....
xG.Gx
xx.xx
ENDMAP

NAME:  fungi_pond_lemuel
DEPTH: D:8-20, Lair
TAGS:  allow_dup extra luniq_mini
MONS:  fungus, wandering mushroom
SUBST: 1 = . 1 2:4
SUBST: ? : w..
SUBST: ! : ww.
MAP
..1...?.....
....1???1...
..1...??ww1.
....1wwwwww.
.11wwwwwwww.
..www!!wwww.
..ww!!www1..
..1ww!ww11..
1..1w!!w1...
....!!1.....
.1...1!.1...
...........1
ENDMAP

# This is an ancient vault.
NAME:  solitary_fountain
DEPTH: D, Elf, Vault
TAGS:  allow_dup extra luniq_mini
SUBST: ?=TUV
KMASK: T = no_monster_gen
KMASK: U = no_monster_gen
MAP
.....
.....
..?..
.....
.....
ENDMAP

# Another very classical vault.
NAME:  fountainhead
DEPTH: D, Elf, Crypt, Vault
TAGS:  allow_dup extra luniq_mini
SUBST: ?=TUV
MAP
..............
..xxxw..wxxx..
.x...xwwx...x.
.x.?.xwwx.?.x.
.x...xwwx...x.
..xxxwwwwxxx..
....wwwwww....
....wwwwww....
..xxxwwwwxxx..
.x...xwwx...x.
.x.?.xwwx.?.x.
.x...xwwx...x.
..xxxw..wxxx..
..............
ENDMAP

NAME:  patterned_corridor
DEPTH: D, Elf, Lair
TAGS:  abyss ruin_abyss ruin_lair
SUBST: x : xxccv
MAP
xxxxxxxxxxxxxxxxxxxxxxx
x.......x.......x.....@
x.xxxxx.x.xxxxx.x.xxxxx
x.x...x.x.x...x.x.x...x
x...x.x.x...x.x.x...x.x
xxxxx.x.xxxxx.x.xxxxx.x
@.....x.......x.......x
xxxxxxxxxxxxxxxxxxxxxxx
ENDMAP

#####################################################################
#
# Various vaults themed around inaccessible items (without monsters).
#
#####################################################################

NAME:  feat_on_display
DEPTH: D, Elf, Crypt, Vault
TAGS:  extra luniq_mini
SUBST: ? = TUl
TAGS:  no_monster_gen no_item_gen
MAP
.....
.mmm.
.m?m.
.mmm.
.....
ENDMAP

NAME:   item_on_display_a
DEPTH:  D, Elf, Crypt, Vault
TAGS:   extra luniq_mini
WEIGHT: 9
SUBST:  % = %%%*
TAGS:   no_monster_gen no_item_gen
MAP
.....
.mmm.
.m%m.
.mmm.
.....
ENDMAP

NAME:   item_on_display_b
DEPTH:  D, Elf, Crypt, Vault
TAGS:   extra luniq_mini
WEIGHT: 1
SUBST:  * = ***|
TAGS:   no_monster_gen no_item_gen
MAP
.....
.nnn.
.n*n.
.nnn.
.....
ENDMAP

# Identical in feature and content to item_on_display_b, only that it
# contains within an unseen horror, by due.
NAME:   unseen_surprise_small
WEIGHT: 1
TAGS:   no_wall_fixup extra luniq_mini
DEPTH:  D:8-27, Elf, Crypt, Vault
KMONS:  a = generate_awake unseen_horror
KITEM:  a = | / *
MAP
.....
.mmm.
.mam.
.mmm.
.....
ENDMAP

# Unseen surprise! by due (and dpeg).
NAME:   due_unseen_surprise
DEPTH:  D, Elf, Crypt, Vault
TAGS:   no_wall_fixup extra luniq_mini
: if you.absdepth()<11 or crawl.random2(27)>you.absdepth() then
SUBST:  a = %
SUBST:  b = %**
: else
KFEAT:  a = .
KFEAT:  b = .
# Two versions for loot.
: if crawl.coinflip() == 0 then
KITEM: a = * / %
KITEM: b = *
: else
KITEM: a = % / | w:1
KITEM: b = |
: end
# Expected value of unseen horrors depends on depth:
: local wt = (you.absdepth()-10) * (you.absdepth()-10)
: kmons("a = generate_awake unseen horror w:" .. wt .. " / nothing w:40")
KMONS: b = generate_awake unseen horror
: end
MAP
........@
.........
..mmmmm..
..maaam..
..mabam..
..maaam..
..mmmmm..
.........
.........
ENDMAP

# Don't you wish you knew apportation?
NAME: baited_tele_trap
DEPTH: !Temple, !Slime
KITEM: x = any good_item, any good_item/nothing, any good_item/nothing
KFEAT: x = teleport trap
MAP
x
ENDMAP

# Not hard to obtain as is, but requires getting shafted.
NAME:  minmay_item_behind_shaft
TAGS:  extra mini_float luniq_mini
DEPTH: D:2-23
KFEAT: S = shaft trap
MAP
ccccc
..S%c
ccccc
ENDMAP

NAME:  minmay_statues_item
TAGS:  extra luniq_mini
DEPTH: D:1-26
MAP
.....
.GcG.
.c%c.
.GcG.
.....
ENDMAP

# Another somewhat-hard-to-obtain item
NAME:  min_item_tele_traps
TAGS:  extra luniq_mini
DEPTH: D:2-26
KFEAT: ! = teleport trap
MAP
.....
.v!v.
.!*!.
.v!v.
.....
ENDMAP

NAME:    treasure_zot_lemuel
DEPTH:   D:10-27, Elf, Vault, Crypt
TAGS:    allow_dup
NSUBST:  Z = 4=. / z
KFEAT:   z = zot trap
SUBST:   *: *$
WEIGHT:  3
MAP
xxxxxxxxxx
xxxxxxx**x
@ZZZZZ=**x
xxxxxxx**x
xxxxxxxxxx
ENDMAP

NAME:   water_maze_lemuel
TAGS:   no_pool_fixup uniq_water_maze_lemuel
WEIGHT: 5
ITEM:   ring of teleportation / scroll of teleportation q:3
DEPTH:  D:5-27
MAP
   wwwwwwwww
  wwcccccccww
 wwccwwwwwccww
wwccwwcccwwccww
wccwwccwccwwccw
wcwwccwwwccwwcw
wcwcc*wcwwccwcw
wcwc*d*ccwwcwcw
wcwcc*ccwwccwcw
wcwwcccwwccwwcw
wccwwccwccwwccw
wwccwwcwcwwccww
 wwccwwwcwccww
  wwcccccwcww
   wwwwwwwww
ENDMAP

NAME:   water_boxes_lemuel
TAGS:   no_pool_fixup uniq_water_maze_lemuel
WEIGHT: 5
DEPTH:  D:5-27, Swamp
KMONS:  * = fungus
KFEAT:  * = *
NSUBST: a = 1:= / *:x
NSUBST: b = 1:= / *:x
NSUBST: c = 1:= / *:x
NSUBST: d = 1:= / *:x
MAP
  wwwwwwww
 wwwwwwwwww
wwxaxwwxbxww
wwa*awwb*bww
wwxaxwwxbxww
wwwwwwwwwwww
wwwwwwwwwwww
wwxdxwwxcxww
wwd*dwwc*cww
wwxdxwwxcxww
 wwwwwwwwww
  wwwwwwww
ENDMAP

####################################################################
#
# Supply closet vaults (vaults with items and no risk).
#
####################################################################

NAME:   supply_closet_lemuel
DEPTH:  D:1-9
TAGS:   no_monster_gen allow_dup extra luniq_mini
ITEM:   potion of water w:20 / bread ration / meat ration / arrow /\
        bolt / spear / any potion w:5
NSUBST: x = 1:= / *:x
SUBST:  = = +===
MAP
x?xx
xddx
xddx
xxxx
ENDMAP

NAME:  minmay_bad_closet
TAGS:  extra mini_float
DEPTH: D:2-12
: if you.absdepth() > 4 then
ITEM:  scroll of immolation / potion of degeneration / potion of decay / \
       potion of strong poison / potion of poison
: else
ITEM:  scroll of paper / scroll of random uselessness / \
       potion of degeneration / potion of poison
: end
MAP
xxxx
xddx
xddx
xx+x
ENDMAP

NAME:   secret_library_closet
DEPTH:  1-27, !Swamp
TAGS:   mini_float allow_dup extra luniq_mini
ITEM:   any book w:20 / any scroll / nothing
MAP
x=xx
xddx
xddx
xxxx
ENDMAP

NAME:   eino_small_chamber_without_monster
TAGS:   mini_float allow_dup extra luniq_mini ruin_lair abyss ruin_abyss
DEPTH:  D:4-27, Lair
MAP
 xxxxx
xx...xx
x..*..x
x.....x
xx...xx
 x...x
ENDMAP

NAME:   eino_tiny_chamber_secret
TAGS:   mini_float allow_dup extra luniq_mini
DEPTH:  D:2-27, Elf, Vault, Crypt
MAP
xxxxx
x...x
x.*.=
x...x
xxxxx
ENDMAP

NAME:  firewood_loft
DEPTH: D:1-26
KITEM: " = quarterstaff, quarterstaff, quarterstaff
KITEM: ' = quarterstaff, quarterstaff / any staff w:3
MAP
xxxxx
x"']x
xxxxx
ENDMAP

#######################################################################
#
# Classical minivaults. All of these are 12x12, almost all are ancient.
#                       This section is seperate for nostalgic reasons.
#
#######################################################################

NAME: minivault_1
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
..xxxx=xxx..
.xx..x...xx.
.x....x...x.
.x...x....x.
.xx.x*x.x.=.
.=.x.x*x.xx.
.x....x...x.
.x...x....x.
.xx...x..xx.
..xxx=xxxx..
............
ENDMAP

NAME: minivault_4
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
....xwxx....
..xxxwwxwx..
..xwwwwwwx..
.xwwxwwxwxx.
.xwwwwwwwwx.
.xwwxwwwxww.
.xxwwwwwwxx.
..wwwwxwwx..
..xxxwwxxw..
....xxww....
............
ENDMAP

NAME: minivault_5
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
.x.xxxxxxxx.
.x.x......x.
.x.x.xxxx.x.
.x.x.x**x.x.
.x.x.x**x.x.
.x.x.xx.x.x.
.x.x....x.x.
.x.xxxxxx.x.
.x........x.
.xxxxxxxxxx.
............
ENDMAP

NAME: minivault_10
TAGS: mini_float extra luniq_mini
MAP
xxxx  xxxx
x**x  x**x
x**+..+**x
xx+x..x+xx
  ......
  ......
xx+x..x+xx
x**+..+**x
x**x  x**x
xxxx  xxxx
ENDMAP

# Multicoloured onion
NAME:    minivault_11
DEPTH:   D, Elf, Vault, Crypt, Lair
TAGS:    extra luniq_mini abyss ruin_abyss ruin_lair
SHUFFLE: bcva
MAP
............
.+xxxxxxxx+.
.x........x.
.x.+cccc+.x.
.x.c....c.x.
.x.c.bb.c.x.
.x.c.bb.c.x.
.x.c....c.x.
.x.+cccc+.x.
.x........x.
.+xxxxxxxx+.
............
ENDMAP

# Water cross
NAME: minivault_14
TAGS: allow_dup extra luniq_mini
MAP
............
.wwwww.wwww.
.wwwww.wwww.
.wwwww.wwww.
.wwwww.wwww.
.......wwww.
.wwww.......
.wwww.wwwww.
.wwww.wwwww.
.wwww.wwwww.
.wwww.wwwww.
............
ENDMAP

NAME: minivault_19
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
.xx......xx.
.xxx....xxx.
..xxx..xxx..
...xxxxxx...
....xxxx....
....xxxx....
...xxxxxx...
..xxx..xxx..
.xxx....xxx.
.xx......xx.
............
ENDMAP

NAME:  minivault_21
TAGS:  allow_dup extra luniq_mini
DEPTH: D:8-26
MAP
............
.~xxxxxxxx~.
.x........x.
.x.cccccc.x.
.x.c|..<c.x.
.x.c.**.c.x.
.x.c.**.c.x.
.x.c>..|c.x.
.x.cccccc.x.
.x........x.
.~xxxxxxxx~.
............
ENDMAP

NAME: minivault_22
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
SUBST: $ : $ *:5
MAP
............
.....xx.....
...xxxxxx...
..x~x..x~x..
..xx.xx.xx..
.xx.x$$x.xx.
.xx.x$$x.xx.
..xx.xx.xx..
..x~x..x~x..
...xxxxxx...
.....xx.....
............
ENDMAP

NAME: minivault_23
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
x.x.x.x.x.x.
.x.x.x.x.x.x
x.x.x.x.x.x.
.x.x.x.x.x.x
x.x.x.x.x.x.
.x.x.x.x.x.x
x.x.x.x.x.x.
.x.x.x.x.x.x
x.x.x.x.x.x.
.x.x.x.x.x.x
x.x.x.x.x.x.
.x.x.x.x.x.x
ENDMAP

NAME: minivault_24
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
....xxxx....
....xxxx....
....xxxx....
.xxxx.x.xxx.
.xxx.x.xxxx.
.xxxx.x.xxx.
.xxx.x.xxxx.
....xxxx....
....xxxx....
....xxxx....
............
ENDMAP

NAME: minivault_25
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
SHUFFLE: XY
SUBST: X=x, Y=+
MAP
............
.xxXxxxxxxx.
.x........x.
.x........Y.
.x........x.
.x........x.
.x........x.
.x........x.
.Y........x.
.x........x.
.xxxxxxxXxx.
............
ENDMAP

NAME: minivault_26
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
c..........c
.c...cc...c.
..c..cc..c..
...c....c...
....c..c....
.cc..cc..cc.
.cc..cc..cc.
....c..c....
...c....c...
..c..cc..c..
.c...cc...c.
c..........c
ENDMAP

NAME: minivault_27
TAGS: allow_dup extra luniq_mini abyss ruin_abyss
MAP
............
.x.xxxxxxxx.
.x........x.
.xxxxxxxx.x.
.x........x.
.x.xxxxxxxx.
.x........x.
.xxxxxxxx.x.
.x........x.
.x.xxxxxxxx.
............
ENDMAP

##########################################################################
#
# Fog generator vaults. Most of these are very dangerous. But no monsters.
#
# Many of these vaults rely on status to halt autoexplore. If a dangerous
# fog has been spotted by the player, autoexclusions will be placed. Note
# that you may use some of these vaults to kill monsters, but there's some
# risk involved and you won't get experience.
#
##########################################################################

NAME:   lemuel_flamethrower_3
DEPTH:  D:12-27, Vault, Elf, Geh
TAGS:   allow_dup abyss ruin_abyss
MARKER: * = lua:fog_machine { cloud_type="flame", \
            pow_min = 20, pow_max = 40, delay = 150, \
            size = 1, walk_dist = 0, spread_rate= 75 }
COLOUR: * = red
SUBST:  * = .
MAP
.....
cc.cc
cc.cc
cc.cc
 c*c
 ccc
  c
ENDMAP

NAME:   lemuel_flamethrower_2
DEPTH:  D:5-27, Vault, Elf, Geh
TAGS:   abyss ruin_abyss
MARKER: * = lua:fog_machine { cloud_type="flame", \
            pow_min = 20, pow_max = 40, delay_min = 100, delay_max=200, \
            size = 1, walk_dist = 0, spread_rate= 75 }
COLOUR: n = red
SUBST:  * = .
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
...........
.xxxx.xxxx.
.xxxx.xxxx.
.xxxx*xxxx.
.xxxnnnxxx.
...*nGn*...
.xxxnnnxxx.
.xxxx*xxxx.
.xxxx.xxxx.
.xxxx.xxxx.
...........
ENDMAP

NAME:   lemuel_flamethrower_1
DEPTH:  D:5-27, Vault, Elf, Geh
TAGS:   layout_rooms layout_city
MARKER: * = lua:fog_machine { cloud_type="flame", \
            pow_min = 20, pow_max = 40, delay = 150, \
            size = 1, walk_dist = 0, spread_rate= 75 }
COLOUR: * = red
SUBST:  * = .
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
xxxxxxxxxxxxx
xxxxxxxxxxxxx
xxxxxxxxxxxxx
xxxxxxxxxxxxx
xxxxxxGxxxxxx
.............
@...........@
.............
xxxxxx.xxxxxx
xxxxxx.xxxxxx
xxxxxx.xxxxxx
xxxxxx*xxxxxx
xxxxxxxxxxxxx
xxxxxxxxxxxxx
xxxxxxxxxxxxx
xxxxxxxxxxxxx
ENDMAP

# Little wisps of steam around the lava, and then occasionally a big
# eruption. No warning needed here - the steam does very little damage.
NAME:   lemuel_old_faithful
DEPTH:  D, Lair, Geh
TAGS:   uniq_geyser no_monster_gen
MONS:   nothing,nothing
MARKER: 1 = lua:fog_machine { cloud_type="steam", \
            pow_min = 2, pow_max = 5, delay = 25, \
            size = 1, walk_dist = 3, spread_rate= 10 }
MARKER: 2 = lua:fog_machine { cloud_type="steam", \
            pow_min = 10, pow_max = 20, delay = 750, \
            size = 10, walk_dist = 1, spread_rate= 75 }
SUBST:  1 = l, 2 = l
SUBST:  l = l w:20
SUBST:  ? : w. , ! : w. , & : w.
MAP
.......?.......
......&?.......
.......??......
..&&&&???......
&&&&?wwwww.....
&&?wwwwwwwww&&.
.wwwwwlwwwwwww&
..&wwl1lwwwww&&
...wwwl2lwww&&.
....wwwlww&&...
..!!wwwww......
..!!!www.......
.!!!!w!.....!..
..!!!w.....!!!.
...!!.......!!.
ENDMAP

NAME:   lemuel_another_geyser
DEPTH:  D, Lair
TAGS:   uniq_geyser no_monster_gen layout_rooms
MONS:   nothing,nothing
MARKER: 1 = lua:fog_machine { cloud_type="steam", \
            pow_min = 2, pow_max = 5, delay = 25, \
            size = 3, walk_dist = 3, spread_rate= 20 }
MARKER: 2 = lua:fog_machine { cloud_type="steam", \
            pow_min = 15, pow_max = 30, delay = 750, \
            size = 12, walk_dist = 1, spread_rate= 99 }
SUBST:  1 = l, 2 = l
SUBST:  l = lw
SUBST:  ? : wlx
MAP
  .......
....www....
...wwwww...
xxxxxwxxxxx
xxxxxwwxxxx
xxxxxxxwxxx
xxxxxxxwxxx
xx??xxwxxxx
xx??lw1wxxx
xxxxxlwwwxx
xxxxxl2xxxx
xxxxxxxxxxx
ENDMAP

NAME:  lemuel_nasty_fountain
DEPTH: D:11-27, Crypt, Tar
TAGS:  allow_dup
MARKER: Y = lua:fog_machine { cloud_type = "foul pestilence", \
             pow_min = 8, pow_max = 12, delay_min = 20, delay_max = 30, \
             size = 1, walk_dist = 1, spread_rate= 33 }
MAP
Y
ENDMAP

NAME:   lemuel_flame_loot_1
DEPTH:  D, Elf, Vault, Zot
ITEM:   nothing
SUBST:  * = *.
SUBST:  * : *$
MARKER: d = lua:fog_machine { cloud_type = "flame", \
             pow_min = 10, pow_max = 10, delay = 10, \
             size = 1, walk_dist = 0, spread_rate= 0 }
SUBST:  ' = .
MAP
ccccc...ccccc
ccccc'''ccccc
ccccc'd'ccccc
ccccc'''ccccc
ccccc...ccccc
.'''.***.'''.
.'d'.***.'d'.
.'''.***.'''.
ccccc...ccccc
ccccc'''ccccc
ccccc'd'ccccc
ccccc'''ccccc
ccccc...ccccc
ENDMAP

# High T&D skill or a means of detecting secret doors is helpful here....
NAME:    lemuel_freeze_loot_1
DEPTH:   D:12-27, Crypt
SUBST:   * : **$
SUBST:   * = **|
NSUBST:  n = 1:= / *:n
MONS:    nothing, nothing, nothing, nothing
SHUFFLE: 1234
MARKER:  1 = lua:fog_machine { cloud_type = "freezing vapour", \
             pow_min = 1, pow_max = 10, delay = 85, \
             size = 1, walk_dist = 2, spread_rate= 20 }
MARKER:  2 = lua:fog_machine { cloud_type = "freezing vapour", \
             pow_min = 1, pow_max = 10, delay = 95, \
             size = 1, walk_dist = 2, spread_rate= 20 }
MARKER:  3 = lua:fog_machine { cloud_type = "freezing vapour", \
             pow_min = 1, pow_max = 10, delay = 105, \
             size = 1, walk_dist = 2, spread_rate= 20 }
MARKER:  4 = lua:fog_machine { cloud_type = "freezing vapour", \
             pow_min = 1, pow_max = 10, delay = 115, \
             size = 1, walk_dist = 2, spread_rate= 20 }
SUBST:   1=w, 2=w, 3=w, 4=w
MAP
   .wwwww.
 .wwwwwwwww.
 wwwww1wwwww
.wwcnnnnncww.
wwwn..F..nwww
ww2n.***.nwww
wwwn.***.n4ww
wwwn..F..nwww
.wwcnnnnncww.
 wwwww3wwwww
 .wwwwwwwww.
   .wwwww.
ENDMAP

# No safe path in this one -- just got to take your chances!
NAME:   lemuel_flames_and_gold
DEPTH:  D:16-27
WEIGHT: 2
TAGS:   no_item_gen
ITEM:   nothing, nothing, nothing
NSUBST: . = 4:d / 4:e / 4:f / *:.
MARKER: d = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 4, delay = 29, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER: e = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 4, delay = 31, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER: f = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 4, delay = 37, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
.............
.............
.............
.............
......$......
.....$$$.....
....$$G$$....
.....$$$.....
......$......
.............
.............
.............
.............
ENDMAP

NAME:    lemuel_firewalk_3
DEPTH:   D:16-27
TAGS:    uniq_firewalk abyss ruin_abyss
WEIGHT:  2
ORIENT:  float
ITEM:    nothing, nothing, nothing
SHUFFLE: def
MARKER:  d = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 4, delay = 39, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER:  e = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 6, delay = 59, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER:  f = lua:fog_machine { cloud_type = "flame", \
             pow_min = 2, pow_max = 8, delay = 79, start_clouds = 1, \
             size = 1, walk_dist = 2, spread_rate= 0 }
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
xxxxxxxG@Gxxxxxxx
x...............x
x...............x
x.d..e.....f..d.x
x...............x
x...............x
x...............x
x.e..f.....d..e.x
x...............x
x...............x
x...............x
x.f..d.....e..f.x
x...............x
x...............x
x...............x
x.d..e.....f..d.x
x...............x
x...............x
x......$$$......x
x.e.f..$$$..d.e.x
x......$$$......x
xxxxxxxxxxxxxxxxx
ENDMAP

#################################################################
# Flame stairs (Lemuel)
#
NAME:    lemuel_flame_stairs_1
DEPTH:   D:9-26, Elf:2-6, Vault, Zot:1-4
ITEM:    nothing
SHUFFLE: {[ / ]}
MARKER:  d = lua:fog_machine { cloud_type = "flame", \
             pow_min = 10, pow_max = 10, delay = 10, \
             size = 1, walk_dist = 0, spread_rate= 0 }
MAP
ccccccccccc
cccccc...{c
@.........c
@..d......c
@.........c
cccccc...[c
ccccccccccc
ENDMAP

NAME:    lemuel_freeze_stairs_1
DEPTH:   D:9-26, Elf:2-6, Vault, Zot:1-4
ITEM:    nothing
SHUFFLE: {[ / ]}
MARKER:  d = lua:fog_machine { cloud_type = "freezing vapour", \
             pow_min = 10, pow_max = 10, delay = 10, \
             size = 1, walk_dist = 0, spread_rate= 0 }
MAP
ccccccccccccc
cccccccc...{c
@...........c
@..d........c
@...........c
cccccccc...[c
ccccccccccccc
ENDMAP

# No item generation for the sake of autoexplore.
NAME:   lemuel_flamethrower_hall
DEPTH:  D:9-27, Vault, Elf, Geh
TAGS:   layout_rooms layout_city no_item_gen abyss ruin_abyss
MARKER: * = lua:fog_machine { cloud_type="flame", \
            pow_min = 25, pow_max = 50, delay = 150, \
            size = 2, walk_dist = 0, spread_rate= 40 }
COLOUR: * = red
SUBST:  * = .
SUBST:  $ : $$*|.c
MARKER: G = lua:props_marker { stop_explore = "a scorch-marked granite statue."\
        , feature_description = "A scorch-marked granite statue." }
MAP
ccccccccccccccccccccccc
ccxxx*xxxxx*xxxxx*xxxxc
Gcxxx.xxxxx.xxxxx.xxxxc
ccccc.ccccc.ccccc.ccccc
c.................+$$$c
+.................+$$$c
c.................+$$$c
cc.ccccc.ccccc.cccccccc
Gc.xxxxx.xxxxx.xxxxxxxc
cc*xxxxx*xxxxx*xxxxxxxc
ccccccccccccccccccccccc
ENDMAP

# A poor man's Radiant Cavern (1KB)
#
# Without an amulet of rMut, in my tests, the cost was 4-6 bad
# mutations -- certainly not worth most of the loot. With rMut,
# it's still a gamble.
NAME:  kilobyte_mutagenic_chamber
DEPTH: D:15-, Elf, Vault
TAGS:  abyss ruin_abyss
MARKER:     U = lua:fog_machine { cloud_type = "mutagenic fog", \
                pow_min = 10, pow_max = 30, delay = 5, \
                size = 4, walk_dist = 0, spread_rate= 0 }
MAP
ccccccccc
cvvvvvvvc
cv.|||.vc
cv.nnn.vc
cv.U.U.vc
cvn...nvc
cv.....vc
cv.nnn.vc
cv.....vc
cvvv+vvvc
ENDMAP
